Поделиться через

оператор in

Область применения: ✅Microsoft Fabric

Фильтрует набор записей для данных с учетом регистра.

В следующей таблице приведено сравнение in операторов:

Оператор Описание С учетом регистра Пример (при true)
in Равно любому из элементов Да "abc" in ("123", "345", "abc")
!in Не соответствует одному из элементов Да "bca" !in ("123", "345", "abc")
in~ Равно любому из элементов нет "Abc" in~ ("123", "345", "abc")
!in~ Не соответствует одному из элементов нет "bCa" !in~ ("123", "345", "ABC")

Примечание.

Вложенные массивы сведены в один список значений. Например, x in (dynamic([1,[2,3]])) преобразуется в x in (1,2,3).

Дополнительные сведения о других операторах и определение наиболее подходящих операторов для запроса см. в разделе строковых операторов типа данных.

Операторы, работающие без учета регистра, сейчас поддерживают только текст ASCII. Для сравнения, отличного от ASCII, используйте функцию tolower( ).

Советы по производительности

Примечание.

Если используются более 128 терминов поиска, оптимизация поиска текстовых индексов отключена, что может привести к снижению производительности запросов.

Примечание.

Производительность зависит от типа поиска и структуры данных. Рекомендации см. в разделе "Рекомендации по запросу".

Синтаксис

T|whereседловинаin(выражение, ... )

Дополнительные сведения о соглашениях синтаксиса.

Параметры

Имя (название) Тип Обязательно Описание
T string ✔️ Табличные входные данные для фильтрации.
седловина string ✔️ Столбец, по которому необходимо отфильтровать.
выражение скалярный или табличный ✔️ Выражение, указывающее значения, для которых выполняется поиск. Каждое выражение может быть скалярным значением или табличным выражением , которое создает набор значений. Если табличное выражение содержит несколько столбцов, используется первый столбец. Поиск рассматривает до 1000 000 различных значений.

Возвраты

Строки в T , для которых является trueпредикат.

Примеры

Список скалярных

В следующем запросе показано, как использовать in с списком скалярных значений.

Выполнение запроса

StormEvents 
| where State in ("FLORIDA", "GEORGIA", "NEW YORK") 
| count

Выпуск

Численность
4775

Динамический массив

В следующем запросе показано, как использовать in динамический массив.

Выполнение запроса

let states = dynamic(['FLORIDA', 'ATLANTIC SOUTH', 'GEORGIA']);
StormEvents 
| where State in (states)
| count

Выпуск

Численность
3218

Табличное выражение

В следующем запросе показано, как использовать in табличное выражение.

Выполнение запроса

let Top_5_States = 
    StormEvents
    | summarize count() by State
    | top 5 by count_; 
StormEvents 
| where State in (Top_5_States) 
| count

Тот же запрос можно записать с помощью встроенной инструкции табличного выражения.

Выполнение запроса

StormEvents 
| where State in (
    StormEvents
    | summarize count() by State
    | top 5 by count_
    ) 
| count

Выпуск

Численность
14242

Основной с другим примером

В следующем примере определяются первые пять состояний с событиями молнии и используется функция iff() и оператор in для классификации событий молнии по пяти верхним пяти состояниям, помеченным именем состояния, и все остальные, помеченные как "Другие".

Выполнение запроса

let Lightning_By_State = materialize(StormEvents
    | summarize lightning_events = countif(EventType == 'Lightning') by State);
let Top_5_States = Lightning_By_State | top 5 by lightning_events | project State; 
Lightning_By_State
| extend State = iff(State in (Top_5_States), State, "Other")
| summarize sum(lightning_events) by State

Выпуск

Штат sum_lightning_events
АЛАБАМА 29
ВИСКОНСИН 31
ТЕХАС 55
ФЛОРИДА 85
ДЖОРДЖИЯ 106
Другие 415

Использование статического списка, возвращенного функцией

В следующем примере выполняется подсчет событий из таблицы StormEvents на основе предопределенного списка интересных состояний. Интересные состояния определяются функцией InterestingStates().

Выполнение запроса

StormEvents 
| where State in (InterestingStates()) 
| count

Выпуск

Численность
4775

В следующем запросе отображаются состояния, которые считаются интересными функцией InterestingStates().

Выполнение запроса

.show function InterestingStates

Выпуск

Имя (название) Параметры Текст Папка Строка документа
Интересные статистические данные () { dynamic(["ВАШИНГТОН", "ФЛОРИДА", "ДЖОРДЖИЯ", "НЬЮ-ЙОРК"]) }

Связанное содержимое