Search for subform record based on text box

The reason for filtering the form rather than navigating to a specific record in my demo is that, in my case, there can be more than one parent record which matches the search criterion, so navigating to a record would just go to the first match. It makes more sense in that context to filter the form so that all of the matching records are together. In yours you could write the code to move the form to the first matching record, as there will be only one record which matches the criterion.

A subform control is a control in a parent form which houses the subform. The subform itself is the source object of the subform control. The control might or might not have the same name as the subform itself.

Where my code refers to ctrl this is an object variable. In my case it returns a reference to the ActiveControl because the code is in the combo box's AfterUpdate event procedure so the ActiveControl is the combo box. The default property of a control is its Value property, so when the code refers to ctrl without specifying any property of it, it is interpreted as a reference to the current value of the control, which in this case is the value of the ContactID field to which the combo box is bound, although the ContactID column is hidden and you see the contact's name from the second column of its RowSource. It would equally well work for a text box, though, because that will probably contain a string rather than a number, the value would need to be wrapped in literal quotes characters, e.g.

WHERE ContactName = """ & ctrl & """)"  

In this each literal quotes character is represented by a contiguous pair of quotes characters, "", which is how a quotes character can be included in a string itself delimited by quotes characters. Some people use a single quote character, ' instead, but that would not work with names like mine in its original non-anglicized form, Cináed O'Siridean, because it includes a single quote character as an apostrophe.

You are quite right, the IN operator does return a TRUE or FALSE value. ProjectID is the primary key of the parent form's table, so the expression will return TRUE if the ProjectID of a record in the Projects table has at least one match in the subform's ContactProjects table where the ContactID matches the value of the combo box. The record will thus be returned when the parent form is filtered. Where there is no match it will return FALSE, and then the record won't be returned.

As far as I can see, what you are attempting is essentially the same as in my demo, so you need to use the same methodology. This means filtering the parent form so that it shows the parent record which is referenced by the record in the subform to which you want to navigate, and then navigating to the appropriate record in the subform. Either of the solutions used by my demo will do this, so you need to adapt my code so that it references the objects in your own database. I don't think I can add anything to what I've said previously.

From your original post my understanding is that you wish to enter a value into an unbound text box in a parent form, and move the parent form to a record where the value you entered is present in a subform, i.e. where it is present in a row in a related table where the row references the record shown in the parent form.

The code I gave you does this by building a string expression which filters the parent form's recordset to the row or rows where the value of the primary key is found as a foreign key in the row or rows in the table to which the subform is bound where the value in another column is that which you entered in the unbound text box.

If you have downloaded my demo you will see that the subform's Current event procedure includes the following code which, when the parent form is filtered by means of the unbound combo box, moves the subform to the record whose value was entered in the unbound combo box:

Private Sub Form_Current()

' select contact in subform if combo box is not Null  
If Not IsNull(Me.cboLastname) Then  
    With Me.fsubContacts.Form  
        .RecordsetClone.FindFirst "ContactID = " & Me.cboLastname  
        If Not .RecordsetClone.NoMatch Then  
            .Bookmark = .RecordsetClone.Bookmark  
        End If  
    End With  
End If  

End Sub

I did not give this code in my original reply because, the subform being in continuous forms view, it is not essential to the process, but where the subform is in single form view, it would be necessary to include code like this to show the record in question. Alternatively the subform itself can be filtered, as in the second example I gave you.

If my understanding of what you are attempting is correct, you will need to amend the references in the code so that it refers to your own table, columns and control names, including the subform control, i.e. that in the parent form which houses the subform. You might also need to wrap values in literal quotes characters if the primary and foreign keys are of text data type rather than numeric as in my demo.

Start making sure, you are actually searching using the right criteria. As noted above:

Debug.Print "Criteria:", strCriteria  
rs.FindFirst strCriteria  

You might like to take a look at FindRecord.zip in my public databases folder at:

https://onedrive.live.com/?cid=44CC60D7FEA42912&id=44CC60D7FEA42912!169

If you have trouble downloading a specific file, clicking on the 'Download' button at the top of the page while no files are selected should download a zip file of all files in the folder, from which you should then be able to unpack the relevant file.

This little demo includes two methods for searching on the basis of a value in a row in a subform. The first filters the parent form only, using the following code:

Private Sub cboLastname_AfterUpdate()

Const MESSAGETEXT = "No matching records found."  
Dim ctrl As Control  
Dim strFilter As String  
  
Set ctrl = Me.ActiveControl  
  
strFilter = "ProjectID IN(SELECT ProjectID " & _  
    "FROM ContactProjects WHERE ContactID = " & ctrl & ")"  
  
If Nz(ctrl, 0) = 0 Then  
    ' turn off filter  
    Me.FilterOn = False  
Else  
    If Not IsNull(DLookup("ContactID", "ContactProjects", "ContactID = " & ctrl)) Then  
        ' filter form to name selected in combo box  
        Me.Filter = strFilter  
        Me.FilterOn = True  
    Else  
        ' inform user if no matching records found and show all records  
        MsgBox MESSAGETEXT, vbInformation, "Warning"  
        Me.FilterOn = False  
        Me.Requery  
    End If  
End If  
     

End Sub

The second filters both the form and subform, using the following code:

Private Sub cboLastname_AfterUpdate()

Const MESSAGETEXT = "No matching records found."  
Dim ctrl As Control  
Dim strFilter As String  
  
Set ctrl = Me.ActiveControl  
  
strFilter = "ProjectID IN(SELECT ProjectID " & _  
    "FROM ContactProjects WHERE ContactID = " & ctrl & ")"  
  
If Nz(ctrl, 0) = 0 Then  
    ' turn off filter  
    Me.FilterOn = False  
    Me.fsubContacts.Form.FilterOn = False  
Else  
    If Not IsNull(DLookup("ContactID", "ContactProjects", "ContactID = " & ctrl)) Then  
        ' filter form to name selected in combo box  
        Me.Filter = strFilter  
        Me.FilterOn = True  
          
        ' filter subform to selected contact  
        Me.fsubContacts.Form.Filter = "ContactID = " & ctrl  
        Me.fsubContacts.Form.FilterOn = True  
    Else  
        ' inform user if no matching records found and show all records  
        MsgBox MESSAGETEXT, vbInformation, "Warning"  
        Me.FilterOn = False  
        Me.Requery  
        Me.fsubContacts.Form.FilterOn = False  

    End If  
End If  
     

End Sub