Анализ формируемых системой журналов с помощью Application Insights

Подключите свои приложения на основе холста к Application Insights, которая является функцией Azure Monitor. Application Insights включает средства аналитики, которые помогают диагностировать проблемы и понимать поведение пользователей в приложениях. Используйте собранную информацию для принятия более обоснованных бизнес-решений и повышения качества приложений.

Предварительные требования

• Вам нужен доступ к порталу Azure.
• Вам нужные разрешения на создание ресурсов Azure.

Создание ресурса Application Insights

Отправляйте создаваемые системой журналы из приложения, создав ресурс Application Insights для хранения событий.

Узнайте, как создать ресурс на основе рабочей области для Application Insights на портале Azure.

Подключение приложения к Application Insights

1. Выполните вход в Power Apps.

2. Откройте приложение для его редактирования.

3. Выберите объект Приложение из левого дерева навигации и вставьте Строку подключения из вашего ресурса Application Insights.

   

4. Выполните действия Сохранить и Опубликовать для приложения.

5. Воспроизведите опубликованное приложение и просмотрите различные экраны.

Когда вы просматриваете экраны приложения, события автоматически регистрируются в Application Insights. К ним относятся такие сведения об использовании, как:

• Откуда пользователи производят доступ в приложение
• Какие устройства используют пользователи
• Типы браузеров, которые используют пользователи

Просмотр событий в Application Insights

1. Войдите в портал Azure и откройте ресурс Application Insights, который вы создали ранее.

2. В левой области навигации выберите Пользователи в разделе Потребление.

   Заметка

   Представление Пользователи показывает сведения об использовании приложения, такие как:

   • Количество пользователей, просмотревших приложение
   • Количество сеансов пользователей
   • Количество зарегистрированных событий
   • Сведения об операционных системах и версиях браузера пользователей
   • Регион и местонахождение пользователей

   Узнайте больше об анализе пользователей, сеансов и событий в Application Insights.

3. Выберите сеанс пользователя, чтобы просмотреть конкретные сведения, такие как продолжительность сеанса и посещенные экраны.

   

4. В левой области навигации выберите События в разделе Потребление. Вы можете просмотреть сводку всех экранов, просмотренных во всех сеансах приложения.

   

Создание пользовательских событий трассировки

Записывайте пользовательские трассировки в Application Insights для анализа информации, специфической для вашего приложения. Функция трассировки позволяет собирать следующие данные:

• Детальная информация об использовании элементов управления на экранах
• Какие конкретные пользователи осуществляют доступ к вашему приложению
• Какие ошибки происходят

Трассировка помогает диагностировать проблемы, отправляя информацию о том, как пользователи просматривают приложение и выполняют действия. Сообщения трассировки, отправляемые в Application Insights, могут быть трех степеней серьезности:

• Информация
• Предупреждение
• Error

Отправьте сообщение трассировки с соответствующей серьезностью в зависимости от ситуации. Вы можете запрашивать данные и выполнять определенные действия в зависимости от серьезности.

Создайте в приложении компонент для сбора отзывов на каждом экране и записывайте события в Application Insights.

1. Выполните вход в Power Apps.

2. Выберите Приложения в левой области переходов. Из списка приложений выберите приложение Kudos, затем выберите Изменить.

   Заметка

   Вы также можете создать новое приложение или изменить любое существующее приложение.

3. Выберите Компоненты в Представлении в виде дерева:

   

4. Выберите Создать компонент, затем измените ширину на 200 и высоту на 75:

   

5. Выберите Вставить в меню, затем выберите Значки ,чтобы добавить Эмодзи — нахмуренный смайлик и Эмодзи — улыбка:

   

6. Выберите Создать пользовательское свойство, чтобы создать собственное свойство:

   

7. Введите свойство Имя и Отображаемое имя (например, FeedbackSceen).

8. Введите свойство Описание.

9. Выберите Тип свойства как Вход и Тип данных как Экран:

   

   Заметка

   Свойство ввода позволяет вам захватывать имя экрана и его компонент, чтобы зарегистрировать эту информацию в Application Insights.

