Поделиться через

Пример ежедневного триггера (создание скриптов)

  • Статья

В этом примере скрипта показано, как создать задачу, которая запускает Блокнот в 8:00 каждый день. Задача содержит ежедневный триггер, указывающий начальную границу для активации триггера и время суток, интервал триггера, указывающий, что задача выполняется каждый день, и конечная граница для отключения триггера. В примере также показано, как задать шаблон повторения для триггера для повторения задачи. Задача также содержит исполняемое действие, запускающее Блокнот.

В следующей процедуре описано, как запланировать выполнение задачи для запуска исполняемого файла в 8:00 каждый день. (Эти шаги соответствуют комментариям к коду, включенным в пример кода.)

Планирование запуска Блокнота в 8:00 каждый день

  1. Создайте объект TaskService . Этот объект позволяет создать задачу в указанной папке.
  2. Получите папку задач и создайте задачу. Используйте метод TaskService.GetFolder , чтобы получить папку, в которой хранится задача, и метод TaskService.NewTask для создания объекта TaskDefinition , представляющего задачу.
  3. Определите сведения о задаче с помощью объекта TaskDefinition . Используйте свойство TaskDefinition.Settings , чтобы определить параметры, определяющие, как служба планировщика задач выполняет задачу, и свойство TaskDefinition.RegistrationInfo для определения сведений, описывающих задачу.
  4. Создайте ежедневный триггер с помощью свойства TaskDefinition.Triggers . Это свойство предоставляет доступ к объекту TriggerCollection , который используется для создания триггера. Используйте метод TriggerCollection.Create (задающий тип триггера, который вы хотите создать) для создания ежедневного триггера. При создании триггера задайте начальную границу для активации триггера и укажите время суток выполнения задачи, интервал между днями и конечную границу для деактивации триггера. В приведенном ниже примере показано, как задать шаблон повторения для триггера для повторения задачи.
  5. Создайте действие для выполнения задачи с помощью свойства TaskDefinition.Actions . Это свойство предоставляет доступ к объекту ActionCollection , используемому для создания действия. Используйте метод ActionCollection.Create , чтобы указать тип создаваемого действия. В этом примере используется объект ExecAction , представляющий действие, которое выполняет операцию командной строки.
  6. Зарегистрируйте задачу с помощью метода TaskFolder.RegisterTaskDefinition . В этом примере задача будет запускаться в Блокноте в 8:00 каждый день.

В следующем примере VBScript показано, как запланировать выполнение задачи в Блокноте каждый день в 8:00.

'------------------------------------------------------------------
' This sample schedules a task to start on a daily basis.
'------------------------------------------------------------------

' A constant that specifies a daily trigger.
const TriggerTypeDaily = 2
' A constant that specifies an executable action.
const ActionTypeExec = 0

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Start notepad at 8:00AM daily"
regInfo.Author = "Administrator"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.Enabled = True
settings.StartWhenAvailable = True
settings.Hidden = False

'********************************************************
' Create a daily trigger. Note that the start boundary 
' specifies the time of day that the task starts and the 
' interval specifies what days the task is run.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeDaily)

' Trigger variables that define when the trigger is active 
' and the time of day that the task is run. The format of 
' this time is YYYY-MM-DDTHH:MM:SS
Dim startTime, endTime

Dim time
startTime = "2006-05-02T08:00:00"  'Task runs at 8:00 AM
endTime = "2015-05-02T08:00:00"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.DaysInterval = 1    'Task runs every day.
trigger.Id = "DailyTriggerId"
trigger.Enabled = True

' Set the task repetition pattern for the task.
' This will repeat the task 5 times.
Dim repetitionPattern
Set repetitionPattern = trigger.Repetition
repetitionPattern.Duration = "PT4M"
repetitionPattern.Interval = "PT1M"

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task to run notepad.exe.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExec )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.

call rootFolder.RegisterTaskDefinition( _
    "Test Daily Trigger", taskDefinition, 6, , , 3)

WScript.Echo "Task submitted."

Использование планировщика задач