Metriche in Application Insights

Application Insights supporta tre diversi tipi di metriche: standard (preaggregati), basati su log e metriche personalizzate. Ciascun tipo offre un valore univoco per il monitoraggio dell'integrità, della diagnostica e dell'analisi dell'applicazione. Gli sviluppatori che instrumentano le applicazioni possono decidere quale tipo di metrica è più adatto a uno scenario specifico. Le decisioni sono basate sulle dimensioni dell'applicazione, sul volume previsto di dati di telemetria e sui requisiti aziendali per la precisione e gli avvisi delle metriche. Questo articolo illustra la differenza tra tutti i tipi di metriche supportati.

Metriche standard

Application Insights raccoglie e monitora automaticamente le metriche standard. Queste metriche predefinite coprono un'ampia gamma di indicatori di prestazioni e utilizzo, ad esempio l'utilizzo della CPU, il consumo di memoria, le tariffe delle richieste e i tempi di risposta. Non è necessario configurare nulla per iniziare a usarli. Durante la raccolta, il servizio preaggrega le metriche standard e le archivia come serie temporali in un repository specializzato con solo dimensioni chiave. Questa progettazione migliora le prestazioni delle query. A causa della velocità e della struttura, le metriche standard funzionano meglio per avvisi quasi in tempo reale e dashboard reattivi.

Metriche basate su log

Le metriche basate su log in Application Insights sono un concetto relativo al momento dell'esecuzione delle query. Il sistema li rappresenta come serie temporali compilate dai dati di log dell'applicazione. Non preaggrega i log sottostanti durante la raccolta o l'archiviazione. Mantiene invece tutte le proprietà di ogni voce di log.

Questa conservazione consente di usare le proprietà del log come dimensioni durante l'esecuzione di query sulle metriche basate su log. È possibile applicare il filtro del grafico delle metriche e la suddivisione delle metriche, che offre queste metriche un valore analitico e diagnostico sicuro.

Tuttavia, le tecniche di riduzione del volume di telemetria influiscono sulle metriche basate su log. Tecniche come il campionamento e il filtraggio telemetrico, spesso usate per ridurre i dati da applicazioni con volumi elevati, riducono il numero di voci di log raccolte. Questa riduzione riduce l'accuratezza delle metriche basate su log.

Metriche personalizzate (anteprima)

Le metriche personalizzate in Application Insights consentono di definire e tenere traccia di misurazioni specifiche univoche per l'applicazione. Queste metriche possono essere create instrumentando il codice per inviare dati di telemetria personalizzati ad Application Insights. Le metriche personalizzate offrono la flessibilità necessaria per monitorare qualsiasi aspetto dell'applicazione non coperta dalle metriche standard, consentendo di ottenere informazioni più approfondite sul comportamento e sulle prestazioni dell'applicazione.

Per altre informazioni, vedere Metriche personalizzate in Monitoraggio di Azure (anteprima).

Nota

Application Insights offre anche una funzionalità denominata Stream Live Metrics, che consente il monitoraggio quasi in tempo reale delle applicazioni Web e non archivia dati di telemetria.

Confronto tra metriche

Funzionalità	Metriche standard	Metriche basate su log	Metriche personalizzate
Origine dati	Dati di serie temporali preaggregati raccolti durante il runtime.	Derivato dai dati di log usando delle query Kusto.	Metriche definite dall'utente raccolte tramite Application Insights SDK o API.
Granularità	Intervalli fissi (1 minuto).	Dipende dalla granularità dei dati di log stessi.	Granularità flessibile basata sulle metriche definite dall'utente.
Precisione	Elevato, non interessato dal campionamento dei log.	Può essere influenzato dal campionamento e dal filtro.	Accuratezza elevata, soprattutto quando si usano metodi preaggregati come GetMetric.
Costi	Incluso nei prezzi di Application Insights.	In base ai costi di inserimento e query dei dati dei log.	Vedere Modello di prezzi e conservazione.
Configurazione	Disponibile automaticamente con configurazione minima.	Richiedere la configurazione delle query di log per estrarre le metriche desiderate dai dati di log.	Richiede implementazione e configurazione personalizzate nel codice.
Prestazioni delle query	Veloce, a causa della preaggregazione.	Più lento, perché comporta l'esecuzione di query sui dati di log.	Dipende dal volume di dati e dalla complessità delle query.
Archiviazione	Archiviato come dati di serie temporali nell'archivio metriche di Azure Monitor.	Archiviato come log nell'area di lavoro Log Analytics.	Archiviato sia in Log Analytics che nell'archivio delle metriche di Monitoraggio di Azure.
Invio di avvisi	Supporta gli avvisi in tempo reale.	Consente scenari di avviso complessi basati su dati di log dettagliati.	Avvisi flessibili basati sulle metriche definite dall'utente.
Limite del servizio	Soggetto ai limiti di Application Insights.	Soggetto ai limiti dell'area di lavoro Log Analytics.	Limitato dalla quota per le metriche gratuite e dal costo per le dimensioni aggiuntive.
Casi d'uso	Monitoraggio in tempo reale, dashboard delle prestazioni e informazioni rapide.	Diagnostica dettagliata, risoluzione dei problemi e analisi approfondita.	Indicatori di prestazioni personalizzati e metriche specifiche dell'azienda.
Esempi	Utilizzo della CPU, utilizzo della memoria, durata della richiesta.	Conteggi delle richieste, tracce di eccezioni, chiamate di dipendenza.	Metriche personalizzate specifiche dell'applicazione, ad esempio l'engagement degli utenti, gli utilizzi delle funzionalità.

