arg_max() (агрегатная функция)

Область применения: ✅Microsoft Fabric

Находит строку в таблице, которая максимизирует указанное выражение. Он возвращает все столбцы входной таблицы или указанные столбцы.

Устаревшие псевдонимы: argmax()

Синтаксис

arg_max ( ExprToMaximize,* | ExprToReturn [, ...])

Дополнительные сведения о соглашениях синтаксиса.

Параметры

Возвраты

Возвращает строку в таблице, которая максимизирует указанное выражение ExprToMaximize, а также значения столбцов, указанных в ExprToReturn.

Примеры

Общие примеры

В следующем примере находит максимальную широту события шторма в каждом состоянии.

StormEvents 
| summarize arg_max(BeginLat, BeginLocation) by State

Выходные данные

В таблице результатов отображаются только первые 10 строк.

В следующем примере отображается время последнего события с прямой смертью в каждом состоянии, где отображаются все столбцы.

Запрос сначала фильтрует события, чтобы включить только те события, в которых была по крайней мере одна прямая смерть. Затем запрос возвращает всю строку с последней StartTime.

StormEvents
| where DeathsDirect > 0
| summarize arg_max(StartTime, *) by State

Выходные данные

В таблице результатов отображаются только первые 10 строк и первые три столбца.

В следующем примере показана обработка значений NULL.

datatable(Fruit: string, Color: string, Version: int) [
    "Apple", "Red", 1,
    "Apple", "Green", int(null),
    "Banana", "Yellow", int(null),
    "Banana", "Green", int(null),
    "Pear", "Brown", 1,
    "Pear", "Green", 2,
]
| summarize arg_max(Version, *) by Fruit

Выходные данные

Примеры сравнения arg_max() и max()

Функция arg_max() отличается от функции max(). Функция arg_max() позволяет возвращать другие столбцы вместе с максимальным значением, а max() возвращает только максимальное значение.

В следующем примере используется arg_max() для поиска последнего события с прямой смертью в каждом состоянии, где отображаются все столбцы. Запрос сначала фильтрует события, чтобы включать только события, в которых была по крайней мере одна прямая смерть. Затем запрос возвращает всю строку с самым последним (максимумом) StartTime.

StormEvents
| where DeathsDirect > 0
| summarize arg_max(StartTime, *)

Таблица результатов возвращает все столбцы для строки, содержащей наибольшее значение в указанном выражении.

В следующем примере функция max() используется для поиска последнего события с прямой смертью в каждом состоянии, но возвращает только максимальное значение StartTime.

StormEvents
| where DeathsDirect > 0
| summarize max(StartTime)

Таблица результатов возвращает максимальное значение StartTime, не возвращая другие столбцы для этой записи.

Связанный контент

• Краткий обзор типов статистических функций
• функции arg_min
• max function
• avg function
• функция процентиля