Пример триггера регистрации (скрипты)

В этом примере скриптов показано, как создать задачу, которая планируется выполнить блокнот при регистрации задачи. Задача содержит триггер регистрации, указывающий начальную границу и конечную границу для задачи. Начальная граница указывает, когда активируется триггер. Задача также содержит действие, указывающее задачу для выполнения Блокнота.

В следующей процедуре описывается, как запланировать исполняемый файл, например Блокнот для запуска при регистрации задачи.

Планирование запуска блокнота при регистрации задачи

1. Создайте объектTaskService. Этот объект позволяет создать задачу в указанной папке.
2. Получите папку задачи и создайте задачу. Используйте метод TaskService.GetFolder, чтобы получить папку, в которой хранится задача, и метод TaskService.NewTask для создания объекта taskDefinitionTaskDefinition, представляющего задачу.
3. Определите сведения о задаче с помощью объекта TaskDefinition. Используйте свойство TaskDefinition.Settings, чтобы определить параметры, определяющие, как служба планировщика задач выполняет задачу и свойство taskDefinition.RegistrationInfo, чтобы определить сведения, описывающие задачу.
4. Создайте триггер регистрации с помощью свойства TaskDefinition.Triggers. Это свойство предоставляет доступ к объекту TriggerCollection. Используйте метод TriggerCollection.Create (указав тип триггера, который требуется создать) для создания триггера регистрации.
5. Создайте действие для выполнения задачи с помощью свойства TaskDefinition.Actions. Это свойство предоставляет доступ к объекту ActionCollection. Используйте метод ActionCollection.Create, чтобы указать тип создаваемого действия. В этом примере используется объект ExecAction, представляющий действие, которое запускает исполняемый файл.
6. Зарегистрируйте задачу с помощью метода TaskFolder.RegisterTaskDefinition.

В следующем примере VBScript показано, как создать задачу, которая планирует выполнение Блокнота при регистрации задачи.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe when
' the task is registered.
'---------------------------------------------------------

' A constant that specifies a registration trigger.
const TriggerTypeRegistration = 7
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start Notepad when the task is registered."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a registration trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeRegistration)

trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "RegistrationTriggerId"   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes Notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Registration Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Связанные разделы

использование планировщика задач