Поделиться через

Практическое руководство. Чтение из текстовых файлов с несколькими форматами в Visual Basic

  • Статья

Объект TextFieldParser позволяет легко и эффективно анализировать структурированные текстовые файлы, например файлы журналов. Обработать файл, имеющий содержимое в нескольких форматах, можно с помощью метода PeekChars, который позволяет определять формат каждой анализируемой строки на протяжении всего файла.

Анализ текстового файла с содержимым в нескольких форматах

  1. Добавьте текстовый файл с именем testfile.txt в проект. Добавьте в текстовый файл следующее содержимое:

    Err  1001 Cannot access resource.
Err  2014 Resource not found.
Acc  10/03/2009User1      Administrator.
Err  0323 Warning: Invalid access attempt.
Acc  10/03/2009User2      Standard user.
Acc  10/04/2009User2      Standard user.

  2. Определите ожидаемый формат и формат, используемый при сообщении об ошибке. Последним элементом в каждом массиве является -1, поэтому предполагается, что ширина последнего поля может изменяться. Это происходит, когда последний элемент массива меньше или равен нулю.

    Dim stdFormat As Integer() = {5, 10, 11, -1}
Dim errorFormat As Integer() = {5, 5, -1}

  3. Создайте объект TextFieldParser, определив ширину и формат.

    Using MyReader As New FileIO.TextFieldParser("..\..\testfile.txt")
    MyReader.TextFieldType = FileIO.FieldType.FixedWidth
    MyReader.FieldWidths = stdFormat

  4. Переберите в цикле строки, проверяя формат перед чтением.

    Dim currentRow As String()
While Not MyReader.EndOfData
    Try
        Dim rowType = MyReader.PeekChars(3)
        If String.Compare(rowType, "Err") = 0 Then
            ' If this line describes an error, the format of the row will be different.
            MyReader.SetFieldWidths(errorFormat)
        Else
            ' Otherwise parse the fields normally
            MyReader.SetFieldWidths(stdFormat)
        End If
        currentRow = MyReader.ReadFields
        For Each newString In currentRow
            Console.Write(newString & "|")
        Next
        Console.WriteLine()

  5. Выведите сообщения об ошибках на консоль.

            Catch ex As Microsoft.VisualBasic.
                      FileIO.MalformedLineException
            MsgBox("Line " & ex.Message & " is invalid.")
        End Try
    End While
End Using

Пример

Далее приведен полный пример, считывающий из файла testfile.txt:

Dim stdFormat As Integer() = {5, 10, 11, -1}
Dim errorFormat As Integer() = {5, 5, -1}
Using MyReader As New FileIO.TextFieldParser("..\..\testfile.txt")
    MyReader.TextFieldType = FileIO.FieldType.FixedWidth
    MyReader.FieldWidths = stdFormat
    Dim currentRow As String()
    While Not MyReader.EndOfData
        Try
            Dim rowType = MyReader.PeekChars(3)
            If String.Compare(rowType, "Err") = 0 Then
                ' If this line describes an error, the format of the row will be different.
                MyReader.SetFieldWidths(errorFormat)
            Else
                ' Otherwise parse the fields normally
                MyReader.SetFieldWidths(stdFormat)
            End If
            currentRow = MyReader.ReadFields
            For Each newString In currentRow
                Console.Write(newString & "|")
            Next
            Console.WriteLine()
        Catch ex As FileIO.MalformedLineException
            MsgBox("Line " & ex.Message & " is invalid.  Skipping")
        End Try
    End While
End Using
Console.ReadLine()

Отказоустойчивость

При следующих условиях возможно возникновение исключения:

  • Строка не может быть проанализирована с использованием указанного формата (MalformedLineException). Сообщение исключения содержит строку, вызвавшую исключение, а свойство ErrorLine присвоено тексту, который содержится в этой строке.
  • Указанный файл не существует (FileNotFoundException).
  • Ситуация частичного доверия, в которой пользователь не имеет достаточных разрешений для доступа к файлу. (SecurityException).
  • Слишком длинный путь (PathTooLongException).
  • Пользователь не имеет необходимых разрешений для доступа к файлу (UnauthorizedAccessException).

См. также