OFFSET

Si applica a:colonna calcolatatabella calcolata calcolo visivomisura

Restituisce una singola riga posizionata prima o dopo la riga corrente all'interno della stessa tabella da un offset specificato. Se non è possibile dedurre la riga corrente in una singola riga, è possibile che vengano restituite più righe.

Sintassi

OFFSET ( <delta>[, <relation> or <axis>][, <orderBy>][, <blanks>][, <partitionBy>][, <matchBy>][, <reset>] )

Parametri

Valore restituito

Una o più righe di relation.

Osservazioni

Ad eccezione delle colonne aggiunte da DAX funzioni di tabella, ogni colonna in relation, quando matchBy non è presente o ogni colonna in matchBy e partitionBy, quando matchBy è presente, deve avere un valore esterno corrispondente per definire la riga corrente su cui operare, con il comportamento seguente:

• Se è presente esattamente una colonna esterna corrispondente, viene usato il relativo valore.
• Se non è presente alcuna colonna esterna corrispondente, eseguire le operazioni seguenti:
  • OFFSET determinerà innanzitutto tutte le colonne che non dispongono di una colonna esterna corrispondente.
  • Per ogni combinazione di valori esistenti per queste colonne nel contesto padre di OFFSET, OFFSET viene valutata e viene restituita una riga.
  • OFFSET'output finale è un'unione di queste righe.
• Se sono presenti più colonne esterne corrispondenti, viene restituito un errore.

Se tutte le colonne di relationsono state aggiunte da DAX funzioni di tabella, viene restituito un errore.

Se matchBy è presente, OFFSET tenterà di usare matchBy e partitionBy colonne per identificare la riga. Se matchBy non è presente e le colonne specificate all'interno di orderBy e partitionBy non possono identificare in modo univoco ogni riga in relation, quindi:

• OFFSET tenterà di trovare il minor numero di colonne aggiuntive necessarie per identificare in modo univoco ogni riga.
• Se è possibile trovare tali colonne, OFFSET accoderà automaticamente queste nuove colonne a orderBye ogni partizione viene ordinata usando questo nuovo set di colonne OrderBy.
• Se non è possibile trovare tali colonne, viene restituito un errore.

Viene restituita una tabella vuota se:

• Il valore esterno corrispondente di una colonna OrderBy o PartitionBy non esiste all'interno di relation.
• Il valore delta determina uno spostamento a una riga che non esiste all'interno della partizione.

Se OFFSET viene utilizzato all'interno di una colonna calcolata definita nella stessa tabella di relatione orderBy viene omesso, viene restituito un errore.

reset possono essere usati solo nei calcoli visivi e non possono essere usati in combinazione con orderBy o partitionBy. Se reset è presente, è possibile specificare axis ma non relation.

Se il valore di reset è assoluto (ad esempio, un numero intero HIGHESTPARENT positivo o un riferimento a un campo) e il calcolo viene valutato al livello di destinazione o superiore al livello di destinazione nella gerarchia, il calcolo viene reimpostato per ogni singolo elemento. Ovvero, la funzione viene valutata all'interno di una partizione contenente solo l'elemento specifico.

Esempio 1 : colonna calcolata

La query di DAX seguente:

DEFINE
VAR vRelation = SUMMARIZECOLUMNS ( 
                    DimProductCategory[EnglishProductCategoryName], 
                    DimDate[CalendarYear], 
                    "CurrentYearSales", SUM(FactInternetSales[SalesAmount]) 
                  )
EVALUATE
ADDCOLUMNS (
    vRelation, 
    "PreviousYearSales", 
    SELECTCOLUMNS(
        OFFSET ( 
                -1, 
                vRelation, 
                ORDERBY([CalendarYear]), 
                PARTITIONBY([EnglishProductCategoryName])
        ),
        [CurrentYearSales]
    )
)

Restituisce una tabella che riepiloga le vendite totali per ogni categoria di prodotto e anno di calendario, nonché le vendite totali per tale categoria nell'anno precedente.

Esempio 2 : misura

La query di DAX seguente:

DEFINE
MEASURE DimProduct[CurrentYearSales] = SUM(FactInternetSales[SalesAmount])
MEASURE DimProduct[PreviousYearSales] = CALCULATE(SUM(FactInternetSales[SalesAmount]), OFFSET(-1, , ORDERBY(DimDate[CalendarYear])))
EVALUATE
SUMMARIZECOLUMNS (
    DimDate[CalendarYear],
    "CurrentYearSales", DimProduct[CurrentYearSales],
    "PreviousYearSales", DimProduct[PreviousYearSales]
)

Usa OFFSET() in una misura per restituire una tabella che riepiloga le vendite totali per ogni anno di calendario e le vendite totali per l'anno precedente.

Esempio 3 : colonna calcolata

La query di DAX seguente:

EVALUATE
ADDCOLUMNS (
    FactInternetSales,
    "Previous Sales Amount",
        SELECTCOLUMNS (
            OFFSET (
                -1,
                FactInternetSales,
                ORDERBY ( FactInternetSales[SalesAmount], DESC ),
                PARTITIONBY ( FactInternetSales[ProductKey] ),
                MATCHBY( FactInternetSales[SalesOrderNumber], FactInternetSales[SalesOrderLineNumber] )
            ),
            FactInternetSales[SalesAmount]
        )
)

Restituisce la tabella FactInternetSales con l'aggiunta di una colonna, che indica, per ogni vendita, l'importo della vendita precedente, dello stesso prodotto, in ordine decrescente dell'importo delle vendite, con la vendita corrente identificata dal relativo SalesOrderNumber e SalesOrderLineNumber. Senza MATCHBY, la query restituirà un errore perché non sono presenti colonne chiave nella tabella FactInternetSales.

Esempio 4 - Calcolo visivo

Il calcolo visivo seguente DAX query:

SalesRelativeToPreviousMonth = [SalesAmount] - CALCULATE(SUM([SalesAmount]), OFFSET(-1, ROWS, HIGHESTPARENT))

Restituisce la differenza delle vendite totali tra ogni mese e quella precedente all'interno dello stesso anno.

Lo screenshot seguente mostra la matrice visiva e l'espressione di calcolo visivo:

Contenuto correlato

INDEX ORDERBY PARTITIONBY MATCHBY WINDOW RANK ROWNUMBER