Запросы для таблицы LAQueryLogs

Для получения информации об использовании этих запросов в портале Azure смотрите учебник по Log Analytics. Сведения о REST API см. в разделе "Запрос".

Наиболее запрашиваемые ResourceIds

Наиболее запрашиваемые ресурсы за последние 24 часа.

LAQueryLogs
| extend reqContext = parse_json(RequestContext)
| extend datasources = array_concat(reqContext["resources"], reqContext["workspaces"], reqContext["applications"])
| mv-expand datasources
| summarize reqCount = count() by tostring(datasources)
| order by reqCount desc

Неавторизованные пользователи

Получите список неавторизованных пользователей с количеством их запросов за последние 24 часа.

LAQueryLogs
| where ResponseCode == "403"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

Пользователи с ограниченным доступом

Получите список пользователей с ограничением доступа и количеством их запросов за последние 24 часа.

LAQueryLogs
| where ResponseCode == "429"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

Количество запросов по коду ответа

Количество запросов по коду ответа в пределах минутных интервалов за последний час.

LAQueryLogs
| where TimeGenerated > ago(1h)
| summarize count() by tostring(ResponseCode), bin(TimeGenerated, 1m)
| render columnchart with (kind=stacked)

Топ 10 запросов, потребляющих наибольшее количество ресурсов

Получить 10 наиболее ресурсоемких запросов (на основе потребления процессора) за последние 24 часа.

LAQueryLogs
| top 10 by StatsCPUTimeMs desc nulls last 

Топ 10 наибольших временных интервалов запросов

Получите 10 лучших запросов, которые охватывали самый длительный временной промежуток за последние 24 часа.

LAQueryLogs
| extend DataProcessedTimeRange = format_timespan(StatsDataProcessedEnd - StatsDataProcessedStart, 'dd.hh:mm:ss:FF')
| top 10 by DataProcessedTimeRange desc nulls last