Сокращение выбросов углерода в Azure

Функционал оптимизации углерода в Azure работает с Azure Advisor для предоставления рекомендаций по оптимизации. Azure Advisor определяет бездействующие и неиспользуемые ресурсы и показывает, как внедрение рекомендаций может сократить выбросы углерода и сэкономить затраты. Рекомендации могут включать завершение работы неактивных виртуальных машин и управление правами виртуальных машин. Дополнительные рекомендации и сведения о Помощнике по Azure см. в статье Сокращение затрат на обслуживание с помощью помощника по Azure.

Чтобы просмотреть рекомендации по оптимизации углерода, перейдите на страницу сокращения выбросов и выберите нужную подписку и группы ресурсов.

На этой странице показано общее количество доступных рекомендаций и потенциальных возможностей экономии с точки зрения затрат и углерода. В нем также показаны эквиваленты экономии углерода, вычисляемые калькуляторомэквивалентов парниковых газов Сша.

Просмотр рекомендаций

В списке рекомендаций в таблице показаны неэффективные ресурсы, которые могут помочь сократить выбросы углерода. Каждая рекомендация показывает связанную экономию углерода и потенциальную экономию средств, которые могут быть получены от выполнения рекомендаций.

Действуйте по рекомендации

Чтобы выполнить действия с рекомендацией, выберите имя ресурса или текст в столбце рекомендаций. При выборе текста рекомендации вы перейдете на страницу действий для ресурса. Например, страница изменения размера, страница изменения количества экземпляров или страница обзора ресурсов, используемая для рекомендаций по удалению.

Снимок экрана со страницей сокращения выбросов.

Преобразование экономии выбросов в эквиваленты

Калькулятор эквивалентных газов парниковых газов позволяет преобразовать данные о выбросах в эквивалентный объем углекислого газа (CO2), генерируемый с помощью этого объема. Калькулятор помогает перевести абстрактные измерения в конкретные термины, которые можно понять, такие как ежегодные выбросы от деревьев, домашних хозяйств или мусорных пакетов. Этот калькулятор может оказаться полезным для общения стратегии сокращения парниковых газов, целевых показателей сокращения или других инициатив, направленных на сокращение выбросов парниковых газов.

Дополнительные сведения о типах рекомендаций см. в статье Сокращение затрат на обслуживание с помощью помощника по Azure.

Рекомендации по сокращению выбросов экспорта

Рекомендации по сокращению выбросов можно экспортировать с помощью Azure Resource Graph. Выполните следующий запрос в обозревателе Ресурсов Azure. После этого вы можете скачать результаты в формате CSV.

Экспорт включает:

  • ИД рекомендации
  • Идентификатор подписки или имя подписки
  • Имя группы ресурсов
  • Ежемесячная экономия затрат
  • Ежемесячная экономия углерода в килограммах
  • Имя ресурса
  • Рекомендованное сообщение
  • Тип рекомендации
  • Сведения о рекомендации, включая метаданные ресурса, такие как идентификатор ресурса и имя роли
// Export emissions reduction recommendations using Azure Resource Graph

advisorresources
  | where tolower(type) == "microsoft.advisor/recommendations"
  | extend RecommendationTypeId = tostring(properties.recommendationTypeId)
  | where RecommendationTypeId in ("94aea435-ef39-493f-a547-8408092c22a7", "e10b1381-5f0a-47ff-8c7b-37bd13d7c974")
  | project stableId=name, subscriptionId, resourceGroup, properties, recommendationId=id
  | join kind=leftouter(
      advisorresources
      | where tolower(type) == 'microsoft.advisor/suppressions'
      | extend tokens = split(id, '/')
      | extend stableId = iff(array_length(tokens) > 3, tokens[(array_length(tokens)-3)], '')
      | extend expirationTimeStamp = todatetime(iff(strcmp(tostring(properties.ttl), '-1') == 0, '9999-12-31', properties.expirationTimeStamp))
      | where expirationTimeStamp > now()
      | project suppressionId = tostring(properties.suppressionId), stableId, expirationTimeStamp
  ) on stableId
  | join kind = leftouter (
      advisorresources
      | where tolower(type) == 'microsoft.advisor/configurations'
      | where isempty(resourceGroup) == true
      | project subscriptionId, excludeRecomm = properties.exclude, lowCpuThreshold = properties.lowCpuThreshold
  ) on subscriptionId
  | extend isActive = iff(isempty(excludeRecomm), true, tobool(excludeRecomm) == false)
  | extend isNotExcludedViaCpuThreshold = iff((isnotempty(lowCpuThreshold) and isnotnull(properties.extendedProperties) and isnotempty(properties.extendedProperties.MaxCpuP95)),
      todouble(properties.extendedProperties.MaxCpuP95) < todouble(lowCpuThreshold),
      iff((isnull(properties.extendedProperties) or isempty(properties.extendedProperties.MaxCpuP95) or todouble(properties.extendedProperties.MaxCpuP95) < 100),
          true,
          false))
  | where isActive == true and isNotExcludedViaCpuThreshold == true
  | join kind = leftouter (
      advisorresources
      | where type =~ 'microsoft.advisor/configurations'
      | where isnotempty(resourceGroup) == true
      | project subscriptionId, resourceGroup, excludeProperty = properties.exclude
  ) on subscriptionId, resourceGroup
  | extend shouldBeIncluded = iff(isempty(excludeProperty), true, tobool(excludeProperty) == false)
  | where shouldBeIncluded == true
  | summarize expirationTimeStamp = max(expirationTimeStamp), suppressionIds = make_list(suppressionId) by recommendationId, stableId, subscriptionId, resourceGroup, tostring(properties)
  | extend isRecommendationActive = (isnull(expirationTimeStamp) or isempty(expirationTimeStamp))
  | extend properties = parse_json(properties)
  | extend monthlyCostSavings = toreal(properties.extendedProperties.savingsAmount)
  | extend monthlyCarbonSavingsKg = toreal(properties.extendedProperties.PotentialMonthlyCarbonSavings)
  | where monthlyCarbonSavingsKg > 0
  | extend resourceId = properties.resourceMetadata.resourceId, resourceName = tostring(properties.extendedProperties.roleName), recommendationMessage = properties.extendedProperties.recommendationMessage, recommendationType=tostring(properties.extendedProperties.recommendationType)
  | project recommendationId, subscriptionId, resourceGroup, suppressionIds, isRecommendationActive, monthlyCostSavings, monthlyCarbonSavingsKg, resourceId, resourceName, recommendationMessage, recommendationType| where isRecommendationActive == true| order by monthlyCarbonSavingsKg desc

Дальнейшие действия

  • Last updated on