10. Выберите компонент в Представлении дерева, выберите Другие действия (…), затем выберите Переименовать, чтобы задать понятное имя компонента, такое как FeedbackComponent.

    

11. Выберите значки, выберите Другие действия (…), затем выберите Переименовать, чтобы переименовать значки на понятные имена, такие как FrownIcon и SmileIcon.

12. Выберите FrownIcon, выберите свойство OnSelect и введите следующее выражение в строку формул:

    Trace(
       "App Feedback",
       TraceSeverity.Information,
           {
             UserName: User().FullName,
             UserEmail: User().Email,
             Screen: FeedbackComponent.FeedbackScreen.Name,
             FeedbackValue: "-1"
           }
         );
    Notify("Thanks for your feedback!");
    

    

    Заметка

    Формула отправляет UserName, UserEmail, Экран и Feedback (со значением -1) в Application Insights.

13. Выберите SmileIcon, выберите свойство OnSelect, затем введите следующее выражение в строку формул:

    Trace(
       "App Feedback",
       TraceSeverity.Information,
           {
             UserName: User().FullName,
             UserEmail: User().Email,
             Screen: FeedbackComponent.FeedbackScreen.Name,
             FeebackValue: "1"
           }
         );
    Notify("Thanks for your feedback!");
    

14. Добавьте компонент на один из экранов в вашем приложении:

    

15. Выберите Сохранить, затем выберите Опубликовать, чтобы сохранить и опубликовать ваше приложение.

16. Воспроизведите опубликованное приложение и отправьте отзыв в виде улыбки или недовольства с его экранов.

    Внимание!

    Вы должны воспроизвести опубликованное приложение, чтобы отправить события в Application Insights. События не отправляются в Application Insights, когда вы предварительно просматриваете приложение в Power Apps Studio.

    

Анализ пользовательских данных в Application Insights

Теперь вы можете начать анализ данных, отправленных вами с помощью функции Trace из вашего приложения в Application Insights.

1. Войдите на портал Azure и откройте ресурс Application Insights, который вы создали ранее.

   

2. Выберите Журналы в разделе Мониторинг на левой панели навигации.

   

3. Введите следующий запрос и выберите Выполнить, чтобы просмотреть отзыв из приложения:

   traces
   | where message == "App Feedback"
   | order by timestamp
   

   

4. Выберите строку в результатах и разверните поле customDimensions.

   Значения параметров Экран, UserName, UserEmail и FeedbackValue для события OnSelect значка улыбки или недовольства в вашем компоненте записаны. Для каждого события, отправленного в Application Insights, также регистрируются такие значения, как appId, appName и appSessionId.

   

5. Используйте следующий пример запроса ,чтобы развернуть свойства пользовательских аналитик JSON и проецировать столбцы в представлении результатов.

   traces
       | extend customdims = parse_json(customDimensions)
       | where message == "App Feedback"
       | project timestamp
           , message
           , AppName = customdims.['ms-appName']
           , AppId = customdims.['ms-appId']
           , FeedbackFrom = customdims.UserEmail
           , Screen = customdims.Screen
           , FeedbackValue = customdims.FeedbackValue
       | order by timestamp desc
   

   

   Совет

   Регистрация запросов — мощный инструмент. Используйте его для объединения нескольких таблиц, агрегирования больших объемов данных и выполнения сложных операций. Узнайте больше о запросах журналов.

Анализ данных жизненного цикла приложения в Application Insights

Сводное событие сеанс регистрируется один раз в сеанс и содержит сведения об успешном открытии приложения, оптимальных и неоптимальных сеансах открытия приложения, а также метриках производительности открытия приложения.

Ограничения

Эти события действительны для приложений на основе холста, работающих в веб-браузере. Они недоступны для приложений, работающих в Power Apps Mobile, и их значения могут не всегда быть доступными или точными для пользовательских страниц.

