Запросы для таблицы AEWComputePipelinesLogs

Сведения об использовании этих запросов в портале Azure смотрите в руководстве Log Analytics. Сведения о REST API см. в разделе "Запрос".

AEWComputePipelinesLogs извлекает количество ежедневных задач

Получить ежедневное число задач из записей потоков вычислений в выбранном диапазоне времени.

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestSucceeded" or EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| summarize Count = count() by Date = bin(TimeGenerated, 1d), ExperimentationGroup = tostring(Properties.ExperimentationGroup)
| sort by Date

AEWComputePipelinesLogs получает сведения о неудачных задачах

Получите подробности последних 100 неудачных задач из записей вычислительных конвейеров за выбранный диапазон времени.

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| project
    TimeGenerated
    ,EventName
    ,ExperimentationGroup = Properties.ExperimentationGroup
    ,AnalysisType = Properties.AnalysisType
| sort by TimeGenerated desc
| take 100

AEWComputePipelinesLogs получают длительные задания

Получите данные о долго выполняющихся заданиях из записей вычислительных конвейеров за последние семь дней.

AEWComputePipelinesLogs
| where EventName =~ "CosmosJobUtilization"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| where todouble(Properties.JobRunningInSeconds) >= 24 * 60 * 60
| project
    TimeGenerated
    ,EventName
    ,ExperimentationGroup = Properties.ExperimentationGroup
    ,AnalysisType = Properties.AnalysisType
| sort by TimeGenerated desc

AEWComputePipelinesLogs получает время задержки задачи E2E.

Получение времени задержки задачи E2E записей вычислительных конвейеров в выбранном диапазоне времени.

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestSucceeded" or EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| summarize
  ScorecardRequestTimeInHoursP99 = percentile(todouble(Properties.ScorecardProcessingInSeconds) / 60 / 60, 99)
  ,ScorecardRequestTimeInHoursAvg = avg(todouble(Properties.ScorecardProcessingInSeconds) / 60 / 60)
  by Date = bin(TimeGenerated, 1d), ExperimentationGroup = tostring(Properties.ExperimentationGroup)
| sort by Date, ExperimentationGroup