Preaggregazione delle metriche

Gli SDK OpenTelemetry e alcuni SDK di Application Insights (API classica) preaggregano le metriche durante la raccolta per ridurre il volume di dati inviati dall'SDK all'endpoint del canale di telemetria. Questo processo si applica alle metriche standard inviate per impostazione predefinita, quindi l'accuratezza non è influenzata dal campionamento o dal filtro. Si applica anche alle metriche personalizzate inviate usando l'API OpenTelemetry o GetMetric e TrackValue, che comporta un minor inserimento dei dati e un costo inferiore. Se la versione di Application Insights SDK supporta GetMetric e TrackValue, è il metodo preferito per l'invio di metriche personalizzate.

Alcuni SDK non implementano la preaggregazione. Gli esempi includono versioni precedenti di Application Insights SDK e strumentazione basata su browser. In questi casi, il back-end crea le nuove metriche aggregando gli eventi ricevuti tramite il canale di telemetria.

Per inviare metriche personalizzate, usare il metodo trackMetric .

Questi SDK non riducono il volume di dati inviati. Tuttavia, è comunque possibile usare le metriche preaggregate che producono. Questa configurazione offre prestazioni migliori e supporta avvisi quasi in tempo reale, anche senza preaggregazione durante la raccolta.

L'endpoint del canale di telemetria preaggrega gli eventi prima del campionamento per inserimento. Per questo motivo, il campionamento per inserimento non influisce mai sull'accuratezza delle metriche preaggregate, indipendentemente dalla versione dell'SDK usata con l'applicazione.

Le seguenti tabelle elencano dove vengono effettuate le preaggregazioni.

Preaggregazione delle metriche con la distribuzione OpenTelemetry di Monitoraggio di Azure

