Поделиться через

Захват и применение образа Windows с помощью одного файла .WIM

Запись образа Windows (. Файл WIM) и его использование для развертывания Windows на новых устройствах.

Вы можете начать с файла install.wim из ISO-файла дистрибутива Windows, или вы можете обобщить и записать работающий образ Windows в .WIM-файл.

Файлы WIM фиксируют только одну секцию. Обычно можно записать только секцию Windows, а затем использовать файлы из этого образа для настройки остальных секций на диске. Если вы создали настраиваемую конфигурацию разделов, см. статью «Создание и применение разделов Windows, системных и восстановительных».

Схема, на которой показан новый компьютер с пустым жестким диском и одним файлом образа WIM, расширяется и становится несколькими настроенными разделами.

Запись изображения

  1. Если вы загрузили Windows, обобщите образ системы, чтобы его можно было развернуть на других устройствах. Дополнительные сведения см. в статье Sysprep (Generalize) для установки Windows.

  2. Загрузите устройство с помощью Windows PE.

  3. Необязательный Оптимизируйте образ, чтобы сократить время загрузки устройства после применения образа. Оптимизация образа особенно полезна при создании образа, который вы будете развертывать на многих машинах, например, в сценарии сборки для хранения.

    DISM /image:C:\ /optimize-image /boot

  4. Создание образа раздела Windows. Рассмотрим пример.

    Dism /Capture-Image /ImageFile:"D:\Images\Fabrikam.wim" /CaptureDir:C:\ /Name:Fabrikam

    Где D: является USB-накопителем флэш-памяти или другим расположением хранилища файлов.

Применение образа

  1. Загрузите устройство с помощью Windows PE.

  2. Очистка жесткого диска и настройка новых разделов жесткого диска с помощью скрипта. Используйте CreatePartitions-UEFI.txt (или CreatePartitions-BIOS.txt для старых устаревших устройств BIOS).

    diskpart /s CreatePartitions-UEFI.txt

  3. Примените изображения с помощью скрипта.

    D:\ApplyImage.bat D:\Images\Fabrikam.wim

Пример скрипта

Ниже приведен простой пример скрипта, который применяет образ к диску, который был секционирован с помощью одного из скриптов секционирования жестких дисков с шага 2.

Note

Чтобы настроить загрузку для использования Windows UEFI 2023 CA, можно использовать параметр /bootex с командой bcdboot в приведенном ниже примере скрипта.

rem == ApplyImage.bat ==

rem == These commands deploy a specified Windows
rem    image file to the Windows partition, and configure
rem    the system partition.

rem    Usage:   ApplyImage WimFileName 
rem    Example: ApplyImage E:\Images\ThinImage.wim ==

rem == Set high-performance power scheme to speed deployment ==
call powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c

rem == Apply the image to the Windows partition ==
dism /Apply-Image /ImageFile:%1 /Index:1 /ApplyDir:W:\

rem == Copy boot files to the System partition ==
rem == Note: specify /bootex parameter to use Windows UEFI 2023 CA
W:\Windows\System32\bcdboot W:\Windows /s S:

:rem == Copy the Windows RE image to the
:rem    Windows RE Tools partition ==
md R:\Recovery\WindowsRE
xcopy /h W:\Windows\System32\Recovery\Winre.wim R:\Recovery\WindowsRE\

:rem == Register the location of the recovery tools ==
W:\Windows\System32\Reagentc /Setreimage /Path R:\Recovery\WindowsRE /Target W:\Windows

:rem == Verify the configuration status of the images. ==
W:\Windows\System32\Reagentc /Info /Target W:\Windows

Развертывание Windows с помощью полного обновления флэш-памяти (FFU)

Создание образа и применение разделов Windows, системного и восстановительного

Настройка секций жестких дисков на основе UEFI/GPT

Настройка разделов жестких дисков на основе BIOS/MBR

Командная строка BCDboot — параметры

Параметры командной строки REAgentC

  • Last updated on