Запросы для таблицы FunctionAppLogs

Сведения об использовании этих запросов в портале Azure смотрите в руководстве по Log Analytics. Сведения о REST API см. в разделе "Запрос".

Показать журналы приложений из Function Apps

Список журналов приложений, отсортированных по времени (последние журналы отображаются сначала).

FunctionAppLogs
| project TimeGenerated, HostInstanceId, Message, _ResourceId
| sort by TimeGenerated desc

Показать журнал предупреждений или исключений

Список журналов, содержащих предупреждения или исключения (последние журналы отображаются сначала).

FunctionAppLogs
| where Level == "Warning" or Level == "Error"
| project TimeGenerated, HostInstanceId, Level, Message, _ResourceId
| sort by TimeGenerated desc

Число ошибок и исключений

Покажите столбчатую диаграмму числа журналов, содержащих предупреждения или ошибки за последний час, для каждого приложения.

FunctionAppLogs
| where TimeGenerated > ago(1h)
| where Level == "Warning" or Level == "Error"
| summarize count_per_app = count() by _ResourceId
| sort by count_per_app desc
| render columnchart

Функциональная активность с течением времени

Линейный график, показывающий динамику объема запросов по каждой функции во времени.

FunctionAppLogs
//| where _ResourceId == "MyResourceId" // Uncomment and enter a resource ID to get results for a specific resource
| where Category startswith "Function." and Message startswith "Executed "
| summarize count() by bin(TimeGenerated, 1h), FunctionName // Aggregate by hour
| render timechart

Результаты функции

Результаты вызова отдельных функций за последний час (последние журналы показаны первыми).

FunctionAppLogs
| where TimeGenerated > ago(1h)
| where Category startswith "Function." and Message startswith "Executed "
| parse Message with "Executed '" Name "' ("  Result ", Id=" Id ", Duration=" Duration:long "ms)"
| project TimeGenerated, FunctionName, Result, FunctionInvocationId, Duration, _ResourceId
| sort by TimeGenerated desc

Частота ошибок функции

Суммирование успешности и ошибок функций в час.

FunctionAppLogs
| where Category startswith "Function." and Message startswith "Executed "
| parse Message with "Executed '" Name "' ("  Result ", Id=" Id ", Duration=" Duration:long "ms)"
// | where Name == "MyFunction" // Use this to restrict to a specific function
| summarize count() by bin(TimeGenerated, 1h), Name, Result, _ResourceId
| order by TimeGenerated desc