Запросы для таблицы SigninLogs

Сведения об использовании этих запросов в портале Azure см. в руководстве по Log Analytics. Сведения о REST API см. в разделе "Запрос".

Все события SiginLogs

Все события аутентификации Azure.

SigninLogs
| project UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, AppId, ResourceDisplayName

Ресурсы, к которым обращался пользователь

Перечисляет ресурсы, к которым был осуществлен доступ конкретным пользователем.

// Set v_Users_UPN with the UPN of the user of interest
let v_Users_UPN = "osotnoc@contoso.com";
SigninLogs
| where UserPrincipalName == v_Users_UPN
| summarize Count=count()  by ResourceDisplayName, AppDisplayName

Количество пользователей на ресурс

Количество уникальных пользователей по ресурсам.

SigninLogs
| project UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, AppId, ResourceDisplayName
| summarize UserCount=dcount(UserPrincipalName) by ResourceDisplayName

Количество пользователей на приложение

Различающееся количество пользователей по приложению.

SigninLogs
| project UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, AppId, ResourceDisplayName
| summarize UserCount=dcount(UserPrincipalName) by AppDisplayName

Причины ошибки входа

В списке запросов перечислены основные причины сбоев входа.

SigninLogs
| where ResultType != 0
| summarize Count=count() by ResultDescription, ResultType
| sort by Count desc nulls last

Не удалось пройти проверку MFA

Выделяет ошибки входа, вызванные ошибкой проверки MFA.

SigninLogs
| where ResultType == 50074
| project UserDisplayName, Identity,UserPrincipalName, ResultDescription,  AppDisplayName, AppId, ResourceDisplayName
| summarize FailureCount=count(), FailedResources=dcount(ResourceDisplayName), ResultDescription=any(ResultDescription) by UserDisplayName

Приложение не смогло выполнить бесшумный вход в систему

Неудачные попытки тихой авторизации приложения.

SigninLogs
| where ResultType == 50058
| project UserDisplayName, Identity,UserPrincipalName, ResultDescription,  AppDisplayName, AppId, ResourceDisplayName
| summarize FailureCount=count(), FailedResources=dcount(ResourceDisplayName), ResultDescription=any(ResultDescription) by UserDisplayName

Количество неудачных попыток входа

Ресурсы с большинством неудачных попыток входа.

SigninLogs
| where ResultType !=0
| summarize FailedLoginCount=count() by ResourceDisplayName
| sort by FailedLoginCount desc nulls last

Места входа

Сбои и успешные входы в систему по исходному местоположению.

SigninLogs
| summarize Successful=countif(ResultType==0), Failed=countif(ResultType!=0) by Location

Имена входа в ресурс

Выводит список входов в API.

SigninLogs
| where ResourceDisplayName == "Windows Azure Service Management API"
| project TimeGenerated, UserDisplayName, Identity,UserPrincipalName,  AppDisplayName, Success=iff(ResultType==0, "Success", "Fail")