Инструкция let

Переключайте службы с помощью раскрывающегося списка Версия. Дополнительные сведения о навигации.
Область применения: ✅ Microsoft Fabric ✅ Azure Data Explorer ✅ Azure Monitor ✅ Microsoft Sentinel

Оператор let используется для задания имени переменной, равного выражению или функции, или для создания представлений.

let операторы полезны для:

• Разбиение сложного выражения на несколько частей, каждая из которых представлена переменной.
• Определение констант за пределами текста запроса для удобства чтения.
• Определение переменной один раз и его использование несколько раз в запросе.

Если переменная ранее представляла другое значение, например в вложенных инструкциях, применяется самая let внутренняя инструкция.

Чтобы оптимизировать несколько вариантов использования инструкции let в одном запросе, см. статью "Оптимизация запросов", использующих именованные выражения.

Синтаксис: скалярные или табличные выражения

let Имя=Выражение

Дополнительные сведения о соглашениях синтаксиса.

Parameters

Синтаксис: представление или функция

let Имя= [] view[(Параметры ]){FunctionBody}

Дополнительные сведения о соглашениях синтаксиса.

Parameters

Examples

В примерах запроса показан синтаксис и пример использования оператора, оператора или функции.

Определение скалярных значений

В следующем примере используется скалярная инструкция выражения.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

Определение табличных выражений

В следующем примере имя привязывается some number с помощью ['name'] нотации, а затем используется в инструкции табличного выражения.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

Создание определяемой пользователем функции с скалярным вычислением

В этом примере используется оператор let с аргументами для скалярного вычисления. Запрос определяет функцию MultiplyByN для умножения двух чисел.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

Создание определяемой пользователем функции, которая обрезает входные данные

В следующем примере удаляются начальные и конечные из входных данных.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

Использование множественных операторов let

В этом примере определяются два оператора let, при этом один оператор (foo2) использует другой (foo1).

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

Создание представления или виртуальной таблицы

В этом примере показано, как использовать инструкцию let для создания или виртуальной view таблицы.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

Использование функции материализации

Функция materialize() позволяет кэшировать результаты вложенных запросов во время выполнения запроса. При использовании materialize() функции данные кэшируются, а любой последующий вызов результата использует кэшированные данные.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

Использование вложенных инструкций let

Вложенные инструкции let разрешены, в том числе в пользовательском выражении функции. Пусть операторы и аргументы применяются как в текущей, так и во внутренней области тела функции.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Табличный аргумент со схемой

В следующем примере указывается, что параметр T таблицы должен иметь столбец State типа string. T Таблица также может содержать другие столбцы, но их нельзя ссылаться в функцииStateState, так как они не объявлены.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

Табличный аргумент с подстановочным знаком

Параметр T таблицы может иметь любую схему, и функция CountRecordsInTable будет работать.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output