Guida introduttiva: Creare e distribuire un flusso di lavoro dell'app per la logica a consumo in App per la logica di Azure multi-tenant con Bicep

Si applica a: App per la logica di Azure (A consumo)

App per la logica di Azure è un servizio cloud che consente di creare ed eseguire flussi di lavoro automatizzati che integrano dati, app, servizi basati sul cloud e sistemi locali scegliendo tra centinaia di connettori. Questo argomento di avvio rapido è incentrato sul processo di distribuzione di un file Bicep per creare un flusso di lavoro di app per la logica a consumo di base che controlla lo stato di Azure in base a una pianificazione oraria ed eseguito in App per la logica di Azure multi-tenant.

Bicep è un linguaggio specifico di dominio (DSL) che usa la sintassi dichiarativa per distribuire le risorse di Azure. Offre sintassi concisa, indipendenza dai tipi affidabile e supporto per il riutilizzo del codice. Bicep offre la migliore esperienza di creazione per le soluzioni di infrastruttura come codice in Azure.

Prerequisiti

Se non si ha una sottoscrizione di Azure, creare un account Azure gratuito prima di iniziare.

Esaminare il file Bicep

Il file Bicep usato in questo avvio rapido proviene dai modelli di avvio rapido di Azure.

Il modello di avvio rapido crea un flusso di lavoro dell'app per la logica a consumo che usa il trigger Ricorrenza predefinito , impostato per l'esecuzione ogni ora e un'azione HTTP predefinita, che chiama un URL che restituisce lo stato per Azure. Le operazioni predefinite vengono eseguite in modo nativo nella piattaforma App per la logica di Azure.

Questo file Bicep crea la risorsa di Azure seguente:

• Microsoft.Logic/workflows, che crea il flusso di lavoro per un'app per la logica.

@description('The name of the logic app to create.')
param logicAppName string

@description('A test URI')
param testUri string = 'https://azure.status.microsoft/status/'

@description('Location for all resources.')
param location string = resourceGroup().location

var frequency = 'Hour'
var interval = '1'
var type = 'recurrence'
var actionType = 'http'
var method = 'GET'
var workflowSchema = 'https://schema.management.azure.com/providers/Microsoft.Logic/schemas/2016-06-01/workflowdefinition.json#'

resource stg 'Microsoft.Logic/workflows@2019-05-01' = {
  name: logicAppName
  location: location
  tags: {
    displayName: logicAppName
  }
  properties: {
    definition: {
      '$schema': workflowSchema
      contentVersion: '1.0.0.0'
      parameters: {
        testUri: {
          type: 'string'
          defaultValue: testUri
        }
      }
      triggers: {
        recurrence: {
          type: type
          recurrence: {
            frequency: frequency
            interval: interval
          }
        }
      }
      actions: {
        actionType: {
          type: actionType
          inputs: {
            method: method
            uri: testUri
          }
        }
      }
    }
  }
}

output name string = stg.name
output resourceId string = stg.id
output resourceGroupName string = resourceGroup().name
output location string = location

Distribuire il file Bicep

1. Salvare il file Bicep come main.bicep nel computer locale.

2. Distribuisci il file Bicep usando l'interfaccia della riga di comando di Azure o Azure PowerShell.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters logicAppName=<logic-name>
   

Al termine della distribuzione, visualizzerai un messaggio che indica che la distribuzione è stata completata.

Esaminare le risorse distribuite

Usare il portale di Azure, l'interfaccia della riga di comando di Azure o Azure PowerShell per elencare le risorse distribuite nel gruppo di risorse.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Pulire le risorse

Quando l'app per la logica non è più necessaria, usare il portale di Azure, l'interfaccia della riga di comando di Azure o Azure PowerShell per eliminare il gruppo di risorse e le relative risorse.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Passaggi successivi