Примечание
Для доступа к этой странице требуется авторизация. Вы можете попробовать войти или изменить каталоги.
Для доступа к этой странице требуется авторизация. Вы можете попробовать изменить каталоги.
В следующем разделе описан пример дизассембли.
Исходный код
Ниже приведен код для функции, которая будет проанализирована.
HRESULT CUserView::CloseView(void)
{
if (m_fDestroyed) return S_OK;
BOOL fViewObjectChanged = FALSE;
ReleaseAndNull(&m_pdtgt);
if (m_psv) {
m_psb->EnableModelessSB(FALSE);
if(m_pws) m_pws->ViewReleased();
IShellView* psv;
HWND hwndCapture = GetCapture();
if (hwndCapture && hwndCapture == m_hwnd) {
SendMessage(m_hwnd, WM_CANCELMODE, 0, 0);
}
m_fHandsOff = TRUE;
m_fRecursing = TRUE;
NotifyClients(m_psv, NOTIFY_CLOSING);
m_fRecursing = FALSE;
m_psv->UIActivate(SVUIA_DEACTIVATE);
psv = m_psv;
m_psv = NULL;
ReleaseAndNull(&_pctView);
if (m_pvo) {
IAdviseSink *pSink;
if (SUCCEEDED(m_pvo->GetAdvise(NULL, NULL, &pSink)) && pSink) {
if (pSink == (IAdviseSink *)this)
m_pvo->SetAdvise(0, 0, NULL);
pSink->Release();
}
fViewObjectChanged = TRUE;
ReleaseAndNull(&m_pvo);
}
if (psv) {
psv->SaveViewState();
psv->DestroyViewWindow();
psv->Release();
}
m_hwndView = NULL;
m_fHandsOff = FALSE;
if (m_pcache) {
GlobalFree(m_pcache);
m_pcache = NULL;
}
m_psb->EnableModelessSB(TRUE);
CancelPendingActions();
}
ReleaseAndNull(&_psf);
if (fViewObjectChanged)
NotifyViewClients(DVASPECT_CONTENT, -1);
if (m_pszTitle) {
LocalFree(m_pszTitle);
m_pszTitle = NULL;
}
SetRect(&m_rcBounds, 0, 0, 0, 0);
return S_OK;
}
Код сборки
Этот раздел содержит аннотированный пример дизассембли.
Функции, использующие регистр ebp в качестве указателя кадра, начинаются следующим образом:
HRESULT CUserView::CloseView(void)
SAMPLE!CUserView__CloseView:
71517134 55 push ebp
71517135 8bec mov ebp,esp
Это настраивает стековый кадр так, чтобы функция могла получить доступ к своим параметрам в виде положительных смещений от ebp, а локальные переменные — в виде отрицательных смещений.
Это метод в закрытом COM-интерфейсе, поэтому используется соглашение о вызове __stdcall. Это означает, что параметры передаются справа налево (в данном случае их нет), а затем передаётся указатель "this", и вызывается функция. Таким образом, при входе в функцию стек выглядит следующим образом:
[esp+0] = return address
[esp+4] = this
После двух предыдущих инструкций параметры доступны следующим образом:
[ebp+0] = previous ebp pushed on stack
[ebp+4] = return address
[ebp+8] = this
Для функции, которая использует ebp в качестве указателя кадров, первый отправленный параметр доступен в [ebp+8]; последующие параметры доступны по более высоким адресам DWORD.
71517137 51 push ecx
71517138 51 push ecx
Эта функция требует только двух локальных переменных стека, поэтому операция sub esp, 8. Затем отправленные значения доступны как [ebp-4] и [ebp-8].
Для функции, которая использует ebp в качестве указателя кадра, локальные переменные стека доступны при отрицательных смещениях из регистра ebp .
71517139 56 push esi
Теперь компилятор сохраняет регистры, необходимые для сохранения во всех вызовах функций. Фактически, сохраняет их по частям, перемежаясь с первой строкой основного кода.
7151713a 8b7508 mov esi,[ebp+0x8] ; esi = this
7151713d 57 push edi ; save another registers
Так происходит, что CloseView — это метод в ViewState, который находится в смещение 12 в базовом объекте. Следовательно, это указатель на класс ViewState, хотя при возникновении путаницы с другим базовым классом он будет более тщательно указан как (ViewState*).
if (m_fDestroyed)
7151713e 33ff xor edi,edi ; edi = 0
Операция XOR регистра с самим собой является стандартным способом его обнуления.
71517140 39beac000000 cmp [esi+0xac],edi ; this->m_fDestroyed == 0?
71517146 7407 jz NotDestroyed (7151714f) ; jump if equal
Инструкция cmp сравнивает два значения (вычитая их). Инструкция jz проверяет, равен ли результат нулю, указывая, что два сравниваемых значения равны.
Инструкция cmp сравнивает два значения; последующая инструкция j выполняет переход на основе результата этого сравнения.
return S_OK;
71517148 33c0 xor eax,eax ; eax = 0 = S_OK
7151714a e972010000 jmp ReturnNoEBX (715172c1) ; return, do not pop EBX
Компилятор отложил сохранение регистра EBX до последующих версий функции, поэтому если программа собирается "досрочно выйти" на этом тесте, то путь выхода должен быть тем, который не восстанавливает EBX.
BOOL fViewObjectChanged = FALSE;
ReleaseAndNull(&m_pdtgt);
Выполнение этих двух строк кода чередуется, поэтому обратите внимание.
NotDestroyed:
7151714f 8d86c0000000 lea eax,[esi+0xc0] ; eax = &m_pdtgt
Инструкция lea вычисляет адрес эффекта доступа к памяти и сохраняет его в назначении. Фактический адрес памяти не разыменован.
Инструкция lea принимает адрес переменной.
71517155 53 push ebx
Перед тем, как регистр EBX будет поврежден, следует сохранить его.
71517156 8b1d10195071 mov ebx,[_imp__ReleaseAndNull]
Так как вы будете часто вызывать ReleaseAndNull , рекомендуется кэшировать свой адрес в EBX.
7151715c 50 push eax ; parameter to ReleaseAndNull
7151715d 897dfc mov [ebp-0x4],edi ; fViewObjectChanged = FALSE
71517160 ffd3 call ebx ; call ReleaseAndNull
if (m_psv) {
71517162 397e74 cmp [esi+0x74],edi ; this->m_psv == 0?
71517165 0f8411010000 je No_Psv (7151727c) ; jump if zero
Помните, что вы отнулили регистрацию EDI в некоторое время назад, и что EDI является регистром, сохраненным в вызовах функций (поэтому вызов ReleaseAndNull не изменил его). Таким образом, он по-прежнему содержит нулевое значение, и его можно использовать для быстрого тестирования на ноль.
m_psb->EnableModelessSB(FALSE);
7151716b 8b4638 mov eax,[esi+0x38] ; eax = this->m_psb
7151716e 57 push edi ; FALSE
7151716f 50 push eax ; "this" for callee
71517170 8b08 mov ecx,[eax] ; ecx = m_psb->lpVtbl
71517172 ff5124 call [ecx+0x24] ; __stdcall EnableModelessSB
Приведенный выше шаблон представляет собой признак вызова метода COM.
Вызовы методов COM довольно популярны, поэтому рекомендуется научиться распознавать их. В частности, можно распознать три метода IUnknown непосредственно из смещения Vtable: QueryInterface=0, AddRef=4 и Release=8.
if(m_pws) m_pws->ViewReleased();
71517175 8b8614010000 mov eax,[esi+0x114] ; eax = this->m_pws
7151717b 3bc7 cmp eax,edi ; eax == 0?
7151717d 7406 jz NoWS (71517185) ; if so, then jump
7151717f 8b08 mov ecx,[eax] ; ecx = m_pws->lpVtbl
71517181 50 push eax ; "this" for callee
71517182 ff510c call [ecx+0xc] ; __stdcall ViewReleased
NoWS:
HWND hwndCapture = GetCapture();
71517185 ff15e01a5071 call [_imp__GetCapture] ; call GetCapture
Косвенные вызовы через глобальные системы — это способ реализации импорта функций в Microsoft Win32. Загрузчик исправляет глобальные значения, чтобы указать фактический адрес целевого объекта. Это удобный способ сориентироваться, когда вы расследуете сбой машины. Найдите вызовы импортированных функций и в целевом объекте. Обычно у вас будет имя импортированной функции, которое вы можете использовать, чтобы определить своё местоположение в исходном коде.
if (hwndCapture && hwndCapture == m_hwnd) {
SendMessage(m_hwnd, WM_CANCELMODE, 0, 0);
}
7151718b 3bc7 cmp eax,edi ; hwndCapture == 0?
7151718d 7412 jz No_Capture (715171a1) ; jump if zero
Возвращаемое значение функции помещается в регистр EAX.
7151718f 8b4e44 mov ecx,[esi+0x44] ; ecx = this->m_hwnd
71517192 3bc1 cmp eax,ecx ; hwndCapture = ecx?
71517194 750b jnz No_Capture (715171a1) ; jump if not
71517196 57 push edi ; 0
71517197 57 push edi ; 0
71517198 6a1f push 0x1f ; WM_CANCELMODE
7151719a 51 push ecx ; hwndCapture
7151719b ff1518195071 call [_imp__SendMessageW] ; SendMessage
No_Capture:
m_fHandsOff = TRUE;
m_fRecursing = TRUE;
715171a1 66818e0c0100000180 or word ptr [esi+0x10c],0x8001 ; set both flags at once
NotifyClients(m_psv, NOTIFY_CLOSING);
715171aa 8b4e20 mov ecx,[esi+0x20] ; ecx = (CNotifySource*)this.vtbl
715171ad 6a04 push 0x4 ; NOTIFY_CLOSING
715171af 8d4620 lea eax,[esi+0x20] ; eax = (CNotifySource*)this
715171b2 ff7674 push [esi+0x74] ; m_psv
715171b5 50 push eax ; "this" for callee
715171b6 ff510c call [ecx+0xc] ; __stdcall NotifyClients
Обратите внимание, что вам пришлось изменить указатель "this" при вызове метода в другом базовом классе, отличном от собственного.
m_fRecursing = FALSE;
715171b9 80a60d0100007f and byte ptr [esi+0x10d],0x7f
m_psv->UIActivate(SVUIA_DEACTIVATE);
715171c0 8b4674 mov eax,[esi+0x74] ; eax = m_psv
715171c3 57 push edi ; SVUIA_DEACTIVATE = 0
715171c4 50 push eax ; "this" for callee
715171c5 8b08 mov ecx,[eax] ; ecx = vtbl
715171c7 ff511c call [ecx+0x1c] ; __stdcall UIActivate
psv = m_psv;
m_psv = NULL;
715171ca 8b4674 mov eax,[esi+0x74] ; eax = m_psv
715171cd 897e74 mov [esi+0x74],edi ; m_psv = NULL
715171d0 8945f8 mov [ebp-0x8],eax ; psv = eax
Первая локальная переменная — psv.
ReleaseAndNull(&_pctView);
715171d3 8d466c lea eax,[esi+0x6c] ; eax = &_pctView
715171d6 50 push eax ; parameter
715171d7 ffd3 call ebx ; call ReleaseAndNull
if (m_pvo) {
715171d9 8b86a8000000 mov eax,[esi+0xa8] ; eax = m_pvo
715171df 8dbea8000000 lea edi,[esi+0xa8] ; edi = &m_pvo
715171e5 85c0 test eax,eax ; eax == 0?
715171e7 7448 jz No_Pvo (71517231) ; jump if zero
Обратите внимание, что компилятор спекулятивно подготовил адрес элемента m_pvo , так как вы собираетесь использовать его часто в течение некоторого времени. Таким образом, наличие адреса приведет к более компактному коду.
if (SUCCEEDED(m_pvo->GetAdvise(NULL, NULL, &pSink)) && pSink) {
715171e9 8b08 mov ecx,[eax] ; ecx = m_pvo->lpVtbl
715171eb 8d5508 lea edx,[ebp+0x8] ; edx = &pSink
715171ee 52 push edx ; parameter
715171ef 6a00 push 0x0 ; NULL
715171f1 6a00 push 0x0 ; NULL
715171f3 50 push eax ; "this" for callee
715171f4 ff5120 call [ecx+0x20] ; __stdcall GetAdvise
715171f7 85c0 test eax,eax ; test bits of eax
715171f9 7c2c jl No_Advise (71517227) ; jump if less than zero
715171fb 33c9 xor ecx,ecx ; ecx = 0
715171fd 394d08 cmp [ebp+0x8],ecx ; _pSink == ecx?
71517200 7425 jz No_Advise (71517227)
Обратите внимание, что компилятор пришел к выводу о том, что входящий параметр "этот" не требуется (поскольку он давно скрыт в регистрЕ ESI). Таким образом, он повторно использует память в качестве локальной переменной pSink.
Если функция использует кадр EBP, то входящие параметры находятся на положительных смещениях относительно EBP, а локальные переменные размещаются на отрицательных смещениях. Но, как и в этом случае, компилятор может повторно использовать эту память для любой цели.
Если вы уделяете пристальное внимание, вы увидите, что компилятор мог бы оптимизировать этот код немного лучше. Это могло бы отложить инструкцию lea edi, [esi+0xa8] до тех пор, пока двух инструкций push 0x0, заменив их на push edi. Это могло бы сохранить 2 байта.
if (pSink == (IAdviseSink *)this)
Эти следующие несколько строк компенсируют тот факт, что в C++, (IAdviseSink *)NULL по-прежнему должно быть NULL. Так что если ваш объект "this" действительно "(ViewState*)NULL", то результат приведения должен быть NULL, а не разница между IAdviseSink и IBrowserService.
71517202 8d46ec lea eax,[esi-0x14] ; eax = -(IAdviseSink*)this
71517205 8d5614 lea edx,[esi+0x14] ; edx = (IAdviseSink*)this
71517208 f7d8 neg eax ; eax = -eax (sets carry if != 0)
7151720a 1bc0 sbb eax,eax ; eax = eax - eax - carry
7151720c 23c2 and eax,edx ; eax = NULL or edx
Несмотря на то, что в Pentium есть инструкция условного выполнения, базовая архитектура i386 её не имеет, поэтому компилятор использует определенные методы для имитации инструкции условного перемещения без переходов.
Общим шаблоном условной оценки является следующее:
neg r
sbb r, r
and r, (val1 - val2)
add r, val2
NEG устанавливает флаг переноса, если r ненулевой, так как NEG получает отрицательное значение, вычитая его из нуля. И вычитание из нуля создаст заимствование (задать перенос), если вычитаете ненулевое значение. Он также повреждает значение в регистре r , но это приемлемо, потому что вы готовы перезаписать его в любом случае.
Затем инструкция sbb r вычитает значение от самого себя, что всегда приводит к нулю. Однако он также вычитает бит переноски (заимствования), поэтому чистый результат заключается в том, чтобы задать r равным нулю или -1, в зависимости от того, была ли переноска ясной или заданной соответственно.
Таким образом , sbb r, r задает значение r равным нулю, если исходное значение r равно нулю или -1, если исходное значение было ненулевое.
Третья инструкция применяет маску. Так как регистр r равен нулю или -1, "это" служит либо для сохранения регистр r равным нулю, либо для изменения значения r с -1 на (val1 - val1). При этом, логическая операция AND с любым значением и -1 сохраняет исходное значение.
Таким образом, результат "and r, (val1 - val1 - val1)" заключается в том, чтобы задать значение r равным нулю, если исходное значение r было равно нулю, или "(val1 - val2)", если исходное значение r было ненулевое.
Наконец, вы добавляете val2 в r, в результате чего val2 или (val1 - val2) + val2 = val1.
Таким образом, конечный результат этой серии инструкций заключается в том, чтобы задать r val2, если изначально он был нулевым или val1, если он был ненулевой. Это эквивалент сборки r = r ? val1 : val2.
В этом конкретном случае можно увидеть, что val2 = 0 и val1 = (IAdviseSink*)this. (Обратите внимание, что компилятор опустил окончательную инструкцию add eax, 0, так как она не имеет эффекта.)
7151720e 394508 cmp [ebp+0x8],eax ; pSink == (IAdviseSink*)this?
71517211 750b jnz No_SetAdvise (7151721e) ; jump if not equal
Ранее в этом разделе вы задали EDI на адрес элемента m_pvo. Теперь вы будете использовать его. Вы также ранее обнулили регистр ECX.
m_pvo->SetAdvise(0, 0, NULL);
71517213 8b07 mov eax,[edi] ; eax = m_pvo
71517215 51 push ecx ; NULL
71517216 51 push ecx ; 0
71517217 51 push ecx ; 0
71517218 8b10 mov edx,[eax] ; edx = m_pvo->lpVtbl
7151721a 50 push eax ; "this" for callee
7151721b ff521c call [edx+0x1c] ; __stdcall SetAdvise
No_SetAdvise:
pSink->Release();
7151721e 8b4508 mov eax,[ebp+0x8] ; eax = pSink
71517221 50 push eax ; "this" for callee
71517222 8b08 mov ecx,[eax] ; ecx = pSink->lpVtbl
71517224 ff5108 call [ecx+0x8] ; __stdcall Release
No_Advise:
Все эти вызовы метода COM должны выглядеть очень знакомыми.
Оценка следующих двух утверждений перемежается. Не забывайте, что EBX содержит адрес ReleaseAndNull.
fViewObjectChanged = TRUE;
ReleaseAndNull(&m_pvo);
71517227 57 push edi ; &m_pvo
71517228 c745fc01000000 mov dword ptr [ebp-0x4],0x1 ; fViewObjectChanged = TRUE
7151722f ffd3 call ebx ; call ReleaseAndNull
No_Pvo:
if (psv) {
71517231 8b7df8 mov edi,[ebp-0x8] ; edi = psv
71517234 85ff test edi,edi ; edi == 0?
71517236 7412 jz No_Psv2 (7151724a) ; jump if zero
psv->SaveViewState();
71517238 8b07 mov eax,[edi] ; eax = psv->lpVtbl
7151723a 57 push edi ; "this" for callee
7151723b ff5034 call [eax+0x34] ; __stdcall SaveViewState
Ниже приведены дополнительные вызовы метода COM.
psv->DestroyViewWindow();
7151723e 8b07 mov eax,[edi] ; eax = psv->lpVtbl
71517240 57 push edi ; "this" for callee
71517241 ff5028 call [eax+0x28] ; __stdcall DestroyViewWindow
psv->Release();
71517244 8b07 mov eax,[edi] ; eax = psv->lpVtbl
71517246 57 push edi ; "this" for callee
71517247 ff5008 call [eax+0x8] ; __stdcall Release
No_Psv2:
m_hwndView = NULL;
7151724a 83667c00 and dword ptr [esi+0x7c],0x0 ; m_hwndView = 0
Применение операции И к ячейке памяти с нулем эквивалентно установке ее в ноль, поскольку любое значение, И ноль, равно нулю. Компилятор использует эту форму, так как, несмотря на то, что она медленнее, она гораздо короче, чем эквивалентная инструкция mov . (Этот код оптимизирован для размера, а не скорости.)
m_fHandsOff = FALSE;
7151724e 83a60c010000fe and dword ptr [esi+0x10c],0xfe
if (m_pcache) {
71517255 8b4670 mov eax,[esi+0x70] ; eax = m_pcache
71517258 85c0 test eax,eax ; eax == 0?
7151725a 740b jz No_Cache (71517267) ; jump if zero
GlobalFree(m_pcache);
7151725c 50 push eax ; m_pcache
7151725d ff15b4135071 call [_imp__GlobalFree] ; call GlobalFree
m_pcache = NULL;
71517263 83667000 and dword ptr [esi+0x70],0x0 ; m_pcache = 0
No_Cache:
m_psb->EnableModelessSB(TRUE);
71517267 8b4638 mov eax,[esi+0x38] ; eax = this->m_psb
7151726a 6a01 push 0x1 ; TRUE
7151726c 50 push eax ; "this" for callee
7151726d 8b08 mov ecx,[eax] ; ecx = m_psb->lpVtbl
7151726f ff5124 call [ecx+0x24] ; __stdcall EnableModelessSB
CancelPendingActions();
Чтобы вызвать CancelPendingActions, необходимо перейти с (ViewState*) на (CUserView*) этот объект. Обратите внимание также, что CancelPendingActions использует соглашение об вызове __thiscall вместо __stdcall. Согласно __thiscall, указатель "this" передается в реестре ECX вместо того, чтобы передаваться на стек.
71517272 8d4eec lea ecx,[esi-0x14] ; ecx = (CUserView*)this
71517275 e832fbffff call CUserView::CancelPendingActions (71516dac) ; __thiscall
ReleaseAndNull(&_psf);
7151727a 33ff xor edi,edi ; edi = 0 (for later)
No_Psv:
7151727c 8d4678 lea eax,[esi+0x78] ; eax = &_psf
7151727f 50 push eax ; parameter
71517280 ffd3 call ebx ; call ReleaseAndNull
if (fViewObjectChanged)
71517282 397dfc cmp [ebp-0x4],edi ; fViewObjectChanged == 0?
71517285 740d jz NoNotifyViewClients (71517294) ; jump if zero
NotifyViewClients(DVASPECT_CONTENT, -1);
71517287 8b46ec mov eax,[esi-0x14] ; eax = ((CUserView*)this)->lpVtbl
7151728a 8d4eec lea ecx,[esi-0x14] ; ecx = (CUserView*)this
7151728d 6aff push 0xff ; -1
7151728f 6a01 push 0x1 ; DVASPECT_CONTENT = 1
71517291 ff5024 call [eax+0x24] ; __thiscall NotifyViewClients
NoNotifyViewClients:
if (m_pszTitle)
71517294 8b8680000000 mov eax,[esi+0x80] ; eax = m_pszTitle
7151729a 8d9e80000000 lea ebx,[esi+0x80] ; ebx = &m_pszTitle (for later)
715172a0 3bc7 cmp eax,edi ; eax == 0?
715172a2 7409 jz No_Title (715172ad) ; jump if zero
LocalFree(m_pszTitle);
715172a4 50 push eax ; m_pszTitle
715172a5 ff1538125071 call [_imp__LocalFree]
m_pszTitle = NULL;
Помните, что EDI по-прежнему равен нулю, и EBX по-прежнему &m_pszTitle, так как эти регистры сохраняются вызовами функций.
715172ab 893b mov [ebx],edi ; m_pszTitle = 0
No_Title:
SetRect(&m_rcBounds, 0, 0, 0, 0);
715172ad 57 push edi ; 0
715172ae 57 push edi ; 0
715172af 57 push edi ; 0
715172b0 81c6fc000000 add esi,0xfc ; esi = &this->m_rcBounds
715172b6 57 push edi ; 0
715172b7 56 push esi ; &m_rcBounds
715172b8 ff15e41a5071 call [_imp__SetRect]
Обратите внимание, что вам больше не нужно значение «this», поэтому компилятор использует команду add, чтобы изменить его непосредственно, вместо использования отдельного регистра для хранения адреса. Это на самом деле улучшение производительности из-за конвейерной обработки Pentium u/v, так как канал v может выполнять арифметические, но не адресные вычисления.
return S_OK;
715172be 33c0 xor eax,eax ; eax = S_OK
Наконец, вы восстановите регистры, которые необходимо сохранить, очистите стек, вернитесь к вызывающему и удалите входящие параметры.
715172c0 5b pop ebx ; restore
ReturnNoEBX:
715172c1 5f pop edi ; restore
715172c2 5e pop esi ; restore
715172c3 c9 leave ; restores EBP and ESP simultaneously
715172c4 c20400 ret 0x4 ; return and clear parameters