Визуальные элементы, относящиеся к панели мониторинга

Все визуализации, создаваемые в контексте оператора отрисовки , доступны в визуализациях панели мониторинга. Однако следующие визуализации доступны только на панелях мониторинга Azure Data Explorer, Real-Time панелях мониторинга или веб-интерфейсе Azure Data Explorer и недоступны с помощью оператора отрисовки.

Сведения о настройке визуальных элементов панели мониторинга см. в статье "Настройка визуальных элементов Azure Data Explorer панели мониторинга".

Общие сведения о панелях мониторинга в Azure Data Explorer см. в разделе Визуализация данных с помощью панелей мониторинга Azure Data Explorer.

Stat

Вы можете использовать статистику в Azure Data Explorer дашбордах и Fabric Real-Time панелях. Он показывает одно скалярное значение. Выберите его из визуального выбора панели управления.

Пример запроса

StormEvents
| summarize TotalEvents = count()

Выберите Stat как визуальный тип.

Мультистат

Multi Stat отображает несколько значений в сетке слотов. Выберите визуализацию через визуальный выбор на панели управления.

Запрос должен возвращать столбец метки и столбец значения. Вы можете явно выбрать столбцы Label и Value в визуальных настройках.

Пример запроса

datatable(Status:string, Count:long)
[
    "Active", 42,
    "Mitigated", 18,
    "Resolved", 73
]

В визуальных настройках выберите первый выходной столбец как столбец Метка, а второй — как столбец Значение.

Воронкообразная диаграмма

Воронковая диаграмма визуализирует линейный процесс, имеющий последовательные, подключенные этапы. Каждый этап воронки представляет процент от общего числа. Таким образом, в большинстве случаев воронковая диаграмма формируется как воронка, причем первый этап является самым большим, и каждый последующий этап меньше своего предшественника.

В следующем примере используются данные из базы данных ContosoSales в общедоступном кластере справки, чтобы показать количество продаж стиральных и сушильных машин в Канаде от общего объема продаж в 2007 году.

Пример запроса

let interestingSales = SalesTable
| where DateKey between (datetime(2007) .. datetime(2008))
| join kind=inner Products on ProductKey;
let totalSales = interestingSales
| summarize sum(SalesAmount)
| extend Name="Total";
//totalSales
let homeAppliancesSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| summarize sum(SalesAmount)
| extend Name="Home Appliances";
//homeAppliancesSales
let washersAndDryersSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| where ProductSubcategoryName == "Washers & Dryers"
| summarize sum(SalesAmount)
| extend Name="Washers & Dryers";
//washersAndDryersSales
let canadaSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| where ProductSubcategoryName == "Washers & Dryers"
| where Country == "Canada"
| summarize sum(SalesAmount)
| extend Name="Canada";
//canadaSales
totalSales
| union homeAppliancesSales
| union washersAndDryersSales
| union canadaSales
| project Name, SalesAmount=sum_SalesAmount
| sort by SalesAmount desc

Тепловая карта

Тепловая карта показывает значения для основной переменной интереса между двумя переменными оси в виде сетки цветных квадратов.

Для отрисовки тепловой карты запрос должен создать таблицу с тремя столбцами. Данные, используемые для поля значения , должны быть числовыми. Столбцы, которые будут использоваться для значений x и y , используют следующие правила:

• Если значения в столбце x имеют формат string, значения в столбце y должны иметь формат string.
• Если значения в столбце x находятся в datetime формате, значения в столбце y должны быть числовыми.

Пример запроса

StormEvents
| summarize count(EventId) by State, EventType