Предложение Join (Visual Basic)
Объединяет две коллекции в одну. Операция соединения основана на сопоставлении ключей и использует Equals оператор.
Синтаксис
Join element In collection _
[ joinClause _ ]
[ groupJoinClause ... _ ]
On key1 Equals key2 [ And key3 Equals key4 [... ]
Детали
element Обязательный. Переменная элемента управления для присоединяемой коллекции.
collection
Обязательный. Коллекция для объединения с коллекцией, определенной Join слева от оператора. Предложение Join может быть вложено в другое Join Group Join предложение или в предложение.
joinClause
Необязательно. Одно или несколько дополнительных Join предложений для дальнейшего уточнения запроса.
groupJoinClause
Необязательно. Одно или несколько дополнительных Group Join предложений для дальнейшего уточнения запроса.
key1 Equals key2
Обязательный. Определяет ключи для присоединенных коллекций. Необходимо использовать Equals оператор для сравнения ключей из присоединенных коллекций. Условия соединения можно объединить с помощью And оператора для идентификации нескольких ключей. key1 должен находиться в коллекции слева Join от оператора. key2 должен находиться в коллекции справа Join от оператора.
Ключи, используемые в условии соединения, могут быть выражениями, которые включают несколько элементов из коллекции. Однако каждое ключевое выражение может содержать только элементы из соответствующей коллекции.
Замечания
Предложение Join объединяет две коллекции на основе сопоставления ключевых значений из присоединенных коллекций. Результирующая коллекция может содержать любое сочетание значений из коллекции, определенной слева Join от оператора и коллекции, определенной в предложении Join . Запрос вернет только результаты, для которых выполняется условие, указанное оператором Equals . Это эквивалентно INNER JOIN sql.
В запросе можно использовать несколько Join предложений для объединения двух или нескольких коллекций в одну коллекцию.
Вы можете выполнить неявное соединение для объединения коллекций Join без предложения. Для этого включите в предложение From несколько In предложений и укажите Where предложение, определяющее ключи, которые необходимо использовать для соединения.
Предложение можно использовать Group Join для объединения коллекций в одну иерархическую коллекцию. Это похоже на LEFT OUTER JOIN SQL.
Пример 1
В следующем примере кода выполняется неявное соединение для объединения списка клиентов с их заказами.
Dim customerIDs() = {"ALFKI", "VICTE", "BLAUS", "TRAIH"}
Dim customerList = From cust In customers, custID In customerIDs
Where cust.CustomerID = custID
Select cust.CompanyName
For Each companyName In customerList
Console.WriteLine(companyName)
Next
Пример 2
Следующий пример кода объединяет две коллекции с помощью Join предложения.
Imports System.Diagnostics
Public Class JoinSample
Public Sub ListProcesses()
Dim processDescriptions As New List(Of ProcessDescription)
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "explorer",
.Description = "Windows Explorer"})
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "winlogon",
.Description = "Windows Logon"})
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "cmd",
.Description = "Command Window"})
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "iexplore",
.Description = "Internet Explorer"})
Dim processes = From proc In Process.GetProcesses
Join desc In processDescriptions
On proc.ProcessName Equals desc.ProcessName
Select proc.ProcessName, proc.Id, desc.Description
For Each proc In processes
Console.WriteLine("{0} ({1}), {2}",
proc.ProcessName, proc.Id, proc.Description)
Next
End Sub
End Class
Public Class ProcessDescription
Public ProcessName As String
Public Description As String
End Class
В этом примере выходные данные будут выглядеть примерно так:
winlogon (968), Windows Logon
explorer (2424), File Explorer
cmd (5136), Command Window
Пример 3
Следующий пример кода объединяет две коллекции с помощью Join предложения с двумя ключевыми столбцами.
Imports System.Diagnostics
Public Class JoinSample2
Public Sub ListProcesses()
Dim processDescriptions As New List(Of ProcessDescription2)
' 8 = Normal priority, 13 = High priority
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "explorer",
.Description = "Windows Explorer",
.Priority = 8})
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "winlogon",
.Description = "Windows Logon",
.Priority = 13})
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "cmd",
.Description = "Command Window",
.Priority = 8})
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "iexplore",
.Description = "Internet Explorer",
.Priority = 8})
Dim processes = From proc In Process.GetProcesses
Join desc In processDescriptions
On proc.ProcessName Equals desc.ProcessName And
proc.BasePriority Equals desc.Priority
Select proc.ProcessName, proc.Id, desc.Description,
desc.Priority
For Each proc In processes
Console.WriteLine("{0} ({1}), {2}, Priority = {3}",
proc.ProcessName,
proc.Id,
proc.Description,
proc.Priority)
Next
End Sub
End Class
Public Class ProcessDescription2
Public ProcessName As String
Public Description As String
Public Priority As Integer
End Class
В примере выходные данные будут выглядеть примерно так:
winlogon (968), Windows Logon, Priority = 13
cmd (700), Command Window, Priority = 8
explorer (2424), File Explorer, Priority = 8