SDK di produzione corrente	Preaggregazione delle metriche standard	Preaggregazione delle metriche personalizzate
ASP.NET Core	SDK	SDK tramite l'API OpenTelemetry
.NET (tramite l'utilità di esportazione)	SDK	SDK tramite l'API OpenTelemetry
Java (3.x)	SDK	SDK tramite l'API OpenTelemetry
Nativo Java	SDK	SDK tramite l'API OpenTelemetry
Node.js	SDK	SDK tramite l'API OpenTelemetry
Pitone	SDK	SDK tramite l'API OpenTelemetry

Preaggregazione delle metriche con Application Insights SDK (API classica)

SDK di produzione corrente	Preaggregazione delle metriche standard	Preaggregazione delle metriche personalizzate
.NET Core e .NET Framework	SDK (V2.13.1+)	SDK (V2.7.2+) tramite GetMetric Endpoint del canale di telemetria tramite TrackMetric
Java (2.x)	Endpoint del canale di telemetria	Endpoint del canale di telemetria tramite TrackMetric
JavaScript (browser)	Endpoint del canale di telemetria	Endpoint del canale di telemetria tramite TrackMetric
Node.js	Endpoint del canale di telemetria	Endpoint del canale di telemetria tramite TrackMetric

Attenzione

Application Insights Java 2.x SDK non è più consigliato. Invece, utilizza l'offerta Java basata su OpenTelemetry.
OpenCensus Python SDK viene ritirato. È consigliabile l'offerta Python basata su OpenTelemetry e fornire indicazioni sulla migrazione.

Preaggregazione delle metriche con strumentazione automatica

Con l'autostrumentazione, l'SDK viene aggiunto automaticamente al codice dell'applicazione e non può essere personalizzato. Per le metriche personalizzate, è necessaria la strumentazione manuale.

SDK di produzione corrente	Preaggregazione delle metriche standard	Preaggregazione delle metriche personalizzate
ASP.NET Core	SDK ¹	Non supportato
ASP.NET	SDK ²	Non supportato
Giava	SDK	Supportato ³
Node.js	SDK	Non supportato
Pitone	SDK	Non supportato

Note a piè di pagina

¹La strumentazione automatica di ASP.NET Core in Servizio app di Azure genera metriche standard senza dimensioni. La strumentazione manuale è necessaria per tutte le dimensioni.
²La strumentazione automatica di ASP.NET in macchine virtuali/set di scalabilità di macchine virtuali e locale genera metriche standard senza dimensioni. Lo stesso vale per Servizio app di Azure, ma il livello di raccolta deve essere impostato su consigliato. La strumentazione manuale è necessaria per tutte le dimensioni.
³ L'agente Java usato con la strumentazione automatica acquisisce le metriche generate dalle librerie più diffuse e le invia ad Application Insights come metriche personalizzate.

Dimensioni delle metriche personalizzate e preaggregazione

Tutte le metriche inviate tramite OpenTelemetry, trackMetric o GetMetric e TrackValue chiamate API vengono archiviate automaticamente nell'archivio delle metriche e nei log. Queste metriche sono disponibili nella tabella customMetrics in Application Insights e in Esplora metriche nello spazio dei nomi delle metriche personalizzato denominato azure.applicationinsights. Sebbene la versione basata su log della metrica personalizzata conservi sempre tutte le dimensioni, la versione preaggregata della metrica viene archiviata senza dimensioni per impostazione predefinita. La conservazione delle dimensioni delle metriche personalizzate è una funzionalità di anteprima che può essere attivata dalla scheda Utilizzo e costi stimati selezionando Con dimensioni in Inviare metriche personalizzate all'archivio metriche di Azure.

Quote

Le metriche preaggregate vengono archiviate come serie temporali in Monitoraggio di Azure. Si applicano le quote di Monitoraggio di Azure per le metriche personalizzate.

Nota

Il superamento della quota potrebbe avere conseguenze impreviste. Monitor di Azure potrebbe diventare inaffidabile nella tua sottoscrizione o nella tua area. Per informazioni su come evitare di superare la quota, vedere Limitazioni e considerazioni sulla progettazione.

Perché la raccolta di dimensioni di metriche personalizzate è disattivata per impostazione predefinita?

Per impostazione predefinita, Application Insights disattiva la raccolta delle dimensioni delle metriche personalizzate. L'archiviazione di metriche personalizzate con dimensioni comporta una fatturazione separata da Application Insights. L'archiviazione di metriche personalizzate nondimensionali rimane gratuita, fino a una quota. Per informazioni dettagliate, vedere la pagina dei prezzi di Monitoraggio di Azure.

Creare grafici ed esplorare le metriche

Usare Esplora metriche di Azure Monitor per generare grafici da metriche preaggregate, basate su log e personalizzate, e per creare dashboard con grafici. Dopo aver selezionato la risorsa di Application Insights desiderata, utilizza il selettore dello spazio dei nomi per passare da una metrica all'altra.

Modelli di prezzi per le metriche di Application Insights

L'inserimento di metriche in Application Insights, basate su log o preaggregate, genera costi in base alle dimensioni dei dati inseriti. Per altre informazioni, vedere Dettagli sui prezzi dei log di Monitoraggio di Azure. Le metriche personalizzate, incluse tutte le dimensioni, vengono sempre archiviate nell'archivio log di Application Insights. Inoltre, per impostazione predefinita, una versione preaggregata delle metriche personalizzate senza dimensioni viene inviata all'archivio delle metriche.

Se si seleziona l'opzione Abilita avvisi sulle dimensioni delle metriche personalizzate per archiviare tutte le dimensioni delle metriche preaggregate nell'archivio metriche, è possibile aumentare gli addebiti in base ai prezzi delle metriche personalizzate.

Le sezioni seguenti elencano le metriche con aggregazioni e dimensioni supportate. I dettagli sulle metriche basate su log includono le istruzioni di query Kusto sottostanti.

Importante

Limite serie temporali: Ogni metrica può avere un massimo di 5.000 serie temporali entro 24 ore. Una volta raggiunto questo limite, tutti i valori delle dimensioni del punto metrico vengono sostituiti con la costante Maximum values reached.
Limite di cardinalità: Ogni dimensione supporta un numero limitato di valori univoci entro un periodo di sette giorni. Quando viene raggiunto il limite, Monitoraggio di Azure sostituisce tutti i nuovi valori con la costante Other values. Le tabelle seguenti elencano il limite di cardinalità per ogni dimensione.

Le sezioni seguenti elencano le metriche con aggregazioni e dimensioni supportate. I dettagli sulle metriche basate su log includono le istruzioni di query Kusto sottostanti. Per praticità, ogni query usa le impostazioni predefinite per la granularità temporale, il tipo di grafico e talvolta la divisione della dimensione, semplificando l'uso della query in Log Analytics senza alcuna necessità di modifica.

Quando si traccia la stessa metrica in Esplora metriche, non esistono impostazioni predefinite: la query viene modificata dinamicamente in base alle impostazioni del grafico:

L'intervallo di tempo selezionato viene convertito in una where timestamp... clausola per selezionare solo gli eventi dall'intervallo di tempo selezionato. Ad esempio, un grafico che mostra i dati delle ultime ventiquattro ore include la query | where timestamp > ago(24 h).
La granularità temporale selezionata
Le dimensioni del filtro selezionate vengono convertite in where clausole.
La dimensione split chart selezionata viene convertita in una summarize proprietà . Ad esempio, se si divide il grafico per locatione si traccia usando una granularità temporale di 5 minuti, la summarize clausola viene riepilogata ... by bin(timestamp, 5 m), location.

Nota

Se non si ha familiarità con il linguaggio di query Kusto, iniziare copiando e incollando le istruzioni Kusto nel riquadro query di Log Analytics senza apportare alcuna modifica. Selezionare Esegui per visualizzare il grafico di base. Quando si inizia a comprendere la sintassi del linguaggio di query, è possibile iniziare a apportare piccole modifiche e visualizzare l'impatto della modifica. L'esplorazione dei propri dati è un ottimo modo per iniziare a sfruttare al meglio Log Analytics e Monitoraggio di Azure.

Importante

Per le metriche basate su log seguenti, se sono supportate più aggregazioni, l'aggregazione in corsivo viene usata nell'esempio di query Kusto.

Metriche di disponibilità

Le metriche nella categoria Disponibilità consentono di visualizzare lo stato dell'applicazione Web come osservato da punti diversi nel mondo. Configurare i test di disponibilità per iniziare a usare qualsiasi metrica di questa categoria.

Standard
Basato su log

Disponibilità (availabilityResults/availabilityPercentage)

La metrica Disponibilità mostra la percentuale delle esecuzioni di test Web che non hanno rilevato problemi. Il valore più basso possibile è 0, che indica che tutte le esecuzioni di test Web non sono riuscite. Il valore 100 indica che tutte le esecuzioni di test Web hanno superato i criteri di convalida.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Percentuale	Avg	`Run location`	`availabilityResult/location`	50
Percentuale	Avg	`Test name`	`availabilityResult/name`	100

Durata del test di disponibilità (availabilityResults/duration)

La metrica Availability test duration mostra il tempo necessario per l'esecuzione del test web. Per i test Web in più passaggi, la metrica riflette il tempo di esecuzione totale di tutti i passaggi.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Millisecondi	Avg, Max, Min	`Run location`	`availabilityResult/location`	50
		`Test name`	`availabilityResult/name`	100
		`Test result`	`availabilityResult/success`	2

Test di disponibilità (availabilityResults/count)

La metrica Test di disponibilità riflette il numero di test Web eseguiti da Azure Monitor.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Run location`	`availabilityResult/location`	50
		`Test name`	`availabilityResult/name`	100
		`Test result`	`availabilityResult/success`	2

Disponibilità (availabilityResults/availabilityPercentage)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Percentuale	Avg	Tutti i campi di telemetria

availabilityResults
| summarize ['availabilityResults/availabilityPercentage_avg'] = sum(todouble(success == 1) * 100) / count() by bin(timestamp, 15m)
| render timechart

Conteggio dei risultati dei test di disponibilità (availabilityResults/count)

La metrica Test di disponibilità riflette il numero di test Web eseguiti da Azure Monitor.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

availabilityResults
| summarize ['availabilityResults/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Durata del test (availabilityResults/duration)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

availabilityResults
| where notempty(duration)
| extend availabilityResult_duration = iif(itemType == 'availabilityResult', duration, todouble(''))
| summarize ['availabilityResults/duration_avg'] = sum(availabilityResult_duration) / sum(itemCount) by bin(timestamp, 5m)
| render timechart

Metriche del browser

Application Insights JavaScript SDK raccoglie le metriche del browser dai browser degli utenti finali reali. Queste metriche offrono informazioni utili sull'esperienza degli utenti con l'app Web. L'SDK in genere non esegue metriche del browser di esempio, quindi offrono una maggiore precisione nei numeri di utilizzo. Al contrario, le metriche lato server spesso usano il campionamento, che può distorcere i risultati.

Nota

Per raccogliere le metriche del browser, l'applicazione deve essere instrumentata con Application Insights JavaScript SDK.

Standard
Basato su log

Tempo di caricamento della pagina del browser (browserTimings/totalDuration)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Max, Min	Nessuno

Tempo di elaborazione client (browserTiming/processingDuration)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Max, Min	Nessuno

Tempo di connessione alla rete durante il caricamento della pagina (browserTimings/networkDuration)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Max, Min	Nessuno

Tempo di ricezione della risposta (browserTimings/receiveDuration)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Max, Min	Nessuno

Tempo di invio della richiesta (browserTimings/sendDuration)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Max, Min	Nessuno

Tempo di caricamento della pagina del browser (browserTimings/totalDuration)

Tempo dalla richiesta dell'utente fino al caricamento di DOM, fogli di stile, script e immagini.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

browserTimings
| where notempty(totalDuration)
| extend _sum = totalDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/totalDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Tempo di elaborazione client (browserTiming/processingDuration)

Tempo compreso tra la ricezione dell'ultimo byte di un documento e il caricamento del DOM. Le richieste asincrone potrebbero ancora essere in fase di elaborazione.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

browserTimings
| where notempty(processingDuration)
| extend _sum = processingDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/processingDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Tempo di connessione alla rete durante il caricamento della pagina (browserTimings/networkDuration)

Tempo tra la richiesta utente e la connessione di rete. Include la ricerca del DNS (Domain Name System) e la connessione di trasporto.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

browserTimings
| where notempty(networkDuration)
| extend _sum = networkDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/networkDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Tempo di ricezione della risposta (browserTimings/receiveDuration)

Tempo compreso tra il primo e l'ultimo byte o fino alla disconnessione.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

browserTimings
| where notempty(receiveDuration)
| extend _sum = receiveDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/receiveDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Tempo di invio della richiesta (browserTimings/sendDuration)

Tempo compreso tra la connessione di rete e la ricezione del primo byte.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

browserTimings
| where notempty(sendDuration)
| extend _sum = sendDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/sendDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Metriche di errore

Le metriche in Errori mostrano problemi con l'elaborazione di richieste, chiamate di dipendenza e eccezioni generate.

Standard
Basato su log

Eccezioni del browser (exceptions/browser)

Questa metrica riflette il numero di eccezioni generate dal codice dell'applicazione in esecuzione nel browser. Nella metrica sono incluse solo le eccezioni rilevate con una trackException() chiamata API di Application Insights.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role name`	`cloud/roleName`	100

Errori di chiamata di dipendenza (dependencies/failed)

Numero di chiamate di dipendenza non riuscite.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Dependency performance`	`dependency/performanceBucket`	20
		`Dependency type`	`dependency/type`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Result code`	`dependency/resultCode`	100
		`Target of dependency call`	`dependency/target`	100

Eccezioni (eccezioni/numero)

Ogni volta che si registra un'eccezione ad Application Insights, viene eseguita una chiamata al metodo trackException() dell'SDK. La metrica Eccezioni mostra il numero di eccezioni registrate.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Device type`	`client/type`	2

Richieste non riuscite (requests/failed)

Numero di richieste server rilevate contrassegnate come non riuscite. Per impostazione predefinita, Application Insights SDK contrassegna automaticamente ogni richiesta del server che ha restituito il codice di risposta HTTP 5xx o 4xx (ad eccezione di 401) come richiesta non riuscita. È possibile personalizzare questa logica modificando la proprietà success dell'elemento di telemetria della richiesta in un inizializzatore di telemetria personalizzato. Per altre informazioni sui vari codici di risposta, vedere Modello di dati di telemetria di Application Insights.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Is synthetic traffic`	`operation/synthetic`	10
		`Request performance`	`request/performanceBucket`	20
		`Result code`	`request/resultCode`	100

Eccezioni del server (eccezioni/server)

Questa metrica mostra il numero di eccezioni del server.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
Conteggio	Conteggio	`Cloud role name`	`cloud/roleName`	100

Eccezioni del browser (exceptions/browser)

Nota

Quando si esegue il campionamento, itemCount indica quanti elementi di telemetria rappresenta un singolo record di log. Ad esempio, con il campionamento del 25%, ogni record di log mantenuto rappresenta quattro elementi (1 mantenuto + 3 campionati). Le query basate su log sommano tutti i valori itemCount per garantire che la metrica rifletta il numero totale di eventi effettivi, non solo il numero di record di log archiviati.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

exceptions
| where client_Type == 'Browser'
| summarize ['exceptions/browser_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Errori di chiamata di dipendenza (dependencies/failed)

Numero di chiamate di dipendenza non riuscite.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

dependencies
| where success == 'False'
| summarize ['dependencies/failed_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Eccezioni (eccezioni/numero)

Ogni volta che si registra un'eccezione ad Application Insights, viene eseguita una chiamata al metodo trackException() dell'SDK. La metrica Eccezioni mostra il numero di eccezioni registrate.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

exceptions
| summarize ['exceptions/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Richieste non riuscite (requests/failed)

Numero di richieste server rilevate contrassegnate come non riuscite. Per impostazione predefinita, Application Insights SDK contrassegna automaticamente ogni richiesta del server che ha restituito il codice di risposta HTTP 5xx o 4xx come richiesta non riuscita. È possibile personalizzare questa logica modificando la proprietà success dell'elemento di telemetria della richiesta in un inizializzatore di telemetria personalizzato.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

requests
| where success == 'False'
| summarize ['requests/failed_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Eccezioni del server (eccezioni/server)

Questa metrica mostra il numero di eccezioni del server.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

exceptions
| where client_Type != 'Browser'
| summarize ['exceptions/server_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Contatori delle prestazioni

Application Insights usa metriche di sistema e processi, denominati contatori delle prestazioni, per diagnosticare i problemi di prestazioni e supportare esperienze predefinite.

La distribuzione OpenTelemetry di Azure Monitor esporta questi contatori come metriche personalizzate nella performanceCounters tabella, ognuna identificata da un nome di metrica univoco.

Nomi e descrizioni dei contatori

Counter	Nome	Description	Misura
Memoria disponibile	`Available Bytes`	Memoria fisica disponibile per i processi in esecuzione.	Bytes
Frequenza delle eccezioni	`# of Exceps Thrown / sec`	Eccezioni generate dall'applicazione per secondo.	Eccezioni al secondo
Tempo di esecuzione della richiesta	`Request Execution Time`	Tempo medio per completare una richiesta.	Millisecondi
Tasso di Richiesta	`Requests/Sec`	Le richieste elaborate ogni secondo.	Richieste al secondo
Richieste in coda	`Requests In Application Queue`	Richieste attualmente in attesa nella coda delle richieste.	Conteggio
% CPU del processo	`% Processor Time`	Utilizzo della CPU del processo dell'applicazione.	Percent
% CPU del processo normalizzata	`% Processor Time Normalized`	Utilizzo cpu processo diviso per numero di processori logici.	Percent
Velocità di I/O del processo	`IO Data Bytes/sec`	Velocità effettiva di I/O per il processo dell'applicazione.	Byte al secondo
Byte privati del processo	`Private Bytes`	Memoria privata usata dal processo dell'applicazione.	Bytes
Tempo di utilizzo del processore % Categoria: Processore	`% Processor Time`	Utilizzo totale della CPU del computer.	Percent
Tempo di utilizzo del processore % Categoria: Processo	`% Processor Time`	Utilizzo della CPU del processo.	Percent

Esperienze migliorate dai contatori delle prestazioni

Visualizzazione prestazioni: memoria disponibile, CPU processo %, velocità di I/O processo.
Visualizzazione errori: memoria disponibile, CPU processo %, velocità di I/O processo.
Rilevamento intelligente e avvisi intelligenti: byte privati processo.
Grafici conteggi delle richieste: i grafici visualizzano i conteggi dalla requests tabella.

Elencare i tipi di contatore delle prestazioni

Per un elenco completo dei contatori delle prestazioni disponibili, che variano a seconda del runtime e della configurazione specifici del linguaggio:

Aprire la risorsa di Application Insights nel portale di Azure.
In Monitoraggio, selezionare Log.
Dal menu Seleziona una tabella, scegliere performanceCounters e quindi Esegui.

In alternativa, eseguire la query seguente.

// List distinct performance counter names with category and counter.
performanceCounters
| where timestamp > ago(1d)
| summarize by name, category, counter
| order by name asc, category asc

Metriche del server

Standard
Basato su log

Chiamate di dipendenza (dependencies/count)

Questa metrica è in relazione al numero di chiamate di dipendenza.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Dependency performance`	`dependency/performanceBucket`	20
		`Dependency type`	`dependency/type`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Result code`	`request/resultCode`	2
		`Successful call`	`dependency/success`	100
		`Target of a dependency call`	`dependency/target`	100

Durata delle dipendenze (dipendenze/durata)

Questa metrica si riferisce alla durata delle chiamate alle dipendenze.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Millisecondi	Avg, Max, Min	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Dependency performance`	`dependency/performanceBucket`	20
		`Dependency type`	`dependency/type`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Result code`	`request/resultCode`	100
		`Successful call`	`dependency/success`	2
		`Target of a dependency call`	`dependency/target`	100

Frequenza richieste server (richieste/frequenza)

Questa metrica mostra il numero di richieste server in ingresso ricevute dall'applicazione Web.

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio al secondo	Avg	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Request performance`	`request/performanceBucket`	20
		`Result code`	`request/resultCode`	100
		`Successful call`	`dependency/success`	2

Richieste server (requests/count)

Unità di misura	Aggregazioni	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Request performance`	`request/performanceBucket`	20
		`Result code`	`request/resultCode`	100
		`Successful call`	`dependency/success`	2

Tempo di risposta del server (richieste/durata)

Questa metrica riflette il tempo necessario per i server per elaborare le richieste in ingresso.

Millisecondi	Avg, Max, Min	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Request performance`	`request/performanceBucket`	20
		`Result code`	`request/resultCode`	100
		`Successful call`	`dependency/success`	2

Chiamate di dipendenza (dependencies/count)

Questa metrica è in relazione al numero di chiamate di dipendenza.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

dependencies
| summarize ['dependencies/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Durata delle dipendenze (dipendenze/durata)

Questa metrica si riferisce alla durata delle chiamate alle dipendenze.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

dependencies
| where notempty(duration)
| extend dependency_duration = iif(itemType == 'dependency', duration, todouble(''))
| extend _sum = dependency_duration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['dependencies/duration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Richieste server (requests/count)

Questa metrica mostra il numero di richieste server in ingresso ricevute dall'applicazione Web.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

requests
| summarize ['requests/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Tempo di risposta del server (richieste/durata)

Questa metrica riflette il tempo necessario per i server per elaborare le richieste in ingresso.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

requests
| where notempty(duration)
| extend request_duration = iif(itemType == 'request', duration, todouble(''))
| extend _sum = request_duration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['requests/duration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

Metriche di utilizzo

Standard
Basato su log

Tempo di caricamento della pagina visualizzata (pageViews/duration)

Questa metrica si riferisce alla quantità di tempo impiegato per il caricamento degli eventi PageView.

Millisecondi	Avg, Max, Min	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Millisecondi	Avg, Max, Min	`Cloud role name`	`cloud/roleName`	100
Millisecondi	Avg, Max, Min	`Is traffic synthetic`	`operation/synthetic`	10

Visualizzazioni pagina (pageViews/count)

Numero di eventi PageView registrati con l'API Application Insights TrackPageView().

Conteggio	Conteggio	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Millisecondi	Avg, Max, Min	`Cloud role name`	`cloud/roleName`	100
Millisecondi	Avg, Max, Min	`Is traffic synthetic`	`operation/synthetic`	10

Tracce (traces/count)

Conteggio delle istruzioni di traccia registrate con la chiamata API di Application Insights TrackTrace().

Conteggio	Conteggio	Nome della dimensione (Esplora metriche)	Nome della dimensione (Analisi dei Log)	Limite di cardinalità
Conteggio	Conteggio	`Cloud role instance`	`cloud/roleInstance`	100
		`Cloud role name`	`cloud/roleName`	100
		`Is traffic synthetic`	`operation/synthetic`	10
		`Severity level`	`trace/severityLevel`	100

Eventi (customEvents/count)

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

customEvents
| summarize ['customEvents/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Tempo di caricamento della pagina visualizzata (pageViews/duration)

Questa metrica si riferisce alla quantità di tempo impiegato per il caricamento degli eventi PageView.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Millisecondi	Avg, Min, Max	Tutti i campi di telemetria

pageViews
| where notempty(duration)
| extend pageView_duration = iif(itemType == 'pageView', duration, todouble(''))
| extend _sum = pageView_duration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['pageViews/duration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render barchart

Visualizzazioni pagina (pageViews/count)

Numero di eventi PageView registrati con l'API Application Insights TrackPageView().

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

pageViews
| summarize ['pageViews/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Sessioni (sessions/count)

Questa metrica si riferisce al numero di identificatori di sessione distinti (ID).

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Unico	Tutti i campi di telemetria

union traces, requests, pageViews, dependencies, customEvents, availabilityResults, exceptions, customMetrics, browserTimings
| where notempty(session_Id)
| summarize ['sessions/count_unique'] = dcount(session_Id) by bin(timestamp, 15m)
| render barchart

Tracce (traces/count)

Conteggio delle istruzioni di traccia registrate con la chiamata API di Application Insights TrackTrace().

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Somma	Tutti i campi di telemetria

traces
| summarize ['traces/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

Utenti (users/count)

Numero di utenti distinti che hanno eseguito l'accesso all'applicazione. L'accuratezza di questa metrica può essere influenzata usando il campionamento e il filtro dei dati di telemetria.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Unico	Tutti i campi di telemetria

union traces, requests, pageViews, dependencies, customEvents, availabilityResults, exceptions, customMetrics, browserTimings
| where notempty(user_Id)
| summarize ['users/count_unique'] = dcount(user_Id) by bin(timestamp, 15m)
| render barchart

Utenti, autenticati (users/authenticated)

Numero di utenti distinti che hanno eseguito l'autenticazione nell'applicazione.

Unità di misura	Aggregazioni supportate	Dimensioni supportate
Conteggio	Unico	Tutti i campi di telemetria

union traces, requests, pageViews, dependencies, customEvents, availabilityResults, exceptions, customMetrics, browserTimings
| where notempty(user_AuthenticatedId)
| summarize ['users/authenticated_unique'] = dcount(user_AuthenticatedId) by bin(timestamp, 15m)
| render barchart

Metriche personalizzate

Standard
Basato su log

Non applicabile alle metriche standard.

Le metriche personalizzate vengono archiviate sia nell'archivio delle metriche che nei log, consentendo di recuperarle usando query Kusto.

Ad esempio, se si instrumenta l'applicazione con _telemetryClient.GetMetric("Sales Amount").TrackValue(saleAmount); getMetrice TrackValue per tenere traccia della metrica personalizzata Sales Amount, è possibile usare le query Kusto seguenti per ogni aggregazione disponibile.

Media (avg)

customMetrics
| where name == "Sales Amount"
| extend
    customMetric_valueSum = iif(itemType == 'customMetric', valueSum, todouble('')),
    customMetric_valueCount = iif(itemType == 'customMetric', valueCount, toint(''))
| summarize ['customMetrics/Sales Amount_avg'] = sum(customMetric_valueSum) / sum(customMetric_valueCount) by bin(timestamp, 15m)
| order by timestamp desc
| render timechart

Minimo (min)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueMin = iif(itemType == 'customMetric', valueMin, todouble(''))
| summarize ['customMetrics/Sales Amount_min'] = min(customMetric_valueMin) by bin(timestamp, 15m)
| render timechart

Massimo (max)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueMax = iif(itemType == 'customMetric', valueMax, todouble(''))
| summarize ['customMetrics/Sales Amount_max'] = max(customMetric_valueMax) by bin(timestamp, 15m)
| render timechart

Somma (sum)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueSum = iif(itemType == 'customMetric', valueSum, todouble(''))
| summarize ['customMetrics/Sales Amount_sum'] = sum(customMetric_valueSum) by bin(timestamp, 15m)
| render barchart

Conteggio (numero)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueCount = iif(itemType == 'customMetric', valueCount, toint(''))
| summarize ['customMetrics/Sales Amount_count'] = sum(customMetric_valueCount) by bin(timestamp, 15m)
| render barchart

Univoco (univoco)

customMetrics
| where name == "Sales Amount"
| extend customMetric_value = iif(itemType == 'customMetric', value, todouble(''))
| summarize ['customMetrics/Sales Amount_unique'] = dcount(customMetric_value) by bin(timestamp, 15m)
| render barchart

Accedere direttamente alle metriche basate su log con l'API REST di Application Insights

L'API REST di Application Insights consente il recupero a livello di codice delle metriche basate su log. Include anche un parametro ai.include-query-payload facoltativo che, quando aggiunto a una stringa di query, richiede all'API di restituire non solo i dati delle serie temporali, ma anche l'istruzione Linguaggio di query Kusto (KQL) usata per recuperarla. Questo parametro può essere utile per gli utenti che vogliono comprendere la connessione tra eventi non elaborati in Log Analytics e la metrica basata su log risultante.

Per accedere direttamente ai dati, passare il parametro ai.include-query-payload all'API di Application Insights in una query usando KQL.

Nota

Per recuperare la query dei log sottostanti, non è necessario sostituire DEMO_APP e DEMO_KEY. Se si vuole solo recuperare l'istruzione KQL e non i dati delle serie temporali della propria applicazione, è possibile copiarlo e incollarlo direttamente nella barra di ricerca del browser.

api.applicationinsights.io/v1/apps/DEMO_APP/metrics/users/authenticated?api_key=DEMO_KEY&prefer=ai.include-query-payload

Questo esempio mostra un'istruzione KQL restituita per la metrica Authenticated Users. In questo esempio è "users/authenticated" l'ID metrica.

output
{
    "value": {
        "start": "2024-06-21T09:14:25.450Z",
        "end": "2024-06-21T21:14:25.450Z",
        "users/authenticated": {
            "unique": 0
        }
    },
    "@ai.query": "union (traces | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (requests | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (pageViews | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (dependencies | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (customEvents | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (availabilityResults | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (exceptions | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (customMetrics | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)), (browserTimings | where timestamp >= datetime(2024-06-21T09:14:25.450Z) and timestamp < datetime(2024-06-21T21:14:25.450Z)) | where notempty(user_AuthenticatedId) | summarize ['users/authenticated_unique'] = dcount(user_AuthenticatedId)"
}

Passaggi successivi

Commenti e suggerimenti

Questa pagina è stata utile?

Last updated on 2025-11-07

Condividi tramite

Metriche in Application Insights

Metriche standard

Metriche basate su log

Metriche personalizzate (anteprima)

Confronto tra metriche

Preaggregazione delle metriche

Preaggregazione delle metriche con la distribuzione OpenTelemetry di Monitoraggio di Azure

Preaggregazione delle metriche con Application Insights SDK (API classica)

Preaggregazione delle metriche con strumentazione automatica

Dimensioni delle metriche personalizzate e preaggregazione

Quote

Perché la raccolta di dimensioni di metriche personalizzate è disattivata per impostazione predefinita?

Creare grafici ed esplorare le metriche

Modelli di prezzi per le metriche di Application Insights

Metriche disponibili

Metriche di disponibilità

Disponibilità (availabilityResults/availabilityPercentage)

Durata del test di disponibilità (availabilityResults/duration)

Test di disponibilità (availabilityResults/count)

Metriche del browser

Tempo di caricamento della pagina del browser (browserTimings/totalDuration)

Tempo di elaborazione client (browserTiming/processingDuration)

Tempo di connessione alla rete durante il caricamento della pagina (browserTimings/networkDuration)

Tempo di ricezione della risposta (browserTimings/receiveDuration)

Tempo di invio della richiesta (browserTimings/sendDuration)

Metriche di errore

Eccezioni del browser (exceptions/browser)

Errori di chiamata di dipendenza (dependencies/failed)

Eccezioni (eccezioni/numero)

Richieste non riuscite (requests/failed)

Eccezioni del server (eccezioni/server)

Contatori delle prestazioni

Nomi e descrizioni dei contatori

Esperienze migliorate dai contatori delle prestazioni

Elencare i tipi di contatore delle prestazioni

Metriche del server

Chiamate di dipendenza (dependencies/count)

Durata delle dipendenze (dipendenze/durata)

Frequenza richieste server (richieste/frequenza)

Richieste server (requests/count)

Tempo di risposta del server (richieste/durata)

Metriche di utilizzo

Tempo di caricamento della pagina visualizzata (pageViews/duration)

Visualizzazioni pagina (pageViews/count)

Tracce (traces/count)

Metriche personalizzate

Accedere direttamente alle metriche basate su log con l'API REST di Application Insights

Passaggi successivi

Commenti e suggerimenti

Risorse aggiuntive