Поделиться через

Пример триггера загрузки (скрипты)

  • Статья

В этом примере скрипта показано, как создать задачу, которую планируется выполнить в Блокноте при загрузке системы. Задача содержит триггер загрузки, указывающий границу запуска и время задержки для запуска задачи после загрузки системы. Задача также содержит действие, указывающее задачу для выполнения в Блокноте. Задача регистрируется с помощью учетной записи локальной службы в качестве контекста безопасности для запуска задачи.

В следующей процедуре описывается планирование запуска исполняемого файла, например Блокнота, при загрузке системы.

Планирование запуска Блокнота при загрузке системы

  1. Создайте объект TaskService . Этот объект позволяет создать задачу в указанной папке.
  2. Получите папку задач и создайте задачу. Используйте метод TaskService.GetFolder , чтобы получить папку, в которой хранится задача, и метод TaskService.NewTask для создания объекта TaskDefinition , представляющего задачу.
  3. Определите сведения о задаче с помощью объекта TaskDefinition . Используйте свойство TaskDefinition.Settings , чтобы определить параметры, определяющие, как служба планировщика задач выполняет задачу, и свойство TaskDefinition.RegistrationInfo для определения сведений, описывающих задачу.
  4. Создайте триггер входа с помощью свойства TaskDefinition.Triggers . Это свойство предоставляет доступ к объекту TriggerCollection . Используйте метод TriggerCollection.Create (задающий тип триггера, который требуется создать) для создания триггера загрузки. При создании триггера задайте свойства StartBoundary и EndBoundary триггера, чтобы активировать и деактивировать триггер. Можно также указать значение свойства Delay триггера загрузки.
  5. Создайте действие для выполнения задачи с помощью свойства TaskDefinition.Actions . Это свойство предоставляет доступ к объекту ActionCollection . Используйте метод ActionCollection.Create , чтобы указать тип действия, которое требуется создать. В этом примере используется объект ExecAction , представляющий действие, которое запускает исполняемый файл.
  6. Зарегистрируйте задачу с помощью метода TaskFolder.RegisterTaskDefinition . Задача регистрируется с помощью учетной записи локальной службы в качестве контекста безопасности для запуска задачи.

В следующем примере VBScript показано, как запланировать выполнение задачи в Блокноте через 30 секунд после загрузки системы.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe 30 seconds after
' the system is booted.
'---------------------------------------------------------

' A constant that specifies a boot trigger.
const TriggerTypeBoot = 8
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Task will execute Notepad when " & _
    "the computer is booted."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a boot trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeBoot)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime
startTime = "2006-05-02T10:49:02"
endTime = "2006-05-02T10:52:02"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    ' Five minutes
trigger.Id = "BootTriggerId"
trigger.Delay = "PT30S"                ' 30 Seconds   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.
const createOrUpdateTask = 6
call rootFolder.RegisterTaskDefinition( _
    "Test Boot Trigger", taskDefinition, createOrUpdateTask, _
    "Local Service", , 5)

WScript.Echo "Task submitted."

Использование планировщика задач