Windows 11 Pro 24H2 will not boot after enabling Hyper-V

Thank you so much Maurice. Your help was very much appreciated.

I watched a video on how to write the bat script and then enable Hyper-V....................for 3 days I was trying to log into my computer. I didnt want to factory restore as machine is relatively new and ive just finished installing my apps + I had a few important docs saved on my desktop.

I watched video after video and read multiple forum comments as computer was stuck on repairing computer loop. Figured out how to get to desktop when that happened (delete latest update) but still couldn’t get Hyper-V to work without the dreaded repairing computer start-up loop.

Followed your post. Deleted pxhlpa64.sys and bingo.

Just wanted to thank you.

Regards,

Teddy

I tried this, and after the reboot in step 2, my system blackscreened on boot because it couldn't find the boot device

Thanks a lot!! It worked, I just disabled pxhlpa64.sys and boom!! appreciate the help.

@Scott Neugroschl , in case you disabled a driver that is required to access the boot device (INACCESSIBLE_BOOT_DEVICE), you need to re-enable the drivers on the recovery console again. Please see the following batch file to do this. Usually a USB stick is available on the recovery console, so you can run it from there. Autoruns stores the original "Start" value in the "AutorunsDisabled" key. This script reverses this.

@echo off
SETLOCAL EnableDelayedExpansion
set HIVE=HKLM\OfflineSystem
set SYS=C:\Windows\System32\Config\SYSTEM
echo reg load %HIVE% "%SYS%" using windows drive %SYS:~0,1%
reg load %HIVE% "%SYS%" >nul 2>&1
if errorlevel 1 exit /b 1
echo iterate through all drivers
for /f "tokens=*" %%R in ('reg query %HIVE%\ControlSet001\Services') do (
call :revertautorun %%R
)
echo reg unload %HIVE%
reg unload %HIVE% >nul 2>&1
exit /b 0
GOTO END
:revertautorun
set R=%1
rem get the current start value
for /f "tokens=3" %%A in ('reg query "%R%" /v Start 2^>nul ^| find "Start"') do (
set S=%%A
)
rem get the old start value and run the changereg function
for /f "tokens=3" %%A in ('reg query "%R%" /v AutorunsDisabled 2^>nul ^| find "AutorunsDisabled"') do (
IF "%%A" NEQ "" call :changereg "%R%" %%A !S!
)
GOTO END
:changereg
set R=%1
set OLDSTART=%2
set S=%3
set S=%S:~2,1%
set /a OLDSTART=%OLDSTART:~2,1% >nul 2>&1
if %errorlevel% == 0 (
IF %S% NEQ %OLDSTART% if %OLDSTART% GEQ 0 if %OLDSTART% LEQ 3 (
echo setting driver %R% to startup type %OLDSTART% from %S%
reg add %R% /v Start /t REG_DWORD /d %OLDSTART% /f
rem reg delete %R% /v AutorunsDisabled /f
)
)
GOTO END
:END