Пример триггера времени (создание скриптов)

В этом примере скриптов показано, как создать задачу, которая запускает Блокнот в определенное время. Задача содержит триггер на основе времени, указывающий начальную границу для активации задачи, исполняемое действие, запускающее Блокнот, и конечную границу, которая деактивирует задачу.

В следующей процедуре описывается планирование задачи для запуска исполняемого файла в определенное время.

Планирование запуска в Блокноте в определенное время

1. Создайте объект TaskService . Этот объект позволяет создать задачу в указанной папке.
2. Получите папку задач и создайте задачу. Используйте метод TaskService.GetFolder , чтобы получить папку, в которой хранится задача, и метод TaskService.NewTask для создания объекта TaskDefinition , представляющего задачу.
3. Определите сведения о задаче с помощью объекта TaskDefinition . Используйте свойство TaskDefinition.Settings , чтобы определить параметры, определяющие, как служба планировщика задач выполняет задачу, и свойство TaskDefinition.RegistrationInfo для определения сведений, описывающих задачу.
4. Создайте триггер на основе времени с помощью свойства TaskDefinition.Triggers . Это свойство предоставляет доступ к объекту TriggerCollection . Используйте метод TriggerCollection.Create (указывающий тип триггера, который вы хотите создать) для создания триггера на основе времени. При создании триггера установите начальную и конечную границы триггера, чтобы активировать и деактивировать триггер. Начальная граница указывает, когда будет выполнено действие задачи.
5. Создайте действие для выполнения задачи с помощью свойства TaskDefinition.Actions . Это свойство предоставляет доступ к объекту ActionCollection . Используйте метод ActionCollection.Create , чтобы указать тип создаваемого действия. В этом примере используется объект ExecAction , представляющий действие, которое выполняет операцию командной строки.
6. Зарегистрируйте задачу с помощью метода TaskFolder.RegisterTaskDefinition . В этом примере задача будет запускаться в Блокнот в текущее время плюс 30 секунд.

В следующем примере VBScript показано, как запланировать выполнение задачи в Блокноте через 30 секунд после регистрации задачи.

'------------------------------------------------------------------
' This sample schedules a task to start notepad.exe 30 seconds
' from the time the task is registered.
'------------------------------------------------------------------

' A constant that specifies a time-based trigger.
const TriggerTypeTime = 1
' A constant that specifies an executable action.
const ActionTypeExec = 0   


'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at a certain time"
regInfo.Author = "Author Name"

'********************************************************
' Set the principal for the task
Dim principal
Set principal = taskDefinition.Principal

' Set the logon type to interactive logon
principal.LogonType = 3


' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a time-based trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeTime)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime

Dim time
time = DateAdd("s", 30, Now)  'start time = 30 seconds from now
startTime = XmlTime(time)

time = DateAdd("n", 5, Now) 'end time = 5 minutes from now
endTime = XmlTime(time)

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    'Five minutes
trigger.Id = "TimeTriggerId"
trigger.Enabled = True

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test TimeTrigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."



'------------------------------------------------------------------
' Used to get the time for the trigger 
' startBoundary and endBoundary.
' Return the time in the correct format: 
' YYYY-MM-DDTHH:MM:SS. 
'------------------------------------------------------------------
Function XmlTime(t)
    Dim cSecond, cMinute, CHour, cDay, cMonth, cYear
    Dim tTime, tDate

    cSecond = "0" & Second(t)
    cMinute = "0" & Minute(t)
    cHour = "0" & Hour(t)
    cDay = "0" & Day(t)
    cMonth = "0" & Month(t)
    cYear = Year(t)

    tTime = Right(cHour, 2) & ":" & Right(cMinute, 2) & _
        ":" & Right(cSecond, 2)
    tDate = cYear & "-" & Right(cMonth, 2) & "-" & Right(cDay, 2)
    XmlTime = tDate & "T" & tTime 
End Function

Связанные темы

Использование планировщика задач