vcpkg_check_features

2024-01-10

Controllare se una o più funzionalità fanno parte di un'installazione del pacchetto.

Utilizzo

vcpkg_check_features(
    OUT_FEATURE_OPTIONS <out-var>
    [PREFIX <prefix>]
    [FEATURES
        [<feature-name> <feature-var>]...
        ]
    [INVERTED_FEATURES
        [<feature-name> <feature-var>]...
        ]
)

L'oggetto <out-var> deve essere impostato su FEATURE_OPTIONS per convenzione.

vcpkg_check_features() will:

per ogni <feature-name> oggetto passato in FEATURES:
- se la funzionalità è impostata, aggiungere -D<feature-var>=ON a <out-var>e impostare su <prefix>_<feature-var> ON.
- se la funzionalità non è impostata, aggiungere -D<feature-var>=OFF a <out-var>e impostare su <prefix>_<feature-var> OFF.
per ogni <feature-name> oggetto passato in INVERTED_FEATURES:
- se la funzionalità è impostata, aggiungere -D<feature-var>=OFF a <out-var>e impostare su <prefix>_<feature-var> OFF.
- se la funzionalità non è impostata, aggiungere -D<feature-var>=ON a <out-var>e impostare su <prefix>_<feature-var> ON.

Se <prefix> non viene passato, il set di vars di funzionalità è semplicemente <feature-var>, non _<feature-var>.

Se INVERTED_FEATURES non viene passato, la FEATURES parola chiave è facoltativa. Questo comportamento è deprecato.

Se lo stesso <feature-var> viene passato più volte, vcpkg_check_features genererà un errore irreversibile, poiché si tratta di un bug.

Esempi

Esempio 1: Funzionalità regolari

$ ./vcpkg install mimalloc[asm,secure]

# ports/mimalloc/portfile.cmake
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
    FEATURES
        asm       MI_SEE_ASM
        override  MI_OVERRIDE
        secure    MI_SECURE
)

vcpkg_cmake_configure(
    SOURCE_PATH "${SOURCE_PATH}"
    OPTIONS
        # Expands to "-DMI_SEE_ASM=ON;-DMI_OVERRIDE=OFF;-DMI_SECURE=ON"
        ${FEATURE_OPTIONS}
)

Esempio 2: funzionalità invertite

$ ./vcpkg install cpprestsdk[websockets]

# ports/cpprestsdk/portfile.cmake
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
    INVERTED_FEATURES
        brotli      CPPREST_EXCLUDE_BROTLI
        websockets  CPPREST_EXCLUDE_WEBSOCKETS
)

vcpkg_cmake_configure(
    SOURCE_PATH "${SOURCE_PATH}"
    OPTIONS
        # Expands to "-DCPPREST_EXCLUDE_BROTLI=ON;-DCPPREST_EXCLUDE_WEBSOCKETS=OFF"
        ${FEATURE_OPTIONS}
)

Esempio 3: Impostare più opzioni per la stessa funzionalità

$ ./vcpkg install pcl[cuda]

# ports/pcl/portfile.cmake
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
    FEATURES
        cuda  WITH_CUDA
        cuda  BUILD_CUDA
        cuda  BUILD_GPU
)

vcpkg_cmake_configure(
    SOURCE_PATH "${SOURCE_PATH}"
    OPTIONS
        # Expands to "-DWITH_CUDA=ON;-DBUILD_CUDA=ON;-DBUILD_GPU=ON"
        ${FEATURE_OPTIONS}
)

Esempio 4: Usare le funzionalità normali e invertite

$ ./vcpkg install rocksdb[tbb]

# ports/rocksdb/portfile.cmake
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
    FEATURES
        tbb   WITH_TBB
    INVERTED_FEATURES
        tbb   ROCKSDB_IGNORE_PACKAGE_TBB
)

vcpkg_cmake_configure(
    SOURCE_PATH "${SOURCE_PATH}"
    OPTIONS
        # Expands to "-DWITH_TBB=ON;-DROCKSDB_IGNORE_PACKAGE_TBB=OFF"
        ${FEATURE_OPTIONS}
)

Esempi nei file di porta

Origine

scripts/cmake/vcpkg_check_features.cmake