Azure Monitor Logs (Журналы мониторинга Azure)

Azure Backup предоставляет встроенные возможности мониторинга и оповещения в хранилище служб восстановления. Эти возможности доступны без дополнительной инфраструктуры управления. Единственным предварительным условием для этой возможности является настройка рабочей области Log Analytics. Эта функция поддерживается в следующих сценариях:

• Мониторинг данных из нескольких хранилищ служб восстановления в подписках
• Видимость пользовательских сценариев
• Настройка оповещений для пользовательских сценариев
• Просмотр сведений из локального компонента. Например, сведения System Center Data Protection Manager в Azure, которые на портале не отображаются в заданиях резервного копирования или оповещениях резервного копирования

Мониторинг заданий резервного копирования с помощью рабочей области Log Analytics

Предварительные требования для использования рабочей области Log Analytics

Прежде чем использовать Log Analytics для мониторинга, рассмотрите следующие предварительные требования:

• Убедитесь, что у вас настроена рабочая область Log Analytics. Если он недоступен, создайте его.
• Настройте параметры диагностики для отправки данных в Log Analytics.
• Настройте хранение таблиц или рабочей области Log Analytics на основе требуемого исторического хранения.

Создание оповещений с помощью Log Analytics

В Azure Monitor можно создать собственные оповещения в рабочей области Log Analytics. В рабочей области вы используете группы действий Azure для выбора предпочтительного механизма уведомлений.

Откройте раздел журналов рабочей области Log Analytics и создайте запрос для собственных журналов. При выборе нового правила генерации оповещений откроется страница создания оповещений Azure Monitor, как показано на следующем рисунке.

Здесь ресурс уже указан как рабочая область Log Analytics, а интеграция с группой действий обеспечена.

Условие тревоги

Определяющая характеристика оповещения — это его условие активации. Выберите Condition для автоматической загрузки запроса Kusto на странице Журналов, как показано на следующем рисунке. Здесь можно изменить условие в соответствии с вашими потребностями. Дополнительные сведения см. в разделе "Примеры запросов Kusto".

При необходимости можно изменить запрос Kusto. Выберите пороговое значение, период и частоту. Пороговое значение определяет, когда возникает оповещение. Период времени, в течение которого выполняется запрос. Например, если пороговое значение больше 0, период составляет 5 минут, а частота составляет 5 минут, то правило выполняет запрос каждые 5 минут, просматривая предыдущие 5 минут. Если число результатов больше 0, вы получите уведомление через выбранную группу действий.

Группы действий оповещений

Используйте группу действий для указания канала уведомлений. Чтобы просмотреть доступные механизмы уведомлений, в разделе "Группы действий" выберите "Создать".

Вы можете удовлетворить все требования к оповещению и мониторингу только из Log Analytics или использовать Log Analytics для дополнения встроенных уведомлений.

Дополнительные сведения см. в статье "Создание, просмотр и управление оповещениями журнала" с помощью Azure Monitor и создания групп действий и управления ими на портале Azure.

Примеры запросов Kusto

Графики по умолчанию предоставляют запросы Kusto для базовых сценариев, на которых можно создавать оповещения. Вы также можете изменить запросы, чтобы получать уведомления о данных, которые вас интересуют. Вставьте следующие образцы запросов Kusto на странице Журналов, а затем создайте оповещения по этим запросам.

Хранилища служб восстановления и хранилища резервных копий отправляют данные в общий набор таблиц, перечисленных в этой статье. Однако существуют незначительные различия в схеме хранилищ служб восстановления и хранилищ резервных копий (дополнительные сведения). Таким образом, этот раздел разделен на несколько подразделов, которые помогают использовать правильные запросы в зависимости от типов рабочей нагрузки или хранилища, которые требуется запрашивать.

Запросы, распространенные в хранилищах служб восстановления и хранилищах резервных копий