Ниже приведен пример запроса, показывающий, как получить доступ к итоговому событию сеанс и ко всем доступным полям:

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
// 
| extend cd = parse_json(customDimensions) 
// 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend successfulAppLaunch = tobool(sessionSummary["successfulAppLaunch"]) 
| extend unsuccessfulReason = tostring(sessionSummary["unsuccessfulReason"]) 
| extend appLoadResult = tostring(sessionSummary["appLoadResult"]) 
| extend appLoadNonOptimalReason = 
tostring(sessionSummary["appLoadNonOptimalReason"]) 
// 
| extend timeToAppInteractive = todouble(sessionSummary["timeToAppInteractive"]) 
| extend timeToAppFullLoad = todouble(sessionSummary["timeToAppFullLoad"]) 
// 
| project 
    timestamp, 
    session_Id, 
    successfulAppLaunch, 
    unsuccessfulReason, 
    appLoadResult, 
    appLoadNonOptimalReason, 
    timeToAppInteractive, 
    timeToAppFullLoad 
| limit 5 

Следующие поля помогают измерить успешность открытия приложения и задержку маркеров производительности, связанных с взаимодействием с конечными пользователями.

Примеры запросов

Коэффициент успешных открытий приложения

Этот запрос покажет процент успешных открытий приложения по дням. Это можно использовать для оценки пиков или тенденций в проблемах, с которыми могут сталкиваться пользователи

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
| extend cd = parse_json(customDimensions) 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend successfulAppLaunch = tobool(sessionSummary["successfulAppLaunch"]) 
| summarize 
sessions_total = dcount(session_Id), 
sessions_success = dcountif(session_Id, successfulAppLaunch == true) 
by bin(timestamp, 1d) 
| extend successRate =  
100.0 * (todouble(sessions_success) / todouble(sessions_total)) 
| project timestamp, successRate 
| render timechart

Количество неудачных сеансов по причинам

Этот запрос покажет количество неудачных сеансов по причине/ошибке. Это можно использовать для отладки сбоев при открытии приложения или оценки тенденций в проблемах, с которыми могут сталкиваться пользователи.

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
| extend cd = parse_json(customDimensions) 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend successfulAppLaunch = tobool(sessionSummary["successfulAppLaunch"]) 
| extend unsuccessfulReason = tostring(sessionSummary["unsuccessfulReason"]) 
| where successfulAppLaunch == false 
| summarize 
count() 
by unsuccessfulReason, bin(timestamp, 1d) 
| render timechart

Производительность открытия приложения

Этот запрос покажет метрики производительности открытия приложений по дням. Это можно использовать для оценки тенденций производительности с течением времени или после внесения изменений. Рекомендуется:

1. Использование 75-го процентиля полей timeToAppInteractive и timeToAppFullLoad, чтобы избежать шума, вызванного выбросами.
2. Фильтрация только по оптимальным сеансам, чтобы избежать шума в данных, вызванного ожидаемыми случаями, такими как сеансы с взаимодействием с пользователем, сеансы, в которых приложение было загружено в фоновой вкладке и т. д.

customEvents 
| where name == "PowerAppsClient.PublishedApp.SessionLoadSummary" 
| extend cd = parse_json(customDimensions) 
| extend sessionSummary = parse_json(tostring(cd["ms-sessionSummary"])) 
| extend appLoadResult = tostring(sessionSummary["appLoadResult"]) 
| extend timeToAppInteractive = todouble(sessionSummary["timeToAppInteractive"]) 
| extend timeToAppFullLoad = todouble(sessionSummary["timeToAppFullLoad"]) 
| where appLoadResult == "optimal" 
| summarize 
percentile(timeToAppInteractive, 75), 
percentile(timeToAppFullLoad, 75) 
by bin(timestamp, 1d) 
| render timechart

Состояние загрузки приложения при HTTP-вызовах

Добавлен новый заголовок запроса x-ms-app-load-state, который указывает, участвовал ли HTTP-вызов в запуске приложения. В частности, это можно использовать, чтобы определить, какие HTTP-вызовы повлияли на timeToAppFullLoad, описанный выше.

Заголовок может иметь одно из двух значений:

