Запросы для таблицы WVDConnectionNetworkData

Для получения информации о использовании этих запросов в портале Azure, см. руководство по Log Analytics. For the REST API, see Query.

Среднее время кругового путешествия со временем

Display a graph of round-trip time (in Milliseconds) across all connections in 10 min intervals at the 10th, 50th, and 90th percentiles.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Average BW across all connections

Отображает график пропускной способности (в килобайтах в секунду) для всех соединений в 10-минутных интервалах по 10-му, 50-му и 90-му процентилям.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Топ 10 пользователей с наибольшим временем кругового путешествия

Returns a list of the top 10 users with the highest average round-trip time (in Milliseconds).

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

Топ 10 пользователей с наименьшей пропускной способностью

Returns a list of the top 10 users with the lowest average bandwidth (in Kilobytes per second).

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Резюме времени задержки и пропускной способности

Возвращает 90-е процентиль для времени поездки туда и обратно (в миллисекундах) и пропускной способности (в килобайтах) для каждого соединения, вместе с дополнительными деталями соединения.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion