Поделиться через

Отображение имен и состояний задач (скрипты)

  • Статья

В этом примере скрипта показано, как перечислять задачи в папке задач и отображать значения свойств из каждой задачи.

В следующей процедуре описывается отображение имен и состояний задач для всех задач в папке задач.

Отображение имен и состояний задач для всех задач в папке задач

  1. Создайте объект TaskService .

    Этот объект позволяет подключиться к службе планировщика задач и получить доступ к определенной папке задач.

  2. Получите папку задач, в которой содержатся нужные сведения.

    Чтобы получить папку, используйте метод TaskService.GetFolder .

  3. Получите коллекцию задач из папки .

    Используйте метод TaskFolder.GetTasks , чтобы получить коллекцию задач (RegisteredTaskCollection).

  4. Получение количества задач в коллекции и перечисление по каждой задаче в коллекции.

    Используйте коллекцию объектов RegisteredTaskCollection для получения экземпляра объекта RegisteredTask . Каждый экземпляр будет содержать задачу в коллекции. Затем можно отобразить сведения (значения свойств) из каждой зарегистрированной задачи.

В следующем примере VBScript показано, как выполнить перечисление через коллекцию зарегистрированных задач в корневой папке задач и отобразить имя и состояние для каждой задачи.

'---------------------------------------------------------
' This sample enumerates through the tasks on the local computer and
' displays their name and state.
'---------------------------------------------------------


' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

' Get the task folder that contains the tasks. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")
 
Dim taskCollection
Set taskCollection = rootFolder.GetTasks(0)

Dim numberOfTasks
numberOfTasks = taskCollection.Count

If numberOfTasks = 0 Then 
    Wscript.Echo "No tasks are registered."
Else
    WScript.Echo "Number of tasks registered: " & numberOfTasks
    
    Dim registeredTask
    For Each registeredTask In taskCollection
        WScript.Echo "Task Name: " & registeredTask.Name
    
        Dim taskState 
        Select Case registeredTask.State 
            Case "0"
                taskState = "Unknown"
            Case "1"
                taskState = "Disabled"
            Case "2"
                taskState = "Queued"
            Case "3"
                taskState = "Ready"
            Case "4"
                taskState = "Running"
        End Select

        WScript.Echo "    Task State: " & taskState
    Next
End If

Использование планировщика задач