Геопространственные визуализации

Переключайте службы с помощью раскрывающегося списка Версия. Дополнительные сведения о навигации.
Область применения: ✅ Microsoft Fabric ✅ Azure Data Explorer ✅ Azure Monitor ✅ Microsoft Sentinel

Геопространственные данные можно визуализировать в рамках запроса с помощью оператора отрисовки в виде точек, пирогов или пузырьков на карте.

Дополнительные сведения о геопространственной кластеризации см. в разделе "Геопространственный кластеризация".

Примеры

Следующий пример находит события storm и визуализирует 100 на карте.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

В следующем примере визуализируется несколько рядов точек, где пара [Долгота, Широта] определяет каждую точку, а третий столбец определяет ряд. В этом примере используется EventTypeряд.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

В следующем примере показано, как визуализировать ряд точек на карте. Если в результате имеется несколько столбцов, необходимо указать столбцы, которые будут использоваться для xcolumn (долгота), ycolumn (Широта) и ряда.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

В следующем примере визуализируется точки на карте с помощью динамических значений GeoJSON для определения точек.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

В следующем примере показаны события шторма, агрегированные ячейками S2. Диаграмма объединяет события в пузырьках по расположению в одном цвете.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

В следующем примере показаны события шторма, агрегированные ячейками S2. Диаграмма объединяет события по типу события в круговых диаграммах по расположению.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Связанный контент

• Геопространственный кластеризация
• Оператор отрисовки
• Аналитика данных для автопарков испытаний (вариант использования геопространственного кластеризации)
• Сведения об архитектуре Azure для геопространственной обработки и аналитики данных