Ниже приведен пример запроса, показывающий, как получить доступ к значению заголовка и спроецировать его в столбце appLoadState:

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| project timestamp, session_Id, appLoadState, name, duration 
| limit 5

Количество HTTP-вызовов, участвующих в полной загрузке

Этот запрос покажет среднее количество HTTP-вызовов, участвующих в timeToAppFullLoad, по дням. Это можно использовать для оценки количества вызовов, выполняемых приложением при запуске, которые могут способствовать снижению производительности.

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| where appLoadState == "TTFL" 
| summarize httpCalls = count() by session_Id, bin(timestamp, 1d) 
| summarize avg(httpCalls) by timestamp 
| render timechart

Длительность HTTP-вызовов, участвующих в полной загрузке

Этот запрос покажет общую длительность HTTP-вызовов, участвующих в timeToAppFullLoad, по дням. Это можно использовать для оценки общего влияния HTTP-вызовов на производительность запуска приложения.

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| where appLoadState == "TTFL" 
| summarize httpCallDuration = sum(duration) by session_Id, bin(timestamp, 1d) 
| summarize percentile(httpCallDuration, 80) by timestamp 
| render timechart

Длительность HTTP-вызовов, участвующих в полной загрузке по URL-адресу

Аналогично предыдущему, этот запрос покажет количество и длительность HTTP-вызовов, участвующих в timeToAppFulLoad по URL-адресу. Это можно использовать для выявления конкретных медленных HTTP-вызовов, которые влияют на производительность запуска приложения.

dependencies 
| extend cd = parse_json(customDimensions) 
| extend requestHeaders = parse_json(tostring(cd["requestHeaders"])) 
| extend appLoadState = tostring(requestHeaders["x-ms-app-load-state"]) 
| where appLoadState == "TTFL" 
| summarize 
count(), percentile(duration, 80) by name

Мониторинг необработанных ошибок (экспериментальная функция)

[Данный раздел посвящен предварительному выпуску и может быть изменен.]

Вы не всегда можете предвидеть или спланировать каждую ошибку, которая может возникнуть во время работы приложения. Необработанные ошибки формул Power Fx выводятся для пользователей в виде баннерных сообщений. Сведения о них можно также передавать в Application Insights, чтобы показать их частоту и серьезность, не полагаясь на то, что пользователи вашего приложения сообщат о проблемах. Вы также можете настроить оповещения в реальном времени при возникновении ошибок во время выполнения, чтобы использовать более активный подход.

Включение передачи ошибок в Application Insights

Включите настройку, которая позволит Power Apps передавать необработанные ошибки времени выполнения в Azure Application Insights.

1. Откройте приложение на основе холста для редактирования.
2. Выберите Параметры>Обновления>Экспериментальные и включите параметр Передавать ошибки в Azure Application Insights.
3. Сохраните и затем публикуйте свое приложение.

События ошибок в Application Insights

Сведения о необработанных ошибках Power Fx, с которыми пользователи сталкиваются во время выполнения приложения, заносятся в таблицу трассировок. Необработанные ошибки можно идентифицировать и отличить от других событий ошибок по сообщению о событии «Необработанная ошибка». Измерение "severityLevel" этих событий равно 3 (TraceSeverity.Error).

Подробные сообщения об ошибках представлены в измерении "errors" свойства customDimension. В ситуациях, когда во время одной операции возникает несколько ошибок, ошибки объединяются в измерение errors одного события трассировки. Сообщения об ошибках совпадают с теми, которые отображаются в Мониторе во время сеанса отладки в реальном времени.

В этом примере запроса выявляются необработанные ошибки и разворачиваются все сообщения об ошибках в событии трассировки:

traces
    | where message == "Unhandled error"
    | extend customdims = parse_json(customDimensions)
    | extend errors = parse_json(tostring(customdims.['errors']))
    | mv-expand errors
    | project timestamp
        , itemId //unique identifier for the trace event
        , AppName = customdims.['ms-appName']
        , AppId = customdims.['ms-appId']
        , errors = errors.['Message']
    | order by timestamp desc

Трассировка корреляции (экспериментальная функция)

[Данный раздел посвящен предварительному выпуску и может быть изменен.]

