Создание двух веб-приложений, подключенных безопасно с помощью частной конечной точки и интеграции виртуальной сети

В этой статье показан пример использования частной конечной точки и региональной интеграции виртуальной сети для безопасного подключения двух веб-приложений (интерфейсных и внутренних серверов) со следующей конфигурацией Terraform:

1. Развертывание виртуальной сети
2. Создание первой подсети для интеграции
3. Создайте вторую подсеть для частной конечной точки и отключите политики сети подсети для частных конечных точек (set private_endpoint_network_policies_enabled = false)
4. Развертывание одного плана службы приложений типа Basic, Standard, PremiumV2, PremiumV3, IsolatedV2, Functions Premium (иногда называется планом Elastic Premium), необходимого для функции частной конечной точки
5. Создайте интерфейсный веб-приложение с определенными параметрами приложения для использования частной зоны DNS. Дополнительные сведения см. в частных зонах Azure DNS.
6. Подключение внешнего веб-приложения к подсети интеграции
7. Создание серверного веб-приложения
8. Создайте частную зону DNS с именем зоны приватного канала для веб-приложений (privatelink.azurewebsites.net)
9. Связывание этой зоны с виртуальной сетью
10. Создайте частную конечную точку для внутреннего веб-приложения в подсети конечной точки и зарегистрируйте DNS-имена (сайт и SCM) в ранее созданной частной зоне DNS.

Использование terraform в Azure

Перейдите к документации по Azure, чтобы узнать, как использовать Terraform с Azure.

Полный terraform-файл

Чтобы использовать этот файл, замените заполнители <unique-frontend-app-name и unique-backend-app-name> (имя приложения используется для формирования уникального DNS-имени по всему миру).<>

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~> 3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

resource "azurerm_resource_group" "rg" {
  name     = "appservice-rg"
  location = "francecentral"
}

resource "azurerm_virtual_network" "vnet" {
  name                = "vnet"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  address_space       = ["10.0.0.0/16"]
}

resource "azurerm_subnet" "integrationsubnet" {
  name                 = "integrationsubnet"
  resource_group_name  = azurerm_resource_group.rg.name
  virtual_network_name = azurerm_virtual_network.vnet.name
  address_prefixes     = ["10.0.1.0/24"]

  delegation {
    name = "delegation"

    service_delegation {
      name = "Microsoft.Web/serverFarms"
    }
  }
}

resource "azurerm_subnet" "endpointsubnet" {
  name                 = "endpointsubnet"
  resource_group_name  = azurerm_resource_group.rg.name
  virtual_network_name = azurerm_virtual_network.vnet.name
  address_prefixes     = ["10.0.2.0/24"]

  private_endpoint_network_policies_enabled = false
}

resource "azurerm_service_plan" "appserviceplan" {
  name                = "appserviceplan"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  os_type             = "Windows"
  sku_name            = "P1v2"
}

resource "azurerm_windows_web_app" "frontwebapp" {
  name                = "<unique-frontend-app-name>"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  service_plan_id     = azurerm_service_plan.appserviceplan.id

  site_config {}

  app_settings = {
    "WEBSITE_DNS_SERVER"     = "168.63.129.16"
    "WEBSITE_VNET_ROUTE_ALL" = "1"
  }
}

resource "azurerm_app_service_virtual_network_swift_connection" "vnetintegrationconnection" {
  app_service_id = azurerm_windows_web_app.frontwebapp.id
  subnet_id      = azurerm_subnet.integrationsubnet.id
}

resource "azurerm_windows_web_app" "backwebapp" {
  name                = "<unique-backend-app-name>"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  service_plan_id     = azurerm_service_plan.appserviceplan.id

  site_config {}
}

resource "azurerm_private_dns_zone" "dnsprivatezone" {
  name                = "privatelink.azurewebsites.net"
  resource_group_name = azurerm_resource_group.rg.name
}

resource "azurerm_private_dns_zone_virtual_network_link" "dnszonelink" {
  name                  = "dnszonelink"
  resource_group_name   = azurerm_resource_group.rg.name
  private_dns_zone_name = azurerm_private_dns_zone.dnsprivatezone.name
  virtual_network_id    = azurerm_virtual_network.vnet.id
}

resource "azurerm_private_endpoint" "privateendpoint" {
  name                = "backwebappprivateendpoint"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  subnet_id           = azurerm_subnet.endpointsubnet.id

  private_dns_zone_group {
    name                 = "privatednszonegroup"
    private_dns_zone_ids = [azurerm_private_dns_zone.dnsprivatezone.id]
  }

  private_service_connection {
    name                           = "privateendpointconnection"
    private_connection_resource_id = azurerm_windows_web_app.backwebapp.id
    subresource_names              = ["sites"]
    is_manual_connection           = false
  }
}

Дальнейшие действия

Дополнительные сведения об использовании Terraform в Azure