Поделиться через

CentralBinaryLogFile Class1

  • Статья

Настраивает параметры для централизованного ведения журнала двоичных файлов на сервере.

Синтаксис

class CentralBinaryLogFile : EmbeddedObject

Методы

Этот класс не содержит методов.

Свойства

В следующей таблице перечислены свойства, предоставляемые классом CentralBinaryLogFile .

Имя Описание
Directory Значение для чтения и записи string , указывающее каталог, в который записываются записи журнала. Значение по умолчанию — "%SystemDrive%\inetpub\logs\LogFiles".
Enabled Значение для чтения и записи boolean . true Значение , если централизованное двоичное ведение журнала включено; в противном случае — false. Значение по умолчанию — true.
LocalTimeRollover Значение для чтения и записи boolean . true Значение , если новый файл журнала основан на местном времени; false Значение , если оно основано на формате UTC. Значение по умолчанию — false.
Period Перечисление для чтения и записи sint32 , указывающее, как часто закрывается текущий файл журнала и запускается новый файл журнала. Возможные значения перечислены далее в разделе Примечания.
TruncateSize Значение для чтения и записи string , указывающее (в байтах) размер, при котором содержимое файла журнала должно быть усечено. Этот атрибут необходимо настроить, если Period задано значение MaxSize. Размер должен быть от 1048576 (1 мегабайт) до 4294967295 (4 гигабайта). Значение по умолчанию — 20971520 (20 мегабайт).

используются подклассы ;

Этот класс не содержит подклассов.

Комментарии

Экземпляры этого класса содержатся в свойстве CentralBinaryLogFile класса LogSection .

В следующей таблице перечислены возможные значения свойства Period . Значение по умолчанию — 1 (Daily).

Значение Ключевое слово Описание
0 MaxSize Файл журнала закрывается, а при достижении значения в TruncateSize запускается новый файл журнала.
1 Daily Файл журнала закрывается, а новый файл журнала запускается один раз в день.
2 Weekly Файл журнала закрывается, а новый файл журнала запускается один раз в неделю.
3 Monthly Файл журнала закрывается, а новый файл журнала запускается один раз в месяц.
4 Hourly Файл журнала закрывается, а новый файл журнала запускается один раз в час.

Пример

В следующем примере кода для режима файла журнала устанавливается значение CentralBinary, включается ведение двоичного журнала, свойству WeeklyPeriod присваивается значение , указывает, что файлы журнала используют местное время, и ограничивает размер журнала 1 гигабайтой. Вспомогательные функции отображают параметры до и после внесения изменений.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the log configuration section.  
Set oSection = oWebAdmin.Get("LogSection.Path=" & _  
   "'MACHINE/WEBROOT/APPHOST',Location=''")  
  
' Show the initial settings.  
DisplaySettings("Initial Values")  
  
' Set the log file mode to CentralBinary.  
oSection.CentralLogFileMode = 1  
  
' Enable central binary logging.  
oSection.CentralBinaryLogFile.Enabled = True  
  
' Set local time rollover to true.  
oSection.CentralBinaryLogFile.LocalTimeRollover = True  
  
' Set the Period property to Weekly.  
oSection.CentralBinaryLogFile.Period = 2  
  
' Set the log truncate size to 1 gigabyte.  
oSection.CentralBinaryLogFile.TruncateSize = 1073741824  
  
' Save the values to configuration.  
oSection.Put_  
  
' Refresh the oSection object variable with the new values.  
oSection.Refresh_  
  
' Show the changed settings.  
Call DisplaySettings("New Values")  
  
' ==== This section contains helper functions. ====  
Function DisplaySettings(HeadingText)  
   WScript.Echo String(Len(HeadingText), "=")  
   WScript.Echo HeadingText  
   WScript.Echo String(Len(HeadingText), "=")  
  
   ' Display the current central log file mode.  
   WScript.Echo "CentralLogFileMode: " & _  
      oSection.CentralLogFileMode  
  
   ' Display the current binary log file properties.  
   Call ShowPropVals(oSection.CentralBinaryLogFile)  
  
End Function  
  
' Display the property values.  
Function ShowPropVals(oObject)  
  
   For Each Prop In oObject.Properties_  
      WScript.Echo Prop.Name & ": " & Prop.Value  
   Next  
  
   WScript.Echo  
  
End Function

Иерархия наследования

EmbeddedObject

CentralBinaryLogFile

Требования

Тип Описание
клиент — IIS 7.0 в Windows Vista
— IIS 7.5 в Windows 7
— IIS 8.0 в Windows 8
— IIS 10.0 в Windows 10
Сервер — IIS 7.0 в Windows Server 2008
— IIS 7.5 в Windows Server 2008 R2
— IIS 8.0 в Windows Server 2012
— IIS 8.5 в Windows Server 2012 R2
— IIS 10.0 в Windows Server 2016
Продукт — IIS 7.0, IIS 7.5, IIS 8.0, IIS 8.5, IIS 10.0
MOF-файл WebAdministration.mof

См. также:

Класс CentralW3CLogFile
Класс EmbeddedObject
Класс LogSection
Класс SiteLogFile