Запросы для таблицы CopilotActivity

Сведения о том, как использовать эти запросы в портале Azure, можно найти в учебнике Log Analytics. Сведения о REST API см. в разделе "Запрос".

Взаимодействие Copilot с пользователем

Показывает взаимодействия Copilot, сгруппированные пользователем с подсчетами и диапазоном времени за последние 7 дней

LLMActivity
| where RecordType == "CopilotInteraction"
| where TimeGenerated >= ago(7d)
| summarize InteractionCount = count(),
            FirstInteraction = min(TimeGenerated),
            LastInteraction = max(TimeGenerated)
            by ActorName, ActorUserId
| order by InteractionCount desc

Действие управления подключаемым модулем Copilot

Отображение изменений в создании, обновлении и состоянии подключаемого модуля за последние 30 дней

LLMActivity
| where RecordType in ("CreateCopilotPlugin", "UpdateCopilotPlugin", "EnableCopilotPlugin", "DisableCopilotPlugin")
| where TimeGenerated >= ago(30d)
| project TimeGenerated, ActorName, RecordType, AgentName, SrcIpAddr
| order by TimeGenerated desc

Управление Copilot PromptBook

Отслеживает создание, обновление и удаление в командной книге за последние 30 дней

LLMActivity
| where RecordType in ("CreateCopilotPromptBook", "UpdateCopilotPromptBook", "DeleteCopilotPromptBook")
| where TimeGenerated >= ago(30d)
| extend PromptBookId = tostring(LLMEventData.Resource[0].Property)
| project TimeGenerated, ActorName, RecordType, PromptBookId, SrcIpAddr
| order by TimeGenerated desc

События безопасности и соответствия copilot

Показывает события, связанные с безопасностью Copilot, включая обнаружение тюрьмы за последние 7 дней

LLMActivity
| where RecordType == "CopilotInteraction"
| where TimeGenerated >= ago(7d)
| extend Messages = LLMEventData.Messages
| mv-expand Messages
| where tobool(Messages.JailbreakDetected) == true
| project TimeGenerated, ActorName, ActorUserId, AgentName,
          MessageId = tostring(Messages.Id),
          JailbreakDetected = tobool(Messages.JailbreakDetected)
| order by TimeGenerated desc

Статистика использования модели ИИ

Показывает, какие модели ИИ используются в взаимодействиях Copilot за последние 30 дней

LLMActivity
| where RecordType == "CopilotInteraction"
| where TimeGenerated >= ago(30d)
| where isnotempty(AIModelName)
| summarize InteractionCount = count(),
            UniqueUsers = dcount(ActorUserId),
            FirstUsed = min(TimeGenerated),
            LastUsed = max(TimeGenerated)
            by AIModelName, AIModelVersion
| order by InteractionCount desc

Доступ к ресурсам, к которым обращается Copilot

Отображение внешних ресурсов, доступ к которые были доступны во время взаимодействия Copilot за последние 7 дней

LLMActivity
| where RecordType == "CopilotInteraction"
| where TimeGenerated >= ago(7d)
| extend AccessedResources = LLMEventData.AccessedResources
| mv-expand AccessedResources
| where isnotempty(AccessedResources.SiteUrl)
| project TimeGenerated, ActorName, AgentName,
          ResourceUrl = tostring(AccessedResources.SiteUrl),
          Action = tostring(AccessedResources.Action),
          ResourceType = tostring(AccessedResources.Type)
| summarize AccessCount = count() by ResourceUrl, Action, ResourceType
| order by AccessCount desc