Запросы к таблице ACSAdvancedMessagingOperations

Сведения об использовании этих запросов в портале Azure см. руководство по Log Analytics. Сведения о REST API см. в разделе "Запрос".

Расширенные операции обмена сообщениями

Возвращает все различные сочетания операций расширенного обмена сообщениями и пар версий.

ACSAdvancedMessagingOperations
| distinct OperationName, OperationVersion 
| limit 100

Перцентили времени выполнения операций усложненной системы обмена сообщениями

Вычисляет 90-й, 95-й и 99-й процентиль длительности выполнения в миллисекундах для каждой операции чата. Его можно настроить для одной операции или для других процентилей.

ACSAdvancedMessagingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

Топ-5 IP-адресов для каждой операции обмена сообщениями

Для каждой операции расширенного обмена сообщениями получите 5 IP-адресов, которые чаще всего вызывали эту операцию.

ACSAdvancedMessagingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Ошибки функционирования расширенного обмена сообщениями

Перечислите все ошибки расширенного обмена сообщениями, упорядоченные по давности.

ACSAdvancedMessagingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

Число результатов операций расширенного обмена сообщениями

Для каждой операции расширенного обмена сообщениями подсчитываются типы возвращаемых результатов.

ACSAdvancedMessagingOperations
| summarize Count = count() by OperationName, OperationVersion, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Активность продвинутого канала обмена сообщениями

Сводка по активности сообщений на каналах за последние 24 часа.

ACSAdvancedMessagingOperations
| where TimeGenerated > ago(24h)
| summarize count() by ChannelId, MessageType
| order by ChannelId asc

Число состояний сообщений продвинутого обмена сообщениями

Количество сообщений за последние 24 часа.

ACSAdvancedMessagingOperations
| where TimeGenerated > ago(24h)
| summarize Count = count() by MessageType, MessageStatus
| order by MessageType asc, Count desc