Запросы для таблицы KubePodInventory

Для получения сведений об использовании этих запросов в Azure Portal см. руководство по Log Analytics. Сведения о REST API см. в разделе "Запрос".

Модули Pod в цикле аварии

Определяет, имеет ли модуль pod или контейнеры этап аварийного цикла.

//Determines whether Pods/Containers has Crash-Loop phase
KubePodInventory
| where ContainerStatus  == 'waiting' 
| where ContainerStatusReason == 'CrashLoopBackOff' or ContainerStatusReason == 'Error'
| extend ContainerLastStatus=todynamic(ContainerLastStatus)
| summarize RestartCount = arg_max(ContainerRestartCount, Computer, Namespace, ContainerLastStatus.reason) by Name

Модули Pod в состоянии ожидания

Проверьте модули Pod, которые не могут быть запущены и время ожидания.

//Check Pods that cannot be started and its pending time
KubePodInventory
| where PodStatus == 'Pending'
| project PodCreationTimeStamp, Namespace, PodStartTime, PodStatus, Name, ContainerStatus
| summarize Start = any(PodCreationTimeStamp), arg_max(PodStartTime, Namespace) by Name
| extend PodStartTime = iff(isnull(PodStartTime), now(), PodStartTime)
| extend PendingTime = PodStartTime - Start
| project Name, Namespace ,PendingTime

Поиск в KubePodInventory

Найдите конкретное значение в таблице KubePodInventory. Обратите внимание, что для получения результатов необходимо обновить параметр <SearchValue>.

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
KubePodInventory
| where * contains tostring(SearchValue)
| take 1000