Краткое руководство. Создание хранилища служб восстановления Azure с помощью Terraform

Из этого краткого руководства вы узнаете, как с помощью Terraform создать группу ресурсов Azure, хранилище служб восстановления Azure и политику резервного копирования для совместного использования файлов в Azure. Служба Azure Site Recovery может помочь бизнес-приложениям оставаться в сети во время запланированных и незапланированных сбоев. В частности, Site Recovery использует репликацию, отработку отказа и восстановление для управления локальными компьютерами и виртуальными машинами Azure во время аварийного восстановления. Эти методы Site Recovery могут способствовать непрерывности бизнес-процессов и стратегии аварийного восстановления.

Хранилище служб восстановления Azure — это сущность хранилища в Azure, в которой содержатся такие данные, как резервные копии и точки восстановления, которые могут защитить данные и управлять ими. Сначала создается хранилище, а затем политика резервного копирования для файлов общего доступа, которая указывает, когда и как часто следует выполнять резервное копирование, а также период хранения. Эта настройка поможет обеспечить согласованное резервное копирование ваших данных и при необходимости легко восстановить их.

Terraform включает определение, предварительную версию и развертывание облачной инфраструктуры. С помощью Terraform вы создаете файлы конфигурации с помощью синтаксиса HCL. Синтаксис HCL позволяет указать поставщика облачных служб, например Azure, и элементы, составляющие облачную инфраструктуру. После создания файлов конфигурации вы создадите план выполнения , который позволяет предварительно просмотреть изменения инфраструктуры перед развертыванием. После проверки изменений примените план выполнения для развертывания инфраструктуры.

Необходимые компоненты

• Создайте учетную запись Azure с активной подпиской. Вы можете бесплатно создать учетную запись.

• Установите и настройте Terraform.

Реализация кода Terraform

1. Создайте каталог, в котором необходимо протестировать и запустить пример кода Terraform и сделать его текущим каталогом.

2. Создайте файл с именем main.tfи вставьте следующий код:

   # Create Resource Group
   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   locals {
     skuName = "RS0"
     skuTier = "Standard"
   }
   
   # Create Recovery Services Vault
   resource "azurerm_recovery_services_vault" "vault" {
     name                = var.vaultName
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     sku                 = local.skuName
   }
   
   # Create Backup Policy for File Share
   resource "azurerm_backup_policy_file_share" "policy" {
     name                = "vaultstorageconfig"
     resource_group_name = azurerm_resource_group.rg.name
     recovery_vault_name = azurerm_recovery_services_vault.vault.name
   
     backup {
       frequency = "Daily"
       time      = "23:00"
     }
   
     retention_daily {
       count = 10
     }
   }
   

3. Создайте файл с именем outputs.tfи вставьте следующий код:

   output "recovery_services_vault_name" {
     value = azurerm_recovery_services_vault.vault.name
   }
   
   output "backup_policy_file_share_name" {
     value = azurerm_backup_policy_file_share.policy.name
   }
   

4. Создайте файл с именем providers.tfи вставьте следующий код:

   terraform {
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. Создайте файл с именем variables.tfи вставьте следующий код:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "vaultName" {
     description = "Name of the Recovery Services Vault."
     type        = string
     default     = "examplevault"
   }
   

Инициализация Terraform

Запустите terraform init , чтобы инициализировать развертывание Terraform. Эта команда скачивает поставщик Azure, необходимый для управления ресурсами Azure.

terraform init -upgrade

Ключевые моменты:

• Параметр -upgrade обновляет необходимые подключаемые модули поставщика до последней версии, которая соответствует ограничениям версии конфигурации.

Создание плана выполнения Terraform

Выполните команду terraform plan, чтобы создать план выполнения.

terraform plan -out main.tfplan

Ключевые моменты:

• Команда terraform plan создает план выполнения, но не выполняет его. Вместо этого она определяет, какие действия необходимы для создания конфигурации, заданной в файлах конфигурации. Этот шаблон позволяет проверить, соответствует ли план выполнения вашим ожиданиям, прежде чем вы начнете вносить изменения в фактические ресурсы.
• Необязательный параметр -out позволяет указать выходной файл для плана. Использование параметра -out гарантирует, что проверяемый план полностью соответствует применяемому.

Применение плана выполнения Terraform

Запустите terraform apply, чтобы применить план выполнения к вашей облачной инфраструктуре.

terraform apply main.tfplan

Ключевые моменты:

• В примере terraform apply команды предполагается, что вы ранее выполнили.terraform plan -out main.tfplan
• Если для параметра -out указано другое имя файла, используйте то же имя в вызове к terraform apply.
• Если вы не использовали параметр -out, вызовите terraform apply без параметров.

Проверка результатов

Очистка ресурсов

Если вам больше не нужны ресурсы, созданные через Terraform, выполните следующие действия:

1. Запустите terraform plan и укажите флаг destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Ключевые моменты:

   • Команда terraform plan создает план выполнения, но не выполняет его. Вместо этого она определяет, какие действия необходимы для создания конфигурации, заданной в файлах конфигурации. Этот шаблон позволяет проверить, соответствует ли план выполнения вашим ожиданиям, прежде чем вы начнете вносить изменения в фактические ресурсы.
   • Необязательный параметр -out позволяет указать выходной файл для плана. Использование параметра -out гарантирует, что проверяемый план полностью соответствует применяемому.

2. Чтобы применить план выполнения, запустите terraform apply.

   terraform apply main.destroy.tfplan
   

Устранение неполадок с Terraform в Azure

Устранение распространенных проблем при использовании Terraform в Azure.

Следующие шаги