SET FMTONLY (Transact-SQL)

Статья
07/05/2024

Область применения: SQL Server База данных SQL Azure Управляемый экземпляр SQL Azure конечной точке аналитики платформы Аналитики Azure Synapse Analytics (PDW) в Microsoft Fabric Хранилище в Microsoft Fabric

Возвращает клиенту только метаданные. Может использоваться для тестирования формата ответа без фактического выполнения запроса.

Примечание.

Не используйте эту функцию. Эта функция заменена следующими:

Соглашения о синтаксисе Transact-SQL

Синтаксис

SET FMTONLY { ON | OFF }

Замечания

Когда FMTONLY является ON, возвращается набор строк с именами столбцов, но не строки данных.

SET FMTONLY ON не оказывает влияния при анализе пакета Transact-SQL. Эффект возникает во время выполнения.

Значение по умолчанию — OFF.

Разрешения

Требуется членство в роли public.

Примеры

В следующем примере кода Transact-SQL FMTONLY задается как ON. Этот параметр заставляет SQL Server возвращать только метаданные о выбранных столбцах. А именно, возвращаются имена столбцов. Строки данных не возвращаются.

В примере тестовое выполнение хранимой процедуры prc_gm29 возвращает следующее:

Несколько наборов строк.
Столбцы из нескольких таблиц в одной из его инструкций SELECT.

SET NOCOUNT ON;
GO

DROP PROCEDURE IF EXISTS prc_gm29;

DROP TABLE IF EXISTS #tabTemp41;
DROP TABLE IF EXISTS #tabTemp42;
GO

CREATE TABLE #tabTemp41
(
   KeyInt41        INT           NOT NULL,
   Name41          NVARCHAR(16)  NOT NULL,
   TargetDateTime  DATETIME      NOT NULL  DEFAULT GetDate()
);

CREATE TABLE #tabTemp42
(
   KeyInt42 INT          NOT NULL,   -- JOIN-able to KeyInt41.
   Name42   NVARCHAR(16) NOT NULL
);
GO

INSERT INTO #tabTemp41 (KeyInt41, Name41) VALUES (10, 't41-c');
INSERT INTO #tabTemp42 (KeyInt42, Name42) VALUES (10, 't42-p');
GO

CREATE PROCEDURE prc_gm29
AS
BEGIN
SELECT * FROM #tabTemp41;
SELECT * FROM #tabTemp42;

SELECT t41.KeyInt41, t41.TargetDateTime, t41.Name41, t42.Name42
   FROM
                 #tabTemp41 AS t41
      INNER JOIN #tabTemp42 AS t42 on t42.KeyInt42 = t41.KeyInt41
END;
GO

SET DATEFORMAT mdy;

SET FMTONLY ON;
EXECUTE prc_gm29;   -- Returns multiple tables.
SET FMTONLY OFF;
GO

DROP PROCEDURE IF EXISTS prc_gm29;

DROP TABLE IF EXISTS #tabTemp41;
DROP TABLE IF EXISTS #tabTemp42;
GO

/****  Actual Output:
[C:\JunkM\]
>> osql.exe -S myazuresqldb.database.windows.net -U somebody -P secret -d MyDatabase -i C:\JunkM\Issue-2246-a.SQL 

 KeyInt41    Name41           TargetDateTime
 ----------- ---------------- -----------------------

 KeyInt42    Name42
 ----------- ----------------

 KeyInt41    TargetDateTime          Name41           Name42
 ----------- ----------------------- ---------------- ----------------


[C:\JunkM\]
>>
****/

См. также

Инструкции SET (Transact-SQL)

Поделиться через