Плагин ipv4_lookup

Переключайте службы с помощью раскрывающегося списка Версия. Дополнительные сведения о навигации.
Область применения: ✅ Microsoft Fabric ✅ Azure Data Explorer

Подключаемый ipv4_lookup модуль ищет значение IPv4 в таблице подстановки и возвращает строки с соответствующими значениями. Подключаемый модуль вызывается оператором evaluate .

Синтаксис

T|evaluateipv4_lookup(LookupTable,SourceIPv4Key,IPv4LookupKey [,ExtraKey1 [.. , ExtraKeyN [,return_unmatched ]]] )

Параметры

Нотация IP-префикса

Нотация IP-префикса (также известная как нотация CIDR) — это краткий способ представления IP-адреса и связанной с ней сетевой маски. Формат: <base IP>/<prefix length>длина префикса — это число ведущих 1 битов в netmask. Длина префикса определяет диапазон IP-адресов, принадлежащих сети.

Для IPv4 длина префикса составляет от 0 до 32. Поэтому нотация 192.168.2.0/24 представляет IP-адрес 192.168.2.0 с netmask 255.255.255.0. Эта netmask имеет 24 ведущих 1 бита или длину префикса 24.

Для IPv6 длина префикса составляет от 0 до 128. Поэтому нотация fe80::85d:e82c:9446:7994/120 представляет IP-адрес fe80::85d:e85d:9446:7994 с netmask ffff:ffff:ffff. Эта netmask имеет 120 ведущих 1 битов или длину префикса 120.

Возвраты

Подключаемый ipv4_lookup модуль возвращает результат соединения (подстановки) на основе ключа IPv4. Схема таблицы — это объединение исходной таблицы и таблицы подстановки, аналогично результату lookup оператора.

Если для аргумента return_unmatched задано trueзначение, результирующая таблица включает как сопоставленные, так и несовпаденные строки (заполненные значениями NULL).

Если аргумент return_unmatched задан falseили опущен (значение false по умолчанию используется), результирующая таблица содержит столько записей, сколько соответствует результатам. Этот вариант поиска имеет лучшую производительность по сравнению с return_unmatched=true выполнением.

Примеры

Поиск IPv4 — только соответствующие строки

// IP lookup table: IP_Data
// Partial data from: https://raw.githubusercontent.com/datasets/geoip2-ipv4/master/data/geoip2-ipv4.csv
let IP_Data = datatable(network:string, continent_code:string ,continent_name:string, country_iso_code:string, country_name:string)
[
  "111.68.128.0/17","AS","Asia","JP","Japan",
  "5.8.0.0/19","EU","Europe","RU","Russia",
  "223.255.254.0/24","AS","Asia","SG","Singapore",
  "46.36.200.51/32","OC","Oceania","CK","Cook Islands",
  "2.20.183.0/24","EU","Europe","GB","United Kingdom",
];
let IPs = datatable(ip:string)
[
  '2.20.183.12',   // United Kingdom
  '5.8.1.2',       // Russia
  '192.165.12.17', // Unknown
];
IPs
| evaluate ipv4_lookup(IP_Data, ip, network)

Выходные данные

Подстановка IPv4 — возвращает как соответствующие, так и несоединяющие строки

// IP lookup table: IP_Data
// Partial data from: 
// https://raw.githubusercontent.com/datasets/geoip2-ipv4/master/data/geoip2-ipv4.csv
let IP_Data = datatable(network:string,continent_code:string ,continent_name:string ,country_iso_code:string ,country_name:string )
[
    "111.68.128.0/17","AS","Asia","JP","Japan",
    "5.8.0.0/19","EU","Europe","RU","Russia",
    "223.255.254.0/24","AS","Asia","SG","Singapore",
    "46.36.200.51/32","OC","Oceania","CK","Cook Islands",
    "2.20.183.0/24","EU","Europe","GB","United Kingdom",
];
let IPs = datatable(ip:string)
[
    '2.20.183.12',   // United Kingdom
    '5.8.1.2',       // Russia
    '192.165.12.17', // Unknown
];
IPs
| evaluate ipv4_lookup(IP_Data, ip, network, return_unmatched = true)

Выходные данные

Поиск IPv4 — использование источника в external_data()

let IP_Data = external_data(network:string,geoname_id:long,continent_code:string,continent_name:string ,country_iso_code:string,country_name:string,is_anonymous_proxy:bool,is_satellite_provider:bool)
    ['https://raw.githubusercontent.com/datasets/geoip2-ipv4/master/data/geoip2-ipv4.csv'];
let IPs = datatable(ip:string)
[
    '2.20.183.12',   // United Kingdom
    '5.8.1.2',       // Russia
    '192.165.12.17', // Sweden
];
IPs
| evaluate ipv4_lookup(IP_Data, ip, network, return_unmatched = true)

Выходные данные

Поиск IPv4 — использование дополнительных столбцов для сопоставления

let IP_Data = external_data(network:string,geoname_id:long,continent_code:string,continent_name:string ,country_iso_code:string,country_name:string,is_anonymous_proxy:bool,is_satellite_provider:bool)
    ['https://raw.githubusercontent.com/datasets/geoip2-ipv4/master/data/geoip2-ipv4.csv'];
let IPs = datatable(ip:string, continent_name:string, country_iso_code:string)
[
    '2.20.183.12',   'Europe', 'GB', // United Kingdom
    '5.8.1.2',       'Europe', 'RU', // Russia
    '192.165.12.17', 'Europe', '',   // Sweden is 'SE' - so it won't be matched
];
IPs
| evaluate ipv4_lookup(IP_Data, ip, network, continent_name, country_iso_code)

Выходные данные

Связанный контент

• Обзор функций IPv4/IPv6
• Общие сведения о функциях сопоставления текста IPv4