Condividi tramite

Ridurre le emissioni di carbonio in Azure

L'ottimizzazione del carbonio in Azure funziona con Azure Advisor per fornire raccomandazioni di ottimizzazione. Azure Advisor identifica le risorse inattive e sottoutilizzate e mostra il risparmio di carbonio e sui costi associati dell'implementazione delle raccomandazioni. Le raccomandazioni possono includere l'arresto di macchine virtuali inattive e il ridimensionamento delle macchine virtuali. Per altre raccomandazioni e informazioni su Azure Advisor, vedere Ridurre i costi del servizio usando Azure Advisor.

Per visualizzare le raccomandazioni per l'ottimizzazione del carbonio, passare alla pagina Riduzione delle Emissioni e selezionare la sottoscrizione e i gruppi di risorse desiderati.

Questa pagina mostra il numero totale di raccomandazioni disponibili e potenziali opportunità di risparmio in termini di costi e carbonio. Mostra anche gli equivalenti a risparmio di carbonio calcolati dal calcolatore United States EPA Greenhouse Gas Equivalents.

Visualizzare le raccomandazioni

L'elenco delle raccomandazioni nella tabella mostra risorse utilizzate in modo inefficiente che possono contribuire a ridurre le emissioni di carbonio. Ogni raccomandazione mostra il risparmio di carbonio associato e potenziali risparmi sui costi che possono provenire da una raccomandazione.

Agire sulla raccomandazione

Per agire sulla raccomandazione, selezionare il nome della risorsa o il testo nella colonna Raccomandazione. La selezione del testo della raccomandazione consente di passare alla pagina dell'azione per la risorsa. Ad esempio, la pagina di ridimensionamento, la pagina di modifica del numero di istanze o la pagina di panoramica della risorsa per le raccomandazioni di eliminazione.

Screenshot che mostra la pagina di riduzione delle emissioni.

Convertire i risparmi sulle emissioni in equivalenti

Il calcolatore delle equivalenze dei gas serra consente di convertire i dati sulle emissioni nella quantità equivalente di anidride carbonica (CO2) emessa in base a tale quantità. La calcolatrice consente di tradurre le misurazioni astratte in termini concreti che è possibile comprendere, ad esempio le emissioni annuali di alberi, famiglie o cestini. Questo calcolatore potrebbe essere utile per comunicare la strategia di riduzione del gas serra, gli obiettivi di riduzione o altre iniziative volte a ridurre le emissioni di gas serra.

Per informazioni sui tipi di raccomandazioni, vedere Ridurre i costi del servizio usando Azure Advisor.

Raccomandazioni per la riduzione delle emissioni di esportazione

È possibile esportare raccomandazioni per la riduzione delle emissioni usando Azure Resource Graph. Esegui la query seguente in Azure Resource Graph Explorer. Successivamente, è possibile scaricare i risultati come CSV.

L'esportazione include:

  • ID raccomandazione
  • ID sottoscrizione/nome sottoscrizione
  • Nome del gruppo di risorse
  • Risparmio sui costi mensili
  • Risparmio di carbonio mensile in chilogrammi
  • Nome risorsa
  • Messaggio di raccomandazione
  • Tipo di raccomandazione
  • Dettagli sulla raccomandazione, inclusi i metadati della risorsa, ad esempio l'ID risorsa e il nome del ruolo
// Export emissions reduction recommendations using Azure Resource Graph

advisorresources
  | where tolower(type) == "microsoft.advisor/recommendations"
  | extend RecommendationTypeId = tostring(properties.recommendationTypeId)
  | where RecommendationTypeId in ("94aea435-ef39-493f-a547-8408092c22a7", "e10b1381-5f0a-47ff-8c7b-37bd13d7c974")
  | project stableId=name, subscriptionId, resourceGroup, properties, recommendationId=id
  | join kind=leftouter(
      advisorresources
      | where tolower(type) == 'microsoft.advisor/suppressions'
      | extend tokens = split(id, '/')
      | extend stableId = iff(array_length(tokens) > 3, tokens[(array_length(tokens)-3)], '')
      | extend expirationTimeStamp = todatetime(iff(strcmp(tostring(properties.ttl), '-1') == 0, '9999-12-31', properties.expirationTimeStamp))
      | where expirationTimeStamp > now()
      | project suppressionId = tostring(properties.suppressionId), stableId, expirationTimeStamp
  ) on stableId
  | join kind = leftouter (
      advisorresources
      | where tolower(type) == 'microsoft.advisor/configurations'
      | where isempty(resourceGroup) == true
      | project subscriptionId, excludeRecomm = properties.exclude, lowCpuThreshold = properties.lowCpuThreshold
  ) on subscriptionId
  | extend isActive = iff(isempty(excludeRecomm), true, tobool(excludeRecomm) == false)
  | extend isNotExcludedViaCpuThreshold = iff((isnotempty(lowCpuThreshold) and isnotnull(properties.extendedProperties) and isnotempty(properties.extendedProperties.MaxCpuP95)),
      todouble(properties.extendedProperties.MaxCpuP95) < todouble(lowCpuThreshold),
      iff((isnull(properties.extendedProperties) or isempty(properties.extendedProperties.MaxCpuP95) or todouble(properties.extendedProperties.MaxCpuP95) < 100),
          true,
          false))
  | where isActive == true and isNotExcludedViaCpuThreshold == true
  | join kind = leftouter (
      advisorresources
      | where type =~ 'microsoft.advisor/configurations'
      | where isnotempty(resourceGroup) == true
      | project subscriptionId, resourceGroup, excludeProperty = properties.exclude
  ) on subscriptionId, resourceGroup
  | extend shouldBeIncluded = iff(isempty(excludeProperty), true, tobool(excludeProperty) == false)
  | where shouldBeIncluded == true
  | summarize expirationTimeStamp = max(expirationTimeStamp), suppressionIds = make_list(suppressionId) by recommendationId, stableId, subscriptionId, resourceGroup, tostring(properties)
  | extend isRecommendationActive = (isnull(expirationTimeStamp) or isempty(expirationTimeStamp))
  | extend properties = parse_json(properties)
  | extend monthlyCostSavings = toreal(properties.extendedProperties.savingsAmount)
  | extend monthlyCarbonSavingsKg = toreal(properties.extendedProperties.PotentialMonthlyCarbonSavings)
  | where monthlyCarbonSavingsKg > 0
  | extend resourceId = properties.resourceMetadata.resourceId, resourceName = tostring(properties.extendedProperties.roleName), recommendationMessage = properties.extendedProperties.recommendationMessage, recommendationType=tostring(properties.extendedProperties.recommendationType)
  | project recommendationId, subscriptionId, resourceGroup, suppressionIds, isRecommendationActive, monthlyCostSavings, monthlyCarbonSavingsKg, resourceId, resourceName, recommendationMessage, recommendationType| where isRecommendationActive == true| order by monthlyCarbonSavingsKg desc

Passaggi successivi