Краткое руководство: создание учетной записи Batch с помощью файла Bicep

Начните работу со службой пакетной обработки Azure, используя файл Bicep для создания учетной записи для пакетной обработки, а также для создания хранилища. Чтобы создавать вычислительные ресурсы (пулы вычислительных узлов) и пакетные задачи, вам необходима Batch-учетная запись. Вы можете связать учетную запись хранения Azure с учетной записью пакетной службы, что будет удобно для развертывания приложений и хранения входных и выходных данных в большинстве реальных рабочих нагрузок.

По завершении этого краткого руководства вы поймете основные концепции службы Batch и будете готовы испытать ее с более реалистичными рабочими нагрузками в более широких масштабах.

Bicep — это предметно-ориентированный язык (DSL), который использует декларативный синтаксис для развертывания ресурсов Azure. Он обеспечивает краткий синтаксис, надежную безопасность типов и поддержку повторного использования кода. Bicep предлагает лучшие возможности для разработки решений Azure типа "инфраструктура как код".

Предварительные условия

У вас должна быть активная подписка Azure.

• Если у вас нет аккаунта Azure, создайте бесплатную учетную запись перед началом.

Проверьте файл Bicep

Файл Bicep, используемый в этом быстром старте, взят из шаблонов Azure Quickstart.

@description('Batch Account Name')
param batchAccountName string = '${toLower(uniqueString(resourceGroup().id))}batch'

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
param storageAccountsku string = 'Standard_LRS'

@description('Location for all resources.')
param location string = resourceGroup().location

var storageAccountName = '${uniqueString(resourceGroup().id)}storage'

resource storageAccount 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountsku
  }
  kind: 'StorageV2'
  tags: {
    ObjectName: storageAccountName
  }
  properties: {
    minimumTlsVersion: 'TLS1_2'
    allowBlobPublicAccess: false
    networkAcls: {
      defaultAction: 'Deny'
    }
    supportsHttpsTrafficOnly: true
  }
}

resource batchAccount 'Microsoft.Batch/batchAccounts@2024-02-01' = {
  name: batchAccountName
  location: location
  tags: {
    ObjectName: batchAccountName
  }
  properties: {
    autoStorage: {
      storageAccountId: storageAccount.id
    }
  }
}

output storageAccountName string = storageAccount.name
output batchAccountName string = batchAccount.name
output location string = location
output resourceGroupName string = resourceGroup().name
output resourceId string = batchAccount.id

В файле Bicep определено два ресурса Azure:

• Microsoft.Storage/storageAccounts: создает учетную запись хранения.
• Microsoft.Batch/batchAccounts: создает учетную запись службы Batch.

Разверните BICEP-файл

1. Сохраните файл Bicep с именем main.bicep на локальном компьютере.

2. Разверните файл Bicep с помощью Azure CLI или Azure PowerShell.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep
   

   После завершения развертывания должно отобразиться сообщение о том, что развертывание успешно выполнено.

Проверка развертывания

Используйте портал Azure, Azure CLI или Azure PowerShell для получения списка ресурсов, развернутых в группе ресурсов.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Очистка ресурсов

Если вы планируете работать с другими нашими учебниками, эти ресурсы следует сохранить. Когда необходимость отпадает, используйте портал Azure, Azure CLI или Azure PowerShell, чтобы удалить группу ресурсов и все её ресурсы.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Следующие шаги

В этом кратком руководстве вы создали учетную запись Azure Batch и учетную запись хранения с помощью Bicep. Чтобы узнать больше о службе Azure Batch, перейдите к руководствам Azure Batch.