Подключение к внешним данным и службам имеет важное значение для большинства приложений. Трассировка корреляции создает и распространяет сведения о контексте, чтобы связать сгенерированные системой журналы между приложением на основе холста и его подключениями с учетом определенных ограничений. Например, приложение может вызвать пользовательский соединитель, который затем вызывает функцию Azure или другой REST API. Трассировка корреляции позволяет сопоставлять действия, выполняемые в приложении, с базовыми вызовами API на разных уровнях. Это полезно для устранения неполадок.

Трассировка корреляций приложения на основе холста реализует трассировку контекста и соответствует спецификации W3C.

Включение трассировки корреляции

1. Чтобы включить трассировку корреляции, откройте приложение на основе холста для редактирования.
2. Выберите Параметры>Обновления>Экспериментальные> и включите параметр Включить трассировку корреляции в Azure Application Insights.
3. Сохраните и опубликуйте приложение.

Ограничения

• Трассировка корреляции работает только с пользовательскими соединителями. Другие типы соединителей не поддерживаются.
• HTTP-запросы фиксируются в Application Insights, только если подключенная служба также подключена к Application Insights.

Использование трассировки корреляции

Будучи включенной, трассировка корреляции добавляет новое событие системного журнала в таблицу зависимостей экземпляра Application Insights для приложения на основе холста. Это событие записывается в момент получения отклика от сетевого вызова. События зависимостей собирают сведения о сетевом вызове, включая заголовки запроса и ответа, код состояния ответа и продолжительность вызова.

Если подключенная служба также подключена к Application Insights, в таблице запросов экземпляра Application Insights этой службы также генерируется дополнительное событие системного журнала, фиксирующее вызов. Некоторые службы Azure, такие как Функции Azure, можно подключить без написания кода на портале Azure. И приложение на основе холста, и несколько приложений и подключенных служб могут быть подключены к одному и тому же экземпляру Application Insights.

Объедините сетевые вызовы для поддерживаемых соединителей с другими системными журналами в измерении "operation_Id". В следующем запросе показан сетевой вызов вместе с событиями трассировки, созданными во время сеанс приложения.

traces | union dependencies | union requests | union pageViews | union customEvents
| project timestamp
    , itemType
    , name
    , operation_Name
    , message
    , severityLevel
    , customDimensions
    , operation_Id
    , operation_ParentId
| where operation_Id == "0a7729e3e83c4e4d93cb4f51149f73b9" //placeholder operation_Id, replace
| order by timestamp asc

Экспорт данных в Power BI

Вы можете экспортировать свои данные и результаты запросов Application Insights в Power BI для анализа и представления данных.

1. Войдите в портал Azure и откройте ресурс Application Insights, который вы настроили ранее.

2. Выберите Журналы в разделе Мониторинг на левой панели навигации.

3. В окне запроса анализа журналов выберите меню Экспорт.

4. Выберите Экспорт в Power BI (M запрос), чтобы загрузить файл запроса Power BI.

   

5. Откройте загруженный файл в текстовом редакторе и скопируйте запрос в буфер обмена.

6. Открыть Power BI.

7. Выберите Получить данные на ленте Главная, затем выберите Пустой запрос.

   

8. В окне запроса выберите Расширенный редактор, вставьте запрос в окно, выберите Готово, затем выберите Закрыть и применить.

   

Создавайте диаграммы и визуализации в Power BI, чтобы представлять отзывы из вашего приложения и принимать решения на основе данных.

Контекст и аналитики события трассировки по умолчанию

Аналитики по умолчанию добавляются к свойству customDimensions для каждого события трассировки. Эти аналитики идентифицируют приложение и сеансы приложения, в которых произошли события. Если вы зарегистрируете дополнительные пользовательские данные с помощью функции трассировки, они также появляются в пользовательских аналитиках.

Неподдерживаемые сценарии

Application Insights не поддерживает эти сценарии.

• События, происходящие в автономном режиме, не регистрируются.
• События из мобильных приложений (iOS и Android) не записываются, когда приложение приостановлено.