• Все успешные задания резервного копирования

  AddonAzureBackupJobs
  | where JobOperation=="Backup"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
  | where JobStatus=="Completed"
  

• Все неудачные задания резервного копирования

  AddonAzureBackupJobs
  | where JobOperation=="Backup"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
  | where JobStatus=="Failed"
  

Запросы, связанные с рабочими нагрузками в хранилище Recovery Services.

• Все успешные задания резервного копирования виртуальных машин Azure

  AddonAzureBackupJobs
  | where JobOperation=="Backup"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
  | where JobStatus=="Completed"
  | join kind=inner
  (
      CoreAzureBackup
      | where OperationName == "BackupItem"
      | where BackupItemType=="VM" and BackupManagementType=="IaaSVM"
      | distinct BackupItemUniqueId, BackupItemFriendlyName
  )
  on BackupItemUniqueId
  

• Все успешные задания резервного копирования журналов SQL

  AddonAzureBackupJobs
  | where JobOperation=="Backup" and JobOperationSubType=="Log"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
  | where JobStatus=="Completed"
  | join kind=inner
  (
      CoreAzureBackup
      | where OperationName == "BackupItem"
      | where BackupItemType=="SQLDataBase" and BackupManagementType=="AzureWorkload"
      | distinct BackupItemUniqueId, BackupItemFriendlyName
  )
  on BackupItemUniqueId
  

• Все успешные задания агента Azure Backup

  AddonAzureBackupJobs
  | where JobOperation=="Backup"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
  | where JobStatus=="Completed"
  | join kind=inner
  (
      CoreAzureBackup
      | where OperationName == "BackupItem"
      | where BackupItemType=="FileFolder" and BackupManagementType=="MAB"
      | distinct BackupItemUniqueId, BackupItemFriendlyName
  )
  on BackupItemUniqueId
  

• Объём резервного хранилища, потребляемый каждым элементом резервного копирования

  CoreAzureBackup
  //Get all Backup Items
  | where OperationName == "BackupItem"
  //Get distinct Backup Items
  | distinct BackupItemUniqueId, BackupItemFriendlyName
  | join kind=leftouter
  (AddonAzureBackupStorage
  | where OperationName == "StorageAssociation"
  //Get latest record for each Backup Item
  | summarize arg_max(TimeGenerated, *) by BackupItemUniqueId
  | project BackupItemUniqueId , StorageConsumedInMBs)
  on BackupItemUniqueId
  | project BackupItemUniqueId , BackupItemFriendlyName , StorageConsumedInMBs
  | sort by StorageConsumedInMBs desc
  

Запросы, относящиеся к рабочим нагрузкам хранилища резервных копий

• Все успешные задания резервного копирования Azure PostgreSQL

  AddonAzureBackupJobs
  | where JobOperation=="Backup"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
    | where DatasourceType == "Microsoft.DBforPostgreSQL/servers/databases"
  | where JobStatus=="Completed"	
  

• Все успешные задания восстановления дисков Azure

  AddonAzureBackupJobs
  | where JobOperation == "Restore"
  | summarize arg_max(TimeGenerated,*) by JobUniqueId
  | where DatasourceType == "Microsoft.Compute/disks"
  | where JobStatus=="Completed"
  

• Объем используемого резервного хранилища на элемент резервной копии

  CoreAzureBackup
  | where OperationName == "BackupItem"
  | summarize arg_max(TimeGenerated, *) by BackupItemUniqueId
  | project BackupItemUniqueId, BackupItemFriendlyName, StorageConsumedInMBs
  

Частота обновления диагностических данных

Диагностические данные из хранилища перекачиваются в рабочую область Log Analytics с некоторой задержкой. Каждое событие поступает в рабочую область Log Analytics 20–30 минут после отправки из хранилища служб восстановления. Ниже приведены дополнительные сведения о задержке:

