Запросы для таблицы ACSCallRecordingIncomingOperations

Для получения информации о том, как использовать эти запросы в портале Azure, см. Log Analytics tutorial. Сведения о REST API см. в разделе "Запрос".

Операции записи звонков

Возвращает все уникальные комбинации операций записи звонков и пар версий.

ACSCallRecordingIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Рассчитать процентиль длительности операции записи вызовов

Вычисляет 90-й, 95-й и 99-й процентиль длительности выполнения в миллисекундах для каждой операции записи звонка. Его можно настроить для выполнения одной операции или для других процентилей.

ACSCallRecordingIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

Лучшие 5 IP-адресов для каждой операции записи звонков

Для каждой операции записи вызова извлеките 5 IP-адресов, которые чаще всего выполняли эту операцию.

ACSCallRecordingIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Операционные ошибки записи звонков

Перечислите все ошибки записи звонков в порядке убывания их давности.

ACSCallRecordingIncomingOperations
| where ResultType == "Failure"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature
| order by TimeGenerated desc
| limit 100

Результаты операций записи звонков

Для каждой операции записи вызова подсчитывайте типы возвращаемых результатов.

ACSCallRecordingIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Журналы записи звонков по ID

Запрашивает журналы записи звонка для конкретного идентификатора соединения вызова или идентификатора корреляции.

ACSCallRecordingIncomingOperations
//| where CorrelationId == "<correlation ID>" // This can be uncommented to filter on a specific correlation ID
//| where CallConnectionId == "<callConnectionId>" // This can be uncommented to filter on a specific call connection ID
| project CorrelationId, CallConnectionId, OperationName, OperationVersion
| limit 100