• Во всех решениях встроенные оповещения службы резервного копирования отправляются сразу после их создания. Поэтому они обычно отображаются в рабочей области Log Analytics через 20–30 минут.
• Во всех решениях задания резервного копирования по запросу и задания восстановления отправляются сразу после их завершения.
• Для всех решений, кроме резервного копирования SQL и SAP HANA, запланированные задания резервного копирования отправляются сразу после их завершения.
• Для резервного копирования SQL и SAP HANA, так как резервные копии журналов могут выполняться каждые 15 минут, сведения обо всех завершенных запланированных заданиях резервного копирования, включая журналы, пакетируются и передаются каждые 6 часов.
• Во всех решениях другие сведения, такие как элемент резервного копирования, политика, точки восстановления, хранилище и т. д., передаются по крайней мере один раз в день.
• Изменение конфигурации резервного копирования (например, изменение политики или политики редактирования) активирует отправку всех связанных сведений о резервном копировании.

Мониторинг заданий резервного копирования с помощью журналов действий хранилища служб восстановления

Журналы действий также можно использовать для получения уведомлений о событиях, таких как успех резервного копирования. Чтобы начать, выполните следующие действия.

1. Войдите на портал Azure.
2. Откройте соответствующее хранилище служб восстановления.
3. В свойствах хранилища откройте раздел Журнал действий.

Чтобы определить соответствующий журнал и создать оповещение:

1. Убедитесь, что вы получаете журналы действий для успешного резервного копирования, применяя фильтры, показанные на следующем рисунке. Измените значение Timespan при необходимости для просмотра записей.

   

2. Выберите имя операции, чтобы просмотреть соответствующие сведения.

3. Выберите новое правило генерации оповещений , чтобы открыть страницу "Создать правило ".

4. Создайте оповещение, выполнив действия, описанные в статье "Создание, просмотр и управление оповещениями журнала действий" с помощью Azure Monitor.

   

Здесь ресурс — это само хранилище служб восстановления. Повторите те же действия для всех хранилищ, в которых требуется получать уведомления с помощью журналов действий. Условие не имеет порогового значения, периода или частоты, так как это оповещение основано на событиях. Как только создается соответствующий журнал действий, создается оповещение.

Мониторинг на масштабируемой платформе с использованием рабочей области Log Analytics

Все оповещения, созданные из журналов действий и рабочих областей Log Analytics, можно просмотреть в Azure Monitor. Просто откройте панель оповещений .

Хотя вы можете получать уведомления с помощью журналов действий, мы настоятельно рекомендуем использовать Log Analytics, а не журналы действий для мониторинга в масштабе. Для этого есть следующие причины.

• Ограниченные сценарии. Уведомления с помощью журналов действий применяются только к резервным копиям виртуальных машин Azure. Уведомления должны быть настроены для каждого хранилища Recovery Services.
• Определение соответствия: запланированная активность резервного копирования не соответствует последнему определению журналов действий. Вместо этого оно соотносится с журналами ресурсов. Это выравнивание приводит к непредвиденным последствиям при изменении данных, которые передаются через канал журнала действий.
• Проблемы с каналом журнала действий: в хранилищах служб восстановления журналы действий, которые выкачены из Azure Backup, следуют новой модели. К сожалению, это изменение влияет на создание журналов действий в Azure для государственных организаций, Azure в Германии и Microsoft Azure, управляемых 21Vianet. Если пользователи этих облачных служб создают или настраивают оповещения из журналов действий в Azure Monitor, оповещения не активируются. Кроме того, во всех общедоступных регионах Azure, если пользователь собирает журналы действий служб восстановления в рабочую область Log Analytics, эти журналы не отображаются.

Используйте рабочую область Log Analytics для масштабного мониторинга и оповещений всех рабочих нагрузок, защищённых с помощью Azure Backup.

Дальнейшие шаги

Сведения о создании пользовательских запросов см. в разделе "Модель данных Log